HWACCMR0A.asm@ 12983

Last change on this file since 12983 was 12702, checked in by vboxsync, 16 years ago
#1865: HWACCM - alignment fix+check for 32-bit gcc, doxygen.
Property svn:eol-style set to `native` Property svn:keywords set to `Id`
File size: 27.6 KB

Line
1	; $Id: HWACCMR0A.asm 12702 2008-09-24 16:56:02Z vboxsync $
2	;; @file
3	; VMXM - R0 vmx helpers
4	;
5
6	;
7	; Copyright (C) 2006-2007 Sun Microsystems, Inc.
8	;
9	; This file is part of VirtualBox Open Source Edition (OSE), as
10	; available from http://www.virtualbox.org. This file is free software;
11	; you can redistribute it and/or modify it under the terms of the GNU
12	; General Public License (GPL) as published by the Free Software
13	; Foundation, in version 2 as it comes in the "COPYING" file of the
14	; VirtualBox OSE distribution. VirtualBox OSE is distributed in the
15	; hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
16	;
17	; Please contact Sun Microsystems, Inc., 4150 Network Circle, Santa
18	; Clara, CA 95054 USA or visit http://www.sun.com if you need
19	; additional information or have any questions.
20	;
21
22	;*******************************************************************************
23	;* Header Files *
24	;*******************************************************************************
25	%include "VBox/asmdefs.mac"
26	%include "VBox/err.mac"
27	%include "VBox/hwacc_vmx.mac"
28	%include "VBox/cpum.mac"
29	%include "VBox/x86.mac"
30
31	%ifdef RT_OS_OS2 ;; @todo fix OMF support in yasm and kick nasm out completely.
32	%macro vmwrite 2,
33	int3
34	%endmacro
35	%define vmlaunch int3
36	%define vmresume int3
37	%define vmsave int3
38	%define vmload int3
39	%define vmrun int3
40	%define clgi int3
41	%define stgi int3
42	%macro invlpga 2,
43	int3
44	%endmacro
45	%endif
46
47	;; This is too risky wrt. stability, performance and correctness.
48	;%define VBOX_WITH_DR6_EXPERIMENT 1
49
50	;; @def MYPUSHAD
51	; Macro generating an equivalent to pushad
52
53	;; @def MYPOPAD
54	; Macro generating an equivalent to popad
55
56	;; @def MYPUSHSEGS
57	; Macro saving all segment registers on the stack.
58	; @param 1 full width register name
59	; @param 2 16-bit regsiter name for \a 1.
60
61	;; @def MYPOPSEGS
62	; Macro restoring all segment registers on the stack
63	; @param 1 full width register name
64	; @param 2 16-bit regsiter name for \a 1.
65
66	%ifdef RT_ARCH_AMD64
67	; Save a host and load the corresponding guest MSR (trashes rdx & rcx)
68	%macro LOADGUESTMSR 2
69	mov rcx, %1
70	rdmsr
71	push rdx
72	push rax
73	mov edx, dword [xSI + %2 + 4]
74	mov eax, dword [xSI + %2]
75	wrmsr
76	%endmacro
77
78	; Save a guest and load the corresponding host MSR (trashes rdx & rcx)
79	; Only really useful for gs kernel base as that one can be changed behind our back (swapgs)
80	%macro LOADHOSTMSREX 2
81	mov rcx, %1
82	rdmsr
83	mov dword [xSI + %2], eax
84	mov dword [xSI + %2 + 4], edx
85	pop rax
86	pop rdx
87	wrmsr
88	%endmacro
89
90	; Load the corresponding host MSR (trashes rdx & rcx)
91	%macro LOADHOSTMSR 1
92	mov rcx, %1
93	pop rax
94	pop rdx
95	wrmsr
96	%endmacro
97
98	%ifdef ASM_CALL64_GCC
99	%macro MYPUSHAD 0
100	push r15
101	push r14
102	push r13
103	push r12
104	push rbx
105	%endmacro
106	%macro MYPOPAD 0
107	pop rbx
108	pop r12
109	pop r13
110	pop r14
111	pop r15
112	%endmacro
113
114	%else ; ASM_CALL64_MSC
115	%macro MYPUSHAD 0
116	push r15
117	push r14
118	push r13
119	push r12
120	push rbx
121	push rsi
122	push rdi
123	%endmacro
124	%macro MYPOPAD 0
125	pop rdi
126	pop rsi
127	pop rbx
128	pop r12
129	pop r13
130	pop r14
131	pop r15
132	%endmacro
133	%endif
134
135	; trashes, rax, rdx & rcx
136	%macro MYPUSHSEGS 2
137	mov %2, es
138	push %1
139	mov %2, ds
140	push %1
141
142	; Special case for FS; Windows and Linux either don't use it or restore it when leaving kernel mode, Solaris OTOH doesn't and we must save it.
143	mov ecx, MSR_K8_FS_BASE
144	rdmsr
145	push rdx
146	push rax
147	push fs
148
149	; Special case for GS; OSes typically use swapgs to reset the hidden base register for GS on entry into the kernel. The same happens on exit
150	mov ecx, MSR_K8_GS_BASE
151	rdmsr
152	push rdx
153	push rax
154	push gs
155	%endmacro
156
157	; trashes, rax, rdx & rcx
158	%macro MYPOPSEGS 2
159	; Note: do not step through this code with a debugger!
160	pop gs
161	pop rax
162	pop rdx
163	mov ecx, MSR_K8_GS_BASE
164	wrmsr
165
166	pop fs
167	pop rax
168	pop rdx
169	mov ecx, MSR_K8_FS_BASE
170	wrmsr
171	; Now it's safe to step again
172
173	pop %1
174	mov ds, %2
175	pop %1
176	mov es, %2
177	%endmacro
178
179	%else ; RT_ARCH_X86
180	%macro MYPUSHAD 0
181	pushad
182	%endmacro
183	%macro MYPOPAD 0
184	popad
185	%endmacro
186
187	%macro MYPUSHSEGS 2
188	push ds
189	push es
190	push fs
191	push gs
192	%endmacro
193	%macro MYPOPSEGS 2
194	pop gs
195	pop fs
196	pop es
197	pop ds
198	%endmacro
199	%endif
200
201
202	BEGINCODE
203
204	;/**
205	; * Prepares for and executes VMLAUNCH/VMRESUME (32 bits guest mode)
206	; *
207	; * @returns VBox status code
208	; * @param fResume vmlauch/vmresume
209	; * @param pCtx Guest context
210	; */
211	BEGINPROC VMXR0StartVM32
212	push xBP
213	mov xBP, xSP
214
215	pushf
216	cli
217
218	;/* First we have to save some final CPU context registers. */
219	%ifdef RT_ARCH_AMD64
220	mov rax, qword .vmlaunch_done
221	push rax
222	%else
223	push .vmlaunch_done
224	%endif
225	mov eax, VMX_VMCS_HOST_RIP ;/* return address (too difficult to continue after VMLAUNCH?) */
226	vmwrite xAX, [xSP]
227	;/* Note: assumes success... */
228	add xSP, xS
229
230	;/* Manual save and restore:
231	; * - General purpose registers except RIP, RSP
232	; *
233	; * Trashed:
234	; * - CR2 (we don't care)
235	; * - LDTR (reset to 0)
236	; * - DRx (presumably not changed at all)
237	; * - DR7 (reset to 0x400)
238	; * - EFLAGS (reset to RT_BIT(1); not relevant)
239	; *
240	; */
241
242	;/* Save all general purpose host registers. */
243	MYPUSHAD
244
245	;/* Save the Guest CPU context pointer. */
246	%ifdef RT_ARCH_AMD64
247	%ifdef ASM_CALL64_GCC
248	; fResume already in rdi
249	; pCtx already in rsi
250	%else
251	mov rdi, rcx ; fResume
252	mov rsi, rdx ; pCtx
253	%endif
254	%else
255	mov edi, [ebp + 8] ; fResume
256	mov esi, [ebp + 12] ; pCtx
257	%endif
258
259	;/* Save segment registers */
260	; Note: MYPUSHSEGS trashes rdx & rcx, so we moved it here (msvc amd64 case)
261	MYPUSHSEGS xAX, ax
262
263	; Save the pCtx pointer
264	push xSI
265
266	; Save LDTR
267	xor eax, eax
268	sldt ax
269	push xAX
270
271	; VMX only saves the base of the GDTR & IDTR and resets the limit to 0xffff; we must restore the limit correctly!
272	sub xSP, xS*2
273	sgdt [xSP]
274
275	sub xSP, xS*2
276	sidt [xSP]
277
278	%ifdef VBOX_WITH_DR6_EXPERIMENT
279	; Restore DR6 - experiment, not safe!
280	mov xBX, [xSI + CPUMCTX.dr6]
281	mov dr6, xBX
282	%endif
283
284	; Restore CR2
285	mov ebx, [xSI + CPUMCTX.cr2]
286	mov cr2, xBX
287
288	mov eax, VMX_VMCS_HOST_RSP
289	vmwrite xAX, xSP
290	;/* Note: assumes success... */
291	;/* Don't mess with ESP anymore!! */
292
293	;/* Restore Guest's general purpose registers. */
294	mov eax, [xSI + CPUMCTX.eax]
295	mov ebx, [xSI + CPUMCTX.ebx]
296	mov ecx, [xSI + CPUMCTX.ecx]
297	mov edx, [xSI + CPUMCTX.edx]
298	mov ebp, [xSI + CPUMCTX.ebp]
299
300	; resume or start?
301	cmp xDI, 0 ; fResume
302	je .vmlauch_lauch
303
304	;/* Restore edi & esi. */
305	mov edi, [xSI + CPUMCTX.edi]
306	mov esi, [xSI + CPUMCTX.esi]
307
308	vmresume
309	jmp .vmlaunch_done; ;/* here if vmresume detected a failure. */
310
311	.vmlauch_lauch:
312	;/* Restore edi & esi. */
313	mov edi, [xSI + CPUMCTX.edi]
314	mov esi, [xSI + CPUMCTX.esi]
315
316	vmlaunch
317	jmp .vmlaunch_done; ;/* here if vmlaunch detected a failure. */
318
319	ALIGNCODE(16)
320	.vmlaunch_done:
321	jc near .vmxstart_invalid_vmxon_ptr
322	jz near .vmxstart_start_failed
323
324	; Restore base and limit of the IDTR & GDTR
325	lidt [xSP]
326	add xSP, xS*2
327	lgdt [xSP]
328	add xSP, xS*2
329
330	push xDI
331	mov xDI, [xSP + xS * 2] ; pCtx
332
333	mov [ss:xDI + CPUMCTX.eax], eax
334	mov [ss:xDI + CPUMCTX.ebx], ebx
335	mov [ss:xDI + CPUMCTX.ecx], ecx
336	mov [ss:xDI + CPUMCTX.edx], edx
337	mov [ss:xDI + CPUMCTX.esi], esi
338	mov [ss:xDI + CPUMCTX.ebp], ebp
339	%ifdef RT_ARCH_AMD64
340	pop xAX ; the guest edi we pushed above
341	mov dword [ss:xDI + CPUMCTX.edi], eax
342	%else
343	pop dword [ss:xDI + CPUMCTX.edi] ; the guest edi we pushed above
344	%endif
345
346	%ifdef VBOX_WITH_DR6_EXPERIMENT
347	; Save DR6 - experiment, not safe!
348	mov xAX, dr6
349	mov [ss:xDI + CPUMCTX.dr6], xAX
350	%endif
351
352	pop xAX ; saved LDTR
353	lldt ax
354
355	add xSP, xS ; pCtx
356
357	; Restore segment registers
358	MYPOPSEGS xAX, ax
359
360	; Restore general purpose registers
361	MYPOPAD
362
363	mov eax, VINF_SUCCESS
364
365	.vmstart_end:
366	popf
367	pop xBP
368	ret
369
370
371	.vmxstart_invalid_vmxon_ptr:
372	; Restore base and limit of the IDTR & GDTR
373	lidt [xSP]
374	add xSP, xS*2
375	lgdt [xSP]
376	add xSP, xS*2
377
378	pop xAX ; saved LDTR
379	lldt ax
380
381	add xSP, xS ; pCtx
382
383	; Restore segment registers
384	MYPOPSEGS xAX, ax
385
386	; Restore all general purpose host registers.
387	MYPOPAD
388	mov eax, VERR_VMX_INVALID_VMXON_PTR
389	jmp .vmstart_end
390
391	.vmxstart_start_failed:
392	; Restore base and limit of the IDTR & GDTR
393	lidt [xSP]
394	add xSP, xS*2
395	lgdt [xSP]
396	add xSP, xS*2
397
398	pop xAX ; saved LDTR
399	lldt ax
400
401	add xSP, xS ; pCtx
402
403	; Restore segment registers
404	MYPOPSEGS xAX, ax
405
406	; Restore all general purpose host registers.
407	MYPOPAD
408	mov eax, VERR_VMX_UNABLE_TO_START_VM
409	jmp .vmstart_end
410
411	ENDPROC VMXR0StartVM32
412
413	%ifdef RT_ARCH_AMD64
414	;/**
415	; * Prepares for and executes VMLAUNCH/VMRESUME (64 bits guest mode)
416	; *
417	; * @returns VBox status code
418	; * @param fResume vmlauch/vmresume
419	; * @param pCtx Guest context
420	; */
421	BEGINPROC VMXR0StartVM64
422	push xBP
423	mov xBP, xSP
424
425	pushf
426	cli
427
428	;/* First we have to save some final CPU context registers. */
429	mov rax, qword .vmlaunch64_done
430	push rax
431	mov rax, VMX_VMCS_HOST_RIP ;/* return address (too difficult to continue after VMLAUNCH?) */
432	vmwrite rax, [xSP]
433	;/* Note: assumes success... */
434	add xSP, xS
435
436	;/* Manual save and restore:
437	; * - General purpose registers except RIP, RSP
438	; *
439	; * Trashed:
440	; * - CR2 (we don't care)
441	; * - LDTR (reset to 0)
442	; * - DRx (presumably not changed at all)
443	; * - DR7 (reset to 0x400)
444	; * - EFLAGS (reset to RT_BIT(1); not relevant)
445	; *
446	; */
447
448	;/* Save all general purpose host registers. */
449	MYPUSHAD
450
451	;/* Save the Guest CPU context pointer. */
452	%ifdef ASM_CALL64_GCC
453	; fResume already in rdi
454	; pCtx already in rsi
455	%else
456	mov rdi, rcx ; fResume
457	mov rsi, rdx ; pCtx
458	%endif
459
460	;/* Save segment registers */
461	; Note: MYPUSHSEGS trashes rdx & rcx, so we moved it here (msvc amd64 case)
462	MYPUSHSEGS xAX, ax
463
464	; Save the host LSTAR, CSTAR, SFMASK & KERNEL_GSBASE MSRs and restore the guest MSRs
465	;; @todo use the automatic load feature for MSRs
466	LOADGUESTMSR MSR_K8_LSTAR, CPUMCTX.msrLSTAR
467	%if 0 ; not supported on Intel CPUs
468	LOADGUESTMSR MSR_K8_CSTAR, CPUMCTX.msrCSTAR
469	%endif
470	LOADGUESTMSR MSR_K6_STAR, CPUMCTX.msrSTAR
471	LOADGUESTMSR MSR_K8_SF_MASK, CPUMCTX.msrSFMASK
472	LOADGUESTMSR MSR_K8_KERNEL_GS_BASE, CPUMCTX.msrKERNELGSBASE
473
474	; Save the pCtx pointer
475	push xSI
476
477	; Save LDTR
478	xor eax, eax
479	sldt ax
480	push xAX
481
482	; VMX only saves the base of the GDTR & IDTR and resets the limit to 0xffff; we must restore the limit correctly!
483	sub xSP, xS*2
484	sgdt [xSP]
485
486	sub xSP, xS*2
487	sidt [xSP]
488
489	%ifdef VBOX_WITH_DR6_EXPERIMENT
490	; Restore DR6 - experiment, not safe!
491	mov xBX, [xSI + CPUMCTX.dr6]
492	mov dr6, xBX
493	%endif
494
495	; Restore CR2
496	mov rbx, qword [xSI + CPUMCTX.cr2]
497	mov cr2, rbx
498
499	mov eax, VMX_VMCS_HOST_RSP
500	vmwrite xAX, xSP
501	;/* Note: assumes success... */
502	;/* Don't mess with ESP anymore!! */
503
504	;/* Restore Guest's general purpose registers. */
505	mov rax, qword [xSI + CPUMCTX.eax]
506	mov rbx, qword [xSI + CPUMCTX.ebx]
507	mov rcx, qword [xSI + CPUMCTX.ecx]
508	mov rdx, qword [xSI + CPUMCTX.edx]
509	mov rbp, qword [xSI + CPUMCTX.ebp]
510	mov r8, qword [xSI + CPUMCTX.r8]
511	mov r9, qword [xSI + CPUMCTX.r9]
512	mov r10, qword [xSI + CPUMCTX.r10]
513	mov r11, qword [xSI + CPUMCTX.r11]
514	mov r12, qword [xSI + CPUMCTX.r12]
515	mov r13, qword [xSI + CPUMCTX.r13]
516	mov r14, qword [xSI + CPUMCTX.r14]
517	mov r15, qword [xSI + CPUMCTX.r15]
518
519	; resume or start?
520	cmp xDI, 0 ; fResume
521	je .vmlauch64_lauch
522
523	;/* Restore edi & esi. */
524	mov rdi, qword [xSI + CPUMCTX.edi]
525	mov rsi, qword [xSI + CPUMCTX.esi]
526
527	vmresume
528	jmp .vmlaunch64_done; ;/* here if vmresume detected a failure. */
529
530	.vmlauch64_lauch:
531	;/* Restore rdi & rsi. */
532	mov rdi, qword [xSI + CPUMCTX.edi]
533	mov rsi, qword [xSI + CPUMCTX.esi]
534
535	vmlaunch
536	jmp .vmlaunch64_done; ;/* here if vmlaunch detected a failure. */
537
538	ALIGNCODE(16)
539	.vmlaunch64_done:
540	jc near .vmxstart64_invalid_vmxon_ptr
541	jz near .vmxstart64_start_failed
542
543	; Restore base and limit of the IDTR & GDTR
544	lidt [xSP]
545	add xSP, xS*2
546	lgdt [xSP]
547	add xSP, xS*2
548
549	push xDI
550	mov xDI, [xSP + xS * 2] ; pCtx
551
552	mov qword [xDI + CPUMCTX.eax], rax
553	mov qword [xDI + CPUMCTX.ebx], rbx
554	mov qword [xDI + CPUMCTX.ecx], rcx
555	mov qword [xDI + CPUMCTX.edx], rdx
556	mov qword [xDI + CPUMCTX.esi], rsi
557	mov qword [xDI + CPUMCTX.ebp], rbp
558	mov qword [xDI + CPUMCTX.r8], r8
559	mov qword [xDI + CPUMCTX.r9], r9
560	mov qword [xDI + CPUMCTX.r10], r10
561	mov qword [xDI + CPUMCTX.r11], r11
562	mov qword [xDI + CPUMCTX.r12], r12
563	mov qword [xDI + CPUMCTX.r13], r13
564	mov qword [xDI + CPUMCTX.r14], r14
565	mov qword [xDI + CPUMCTX.r15], r15
566
567	pop xAX ; the guest edi we pushed above
568	mov qword [xDI + CPUMCTX.edi], rax
569
570	%ifdef VBOX_WITH_DR6_EXPERIMENT
571	; Save DR6 - experiment, not safe!
572	mov xAX, dr6
573	mov [xDI + CPUMCTX.dr6], xAX
574	%endif
575
576	pop xAX ; saved LDTR
577	lldt ax
578
579	pop xSI ; pCtx (needed in rsi by the macros below)
580
581	; Restore the host LSTAR, CSTAR, SFMASK & KERNEL_GSBASE MSRs
582	;; @todo use the automatic load feature for MSRs
583	LOADHOSTMSREX MSR_K8_KERNEL_GS_BASE, CPUMCTX.msrKERNELGSBASE
584	LOADHOSTMSR MSR_K8_SF_MASK
585	LOADHOSTMSR MSR_K6_STAR
586	%if 0 ; not supported on Intel CPUs
587	LOADHOSTMSR MSR_K8_CSTAR
588	%endif
589	LOADHOSTMSR MSR_K8_LSTAR
590
591	; Restore segment registers
592	MYPOPSEGS xAX, ax
593
594	; Restore general purpose registers
595	MYPOPAD
596
597	mov eax, VINF_SUCCESS
598
599	.vmstart64_end:
600	popf
601	pop xBP
602	ret
603
604
605	.vmxstart64_invalid_vmxon_ptr:
606	; Restore base and limit of the IDTR & GDTR
607	lidt [xSP]
608	add xSP, xS*2
609	lgdt [xSP]
610	add xSP, xS*2
611
612	pop xAX ; saved LDTR
613	lldt ax
614
615	pop xSI ; pCtx (needed in rsi by the macros below)
616
617	; Restore the host LSTAR, CSTAR, SFMASK & KERNEL_GSBASE MSRs
618	;; @todo use the automatic load feature for MSRs
619	LOADHOSTMSREX MSR_K8_KERNEL_GS_BASE, CPUMCTX.msrKERNELGSBASE
620	LOADHOSTMSR MSR_K8_SF_MASK
621	LOADHOSTMSR MSR_K8_CSTAR
622	LOADHOSTMSR MSR_K8_LSTAR
623
624	; Restore segment registers
625	MYPOPSEGS xAX, ax
626
627	; Restore all general purpose host registers.
628	MYPOPAD
629	mov eax, VERR_VMX_INVALID_VMXON_PTR
630	jmp .vmstart64_end
631
632	.vmxstart64_start_failed:
633	; Restore base and limit of the IDTR & GDTR
634	lidt [xSP]
635	add xSP, xS*2
636	lgdt [xSP]
637	add xSP, xS*2
638
639	pop xAX ; saved LDTR
640	lldt ax
641
642	pop xSI ; pCtx (needed in rsi by the macros below)
643
644	; Restore the host LSTAR, CSTAR, SFMASK & KERNEL_GSBASE MSRs
645	;; @todo use the automatic load feature for MSRs
646	LOADHOSTMSREX MSR_K8_KERNEL_GS_BASE, CPUMCTX.msrKERNELGSBASE
647	LOADHOSTMSR MSR_K8_SF_MASK
648	LOADHOSTMSR MSR_K8_CSTAR
649	LOADHOSTMSR MSR_K8_LSTAR
650
651	; Restore segment registers
652	MYPOPSEGS xAX, ax
653
654	; Restore all general purpose host registers.
655	MYPOPAD
656	mov eax, VERR_VMX_UNABLE_TO_START_VM
657	jmp .vmstart64_end
658	ENDPROC VMXR0StartVM64
659
660	;/**
661	; * Executes VMWRITE
662	; *
663	; * @returns VBox status code
664	; * @param idxField x86: [ebp + 08h] msc: rcx gcc: rdi VMCS index
665	; * @param pData x86: [ebp + 0ch] msc: rdx gcc: rsi VM field value
666	; */
667	BEGINPROC VMXWriteVMCS64
668	%ifdef ASM_CALL64_GCC
669	mov eax, 0ffffffffh
670	and rdi, rax
671	xor rax, rax
672	vmwrite rdi, rsi
673	%else
674	mov eax, 0ffffffffh
675	and rcx, rax
676	xor rax, rax
677	vmwrite rcx, rdx
678	%endif
679	jnc .valid_vmcs
680	mov eax, VERR_VMX_INVALID_VMCS_PTR
681	ret
682	.valid_vmcs:
683	jnz .the_end
684	mov eax, VERR_VMX_INVALID_VMCS_FIELD
685	.the_end:
686	ret
687	ENDPROC VMXWriteVMCS64
688
689	;/**
690	; * Executes VMREAD
691	; *
692	; * @returns VBox status code
693	; * @param idxField VMCS index
694	; * @param pData Ptr to store VM field value
695	; */
696	;DECLASM(int) VMXReadVMCS64(uint32_t idxField, uint64_t *pData);
697	BEGINPROC VMXReadVMCS64
698	%ifdef ASM_CALL64_GCC
699	mov eax, 0ffffffffh
700	and rdi, rax
701	xor rax, rax
702	vmread [rsi], rdi
703	%else
704	mov eax, 0ffffffffh
705	and rcx, rax
706	xor rax, rax
707	vmread [rdx], rcx
708	%endif
709	jnc .valid_vmcs
710	mov eax, VERR_VMX_INVALID_VMCS_PTR
711	ret
712	.valid_vmcs:
713	jnz .the_end
714	mov eax, VERR_VMX_INVALID_VMCS_FIELD
715	.the_end:
716	ret
717	ENDPROC VMXReadVMCS64
718
719
720	;/**
721	; * Executes VMXON
722	; *
723	; * @returns VBox status code
724	; * @param HCPhysVMXOn Physical address of VMXON structure
725	; */
726	;DECLASM(int) VMXEnable(RTHCPHYS HCPhysVMXOn);
727	BEGINPROC VMXEnable
728	%ifdef RT_ARCH_AMD64
729	xor rax, rax
730	%ifdef ASM_CALL64_GCC
731	push rdi
732	%else
733	push rcx
734	%endif
735	vmxon [rsp]
736	%else
737	xor eax, eax
738	vmxon [esp + 4]
739	%endif
740	jnc .good
741	mov eax, VERR_VMX_INVALID_VMXON_PTR
742	jmp .the_end
743
744	.good:
745	jnz .the_end
746	mov eax, VERR_VMX_GENERIC
747
748	.the_end:
749	%ifdef RT_ARCH_AMD64
750	add rsp, 8
751	%endif
752	ret
753	ENDPROC VMXEnable
754
755	;/**
756	; * Executes VMXOFF
757	; */
758	;DECLASM(void) VMXDisable(void);
759	BEGINPROC VMXDisable
760	vmxoff
761	ret
762	ENDPROC VMXDisable
763
764
765	;/**
766	; * Executes VMCLEAR
767	; *
768	; * @returns VBox status code
769	; * @param HCPhysVMCS Physical address of VM control structure
770	; */
771	;DECLASM(int) VMXClearVMCS(RTHCPHYS HCPhysVMCS);
772	BEGINPROC VMXClearVMCS
773	%ifdef RT_ARCH_AMD64
774	xor rax, rax
775	%ifdef ASM_CALL64_GCC
776	push rdi
777	%else
778	push rcx
779	%endif
780	vmclear [rsp]
781	%else
782	xor eax, eax
783	vmclear [esp + 4]
784	%endif
785	jnc .the_end
786	mov eax, VERR_VMX_INVALID_VMCS_PTR
787	.the_end:
788	%ifdef RT_ARCH_AMD64
789	add rsp, 8
790	%endif
791	ret
792	ENDPROC VMXClearVMCS
793
794
795	;/**
796	; * Executes VMPTRLD
797	; *
798	; * @returns VBox status code
799	; * @param HCPhysVMCS Physical address of VMCS structure
800	; */
801	;DECLASM(int) VMXActivateVMCS(RTHCPHYS HCPhysVMCS);
802	BEGINPROC VMXActivateVMCS
803	%ifdef RT_ARCH_AMD64
804	xor rax, rax
805	%ifdef ASM_CALL64_GCC
806	push rdi
807	%else
808	push rcx
809	%endif
810	vmptrld [rsp]
811	%else
812	xor eax, eax
813	vmptrld [esp + 4]
814	%endif
815	jnc .the_end
816	mov eax, VERR_VMX_INVALID_VMCS_PTR
817	.the_end:
818	%ifdef RT_ARCH_AMD64
819	add rsp, 8
820	%endif
821	ret
822	ENDPROC VMXActivateVMCS
823
824	%endif ; RT_ARCH_AMD64
825
826	;/**
827	; * Executes VMPTRST
828	; *
829	; * @returns VBox status code
830	; * @param [esp + 04h] gcc:rdi msc:rcx Param 1 - First parameter - Address that will receive the current pointer
831	; */
832	;DECLASM(int) VMXGetActivateVMCS(RTHCPHYS *pVMCS);
833	BEGINPROC VMXGetActivateVMCS
834	%ifdef RT_ARCH_AMD64
835	%ifdef ASM_CALL64_GCC
836	vmptrst qword [rdi]
837	%else
838	vmptrst qword [rcx]
839	%endif
840	%else
841	vmptrst qword [esp+04h]
842	%endif
843	xor eax, eax
844	ret
845	ENDPROC VMXGetActivateVMCS
846
847
848	;/**
849	; * Prepares for and executes VMRUN (32 bits guests)
850	; *
851	; * @returns VBox status code
852	; * @param HCPhysVMCB Physical address of host VMCB
853	; * @param HCPhysVMCB Physical address of guest VMCB
854	; * @param pCtx Guest context
855	; */
856	BEGINPROC SVMVMRun
857	%ifdef RT_ARCH_AMD64 ; fake a cdecl stack frame
858	%ifdef ASM_CALL64_GCC
859	push rdx
860	push rsi
861	push rdi
862	%else
863	push r8
864	push rdx
865	push rcx
866	%endif
867	push 0
868	%endif
869	push xBP
870	mov xBP, xSP
871	pushf
872
873	;/* Manual save and restore:
874	; * - General purpose registers except RIP, RSP, RAX
875	; *
876	; * Trashed:
877	; * - CR2 (we don't care)
878	; * - LDTR (reset to 0)
879	; * - DRx (presumably not changed at all)
880	; * - DR7 (reset to 0x400)
881	; */
882
883	;/* Save all general purpose host registers. */
884	MYPUSHAD
885
886	;/* Save the Guest CPU context pointer. */
887	mov xSI, [xBP + xS2 + RTHCPHYS_CB2] ; pCtx
888	push xSI ; push for saving the state at the end
889
890	; Restore CR2
891	mov ebx, [xSI + CPUMCTX.cr2]
892	mov cr2, xBX
893
894	; save host fs, gs, sysenter msr etc
895	mov xAX, [xBP + xS*2] ; pVMCBHostPhys (64 bits physical address; x86: take low dword only)
896	push xAX ; save for the vmload after vmrun
897	vmsave
898
899	; setup eax for VMLOAD
900	mov xAX, [xBP + xS*2 + RTHCPHYS_CB] ; pVMCBPhys (64 bits physical address; take low dword only)
901
902	;/* Restore Guest's general purpose registers. */
903	;/* EAX is loaded from the VMCB by VMRUN */
904	mov ebx, [xSI + CPUMCTX.ebx]
905	mov ecx, [xSI + CPUMCTX.ecx]
906	mov edx, [xSI + CPUMCTX.edx]
907	mov edi, [xSI + CPUMCTX.edi]
908	mov ebp, [xSI + CPUMCTX.ebp]
909	mov esi, [xSI + CPUMCTX.esi]
910
911	; Clear the global interrupt flag & execute sti to make sure external interrupts cause a world switch
912	clgi
913	sti
914
915	; load guest fs, gs, sysenter msr etc
916	vmload
917	; run the VM
918	vmrun
919
920	;/* EAX is in the VMCB already; we can use it here. */
921
922	; save guest fs, gs, sysenter msr etc
923	vmsave
924
925	; load host fs, gs, sysenter msr etc
926	pop xAX ; pushed above
927	vmload
928
929	; Set the global interrupt flag again, but execute cli to make sure IF=0.
930	cli
931	stgi
932
933	pop xAX ; pCtx
934
935	mov [ss:xAX + CPUMCTX.ebx], ebx
936	mov [ss:xAX + CPUMCTX.ecx], ecx
937	mov [ss:xAX + CPUMCTX.edx], edx
938	mov [ss:xAX + CPUMCTX.esi], esi
939	mov [ss:xAX + CPUMCTX.edi], edi
940	mov [ss:xAX + CPUMCTX.ebp], ebp
941
942	; Restore general purpose registers
943	MYPOPAD
944
945	mov eax, VINF_SUCCESS
946
947	popf
948	pop xBP
949	%ifdef RT_ARCH_AMD64
950	add xSP, 4*xS
951	%endif
952	ret
953	ENDPROC SVMVMRun
954
955	%ifdef RT_ARCH_AMD64
956	;/**
957	; * Prepares for and executes VMRUN (64 bits guests)
958	; *
959	; * @returns VBox status code
960	; * @param HCPhysVMCB Physical address of host VMCB
961	; * @param HCPhysVMCB Physical address of guest VMCB
962	; * @param pCtx Guest context
963	; */
964	BEGINPROC SVMVMRun64
965	; fake a cdecl stack frame
966	%ifdef ASM_CALL64_GCC
967	push rdx
968	push rsi
969	push rdi
970	%else
971	push r8
972	push rdx
973	push rcx
974	%endif
975	push 0
976	push rbp
977	mov rbp, rsp
978	pushf
979
980	;/* Manual save and restore:
981	; * - General purpose registers except RIP, RSP, RAX
982	; *
983	; * Trashed:
984	; * - CR2 (we don't care)
985	; * - LDTR (reset to 0)
986	; * - DRx (presumably not changed at all)
987	; * - DR7 (reset to 0x400)
988	; */
989
990	;/* Save all general purpose host registers. */
991	MYPUSHAD
992
993	;/* Save the Guest CPU context pointer. */
994	mov rsi, [rbp + xS2 + RTHCPHYS_CB2] ; pCtx
995	push rsi ; push for saving the state at the end
996
997	; Restore CR2
998	mov rbx, [rsi + CPUMCTX.cr2]
999	mov cr2, rbx
1000
1001	; save host fs, gs, sysenter msr etc
1002	mov rax, [rbp + xS*2] ; pVMCBHostPhys (64 bits physical address; x86: take low dword only)
1003	push rax ; save for the vmload after vmrun
1004	vmsave
1005
1006	; setup eax for VMLOAD
1007	mov rax, [rbp + xS*2 + RTHCPHYS_CB] ; pVMCBPhys (64 bits physical address; take low dword only)
1008
1009	;/* Restore Guest's general purpose registers. */
1010	;/* RAX is loaded from the VMCB by VMRUN */
1011	mov rbx, qword [xSI + CPUMCTX.ebx]
1012	mov rcx, qword [xSI + CPUMCTX.ecx]
1013	mov rdx, qword [xSI + CPUMCTX.edx]
1014	mov rdi, qword [xSI + CPUMCTX.edi]
1015	mov rbp, qword [xSI + CPUMCTX.ebp]
1016	mov r8, qword [xSI + CPUMCTX.r8]
1017	mov r9, qword [xSI + CPUMCTX.r9]
1018	mov r10, qword [xSI + CPUMCTX.r10]
1019	mov r11, qword [xSI + CPUMCTX.r11]
1020	mov r12, qword [xSI + CPUMCTX.r12]
1021	mov r13, qword [xSI + CPUMCTX.r13]
1022	mov r14, qword [xSI + CPUMCTX.r14]
1023	mov r15, qword [xSI + CPUMCTX.r15]
1024	mov rsi, qword [xSI + CPUMCTX.esi]
1025
1026	; Clear the global interrupt flag & execute sti to make sure external interrupts cause a world switch
1027	clgi
1028	sti
1029
1030	; load guest fs, gs, sysenter msr etc
1031	vmload
1032	; run the VM
1033	vmrun
1034
1035	;/* RAX is in the VMCB already; we can use it here. */
1036
1037	; save guest fs, gs, sysenter msr etc
1038	vmsave
1039
1040	; load host fs, gs, sysenter msr etc
1041	pop rax ; pushed above
1042	vmload
1043
1044	; Set the global interrupt flag again, but execute cli to make sure IF=0.
1045	cli
1046	stgi
1047
1048	pop rax ; pCtx
1049
1050	mov qword [rax + CPUMCTX.ebx], rbx
1051	mov qword [rax + CPUMCTX.ecx], rcx
1052	mov qword [rax + CPUMCTX.edx], rdx
1053	mov qword [rax + CPUMCTX.esi], rsi
1054	mov qword [rax + CPUMCTX.edi], rdi
1055	mov qword [rax + CPUMCTX.ebp], rbp
1056	mov qword [rax + CPUMCTX.r8], r8
1057	mov qword [rax + CPUMCTX.r9], r9
1058	mov qword [rax + CPUMCTX.r10], r10
1059	mov qword [rax + CPUMCTX.r11], r11
1060	mov qword [rax + CPUMCTX.r12], r12
1061	mov qword [rax + CPUMCTX.r13], r13
1062	mov qword [rax + CPUMCTX.r14], r14
1063	mov qword [rax + CPUMCTX.r15], r15
1064
1065	; Restore general purpose registers
1066	MYPOPAD
1067
1068	mov eax, VINF_SUCCESS
1069
1070	popf
1071	pop rbp
1072	add rsp, 4*xS
1073	ret
1074	ENDPROC SVMVMRun64
1075	%endif ; RT_ARCH_AMD64
1076
1077
1078	%if GC_ARCH_BITS == 64
1079	;;
1080	; Executes INVLPGA
1081	;
1082	; @param pPageGC msc:rcx gcc:rdi x86:[esp+04] Virtual page to invalidate
1083	; @param uASID msc:rdx gcc:rsi x86:[esp+0C] Tagged TLB id
1084	;
1085	;DECLASM(void) SVMInvlpgA(RTGCPTR pPageGC, uint32_t uASID);
1086	BEGINPROC SVMInvlpgA
1087	%ifdef RT_ARCH_AMD64
1088	%ifdef ASM_CALL64_GCC
1089	mov rax, rdi
1090	mov rcx, rsi
1091	%else
1092	; from http://www.cs.cmu.edu/~fp/courses/15213-s06/misc/asm64-handout.pdf:
1093	; ``Perhaps unexpectedly, instructions that move or generate 32-bit register
1094	; values also set the upper 32 bits of the register to zero. Consequently
1095	; there is no need for an instruction movzlq.''
1096	mov eax, ecx
1097	mov rcx, rdx
1098	%endif
1099	%else
1100	mov eax, [esp + 4]
1101	mov ecx, [esp + 0Ch]
1102	%endif
1103	invlpga [xAX], ecx
1104	ret
1105	ENDPROC SVMInvlpgA
1106
1107	%else
1108	;;
1109	; Executes INVLPGA
1110	;
1111	; @param pPageGC msc:ecx gcc:edi x86:[esp+04] Virtual page to invalidate
1112	; @param uASID msc:edx gcc:esi x86:[esp+08] Tagged TLB id
1113	;
1114	;DECLASM(void) SVMInvlpgA(RTGCPTR pPageGC, uint32_t uASID);
1115	BEGINPROC SVMInvlpgA
1116	%ifdef RT_ARCH_AMD64
1117	%ifdef ASM_CALL64_GCC
1118	movzx rax, edi
1119	mov ecx, esi
1120	%else
1121	; from http://www.cs.cmu.edu/~fp/courses/15213-s06/misc/asm64-handout.pdf:
1122	; ``Perhaps unexpectedly, instructions that move or generate 32-bit register
1123	; values also set the upper 32 bits of the register to zero. Consequently
1124	; there is no need for an instruction movzlq.''
1125	mov eax, ecx
1126	mov ecx, edx
1127	%endif
1128	%else
1129	mov eax, [esp + 4]
1130	mov ecx, [esp + 8]
1131	%endif
1132	invlpga [xAX], ecx
1133	ret
1134	ENDPROC SVMInvlpgA
1135
1136	%endif ; GC_ARCH_BITS != 64
1137

Note: See TracBrowser for help on using the repository browser.

source: vbox/trunk/src/VBox/VMM/VMMR0/HWACCMR0A.asm@ 12983

Download in other formats: