TRPMGCHandlersA.asm@ 8707

Last change on this file since 8707 was 8155, checked in by vboxsync, 17 years ago
The Big Sun Rebranding Header Change
Property svn:eol-style set to `native` Property svn:keywords set to `Id`
File size: 41.7 KB

Line
1	; $Id: TRPMGCHandlersA.asm 8155 2008-04-18 15:16:47Z vboxsync $
2	;; @file
3	; TRPM - Guest Context Trap Handlers
4	;
5
6	; Copyright (C) 2006-2007 Sun Microsystems, Inc.
7	;
8	; This file is part of VirtualBox Open Source Edition (OSE), as
9	; available from http://www.virtualbox.org. This file is free software;
10	; you can redistribute it and/or modify it under the terms of the GNU
11	; General Public License (GPL) as published by the Free Software
12	; Foundation, in version 2 as it comes in the "COPYING" file of the
13	; VirtualBox OSE distribution. VirtualBox OSE is distributed in the
14	; hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
15	;
16	; Please contact Sun Microsystems, Inc., 4150 Network Circle, Santa
17	; Clara, CA 95054 USA or visit http://www.sun.com if you need
18	; additional information or have any questions.
19	;
20
21	;*******************************************************************************
22	;* Header Files *
23	;*******************************************************************************
24	%include "VMMGC.mac"
25	%include "VBox/x86.mac"
26	%include "VBox/cpum.mac"
27	%include "VBox/stam.mac"
28	%include "VBox/vm.mac"
29	%include "TRPMInternal.mac"
30	%include "VBox/err.mac"
31	%include "VBox/trpm.mac"
32
33
34	;*******************************************************************************
35	;* External Symbols *
36	;*******************************************************************************
37	extern IMPNAME(g_CPUM) ; These IMPNAME(g_*) symbols resolve to the import table
38	extern IMPNAME(g_TRPM) ; where there is a pointer to the real symbol. PE imports
39	extern IMPNAME(g_VM) ; are a bit confusing at first... :-)
40	extern NAME(CPUMGCRestoreInt)
41	extern NAME(CPUMHandleLazyFPUAsm)
42	extern NAME(CPUMHyperSetCtxCore)
43	extern NAME(trpmGCTrapInGeneric)
44	extern NAME(TRPMGCHyperTrap0bHandler)
45	extern NAME(TRPMGCHyperTrap0dHandler)
46	extern NAME(TRPMGCHyperTrap0eHandler)
47	extern NAME(TRPMGCTrap01Handler)
48	%ifdef VBOX_WITH_NMI
49	extern NAME(TRPMGCTrap02Handler)
50	%endif
51	extern NAME(TRPMGCTrap03Handler)
52	extern NAME(TRPMGCTrap06Handler)
53	extern NAME(TRPMGCTrap0bHandler)
54	extern NAME(TRPMGCTrap0dHandler)
55	extern NAME(TRPMGCTrap0eHandler)
56	extern NAME(TRPMGCTrap07Handler)
57
58	;; IMPORTANT all COM_ functions trashes esi, some edi and the LOOP_SHORT_WHILE kills ecx.
59	;%define DEBUG_STUFF 1
60	;%define DEBUG_STUFF_TRPG 1
61	;%define DEBUG_STUFF_INT 1
62
63	BEGINCODE
64
65	;;
66	; Jump table for trap handlers for hypervisor traps.
67	;
68	g_apfnStaticTrapHandlersHyper:
69	; N - M M - T - C - D i
70	; o - n o - y - o - e p
71	; - e n - p - d - s t
72	; - i - e - e - c .
73	; - c - - - r
74	; =============================================================
75	dd 0 ; 0 - #DE - F - N - Divide error
76	dd NAME(TRPMGCTrap01Handler) ; 1 - #DB - F/T - N - Single step, INT 1 instruction
77	%ifdef VBOX_WITH_NMI
78	dd NAME(TRPMGCTrap02Handler) ; 2 - - I - N - Non-Maskable Interrupt (NMI)
79	%else
80	dd 0 ; 2 - - I - N - Non-Maskable Interrupt (NMI)
81	%endif
82	dd NAME(TRPMGCTrap03Handler) ; 3 - #BP - T - N - Breakpoint, INT 3 instruction.
83	dd 0 ; 4 - #OF - T - N - Overflow, INTO instruction.
84	dd 0 ; 5 - #BR - F - N - BOUND Range Exceeded, BOUND instruction.
85	dd 0 ; 6 - #UD - F - N - Undefined(/Invalid) Opcode.
86	dd 0 ; 7 - #NM - F - N - Device not available, FP or (F)WAIT instruction.
87	dd 0 ; 8 - #DF - A - 0 - Double fault.
88	dd 0 ; 9 - - F - N - Coprocessor Segment Overrun (obsolete).
89	dd 0 ; a - #TS - F - Y - Invalid TSS, Taskswitch or TSS access.
90	dd NAME(TRPMGCHyperTrap0bHandler) ; b - #NP - F - Y - Segment not present.
91	dd 0 ; c - #SS - F - Y - Stack-Segment fault.
92	dd NAME(TRPMGCHyperTrap0dHandler) ; d - #GP - F - Y - General protection fault.
93	dd NAME(TRPMGCHyperTrap0eHandler) ; e - #PF - F - Y - Page fault.
94	dd 0 ; f - - - - Intel Reserved. Do not use.
95	dd 0 ; 10 - #MF - F - N - x86 FPU Floating-Point Error (Math fault), FP or (F)WAIT instruction.
96	dd 0 ; 11 - #AC - F - 0 - Alignment Check.
97	dd 0 ; 12 - #MC - A - N - Machine Check.
98	dd 0 ; 13 - #XF - F - N - SIMD Floating-Point Exception.
99	dd 0 ; 14 - - - - Intel Reserved. Do not use.
100	dd 0 ; 15 - - - - Intel Reserved. Do not use.
101	dd 0 ; 16 - - - - Intel Reserved. Do not use.
102	dd 0 ; 17 - - - - Intel Reserved. Do not use.
103	dd 0 ; 18 - - - - Intel Reserved. Do not use.
104
105
106	;;
107	; Jump table for trap handlers for guest traps
108	;
109	g_apfnStaticTrapHandlersGuest:
110	; N - M M - T - C - D i
111	; o - n o - y - o - e p
112	; - e n - p - d - s t
113	; - i - e - e - c .
114	; - c - - - r
115	; =============================================================
116	dd 0 ; 0 - #DE - F - N - Divide error
117	dd NAME(TRPMGCTrap01Handler) ; 1 - #DB - F/T - N - Single step, INT 1 instruction
118	%ifdef VBOX_WITH_NMI
119	dd NAME(TRPMGCTrap02Handler) ; 2 - - I - N - Non-Maskable Interrupt (NMI)
120	%else
121	dd 0 ; 2 - - I - N - Non-Maskable Interrupt (NMI)
122	%endif
123	dd NAME(TRPMGCTrap03Handler) ; 3 - #BP - T - N - Breakpoint, INT 3 instruction.
124	dd 0 ; 4 - #OF - T - N - Overflow, INTO instruction.
125	dd 0 ; 5 - #BR - F - N - BOUND Range Exceeded, BOUND instruction.
126	dd NAME(TRPMGCTrap06Handler) ; 6 - #UD - F - N - Undefined(/Invalid) Opcode.
127	dd NAME(TRPMGCTrap07Handler) ; 7 - #NM - F - N - Device not available, FP or (F)WAIT instruction.
128	dd 0 ; 8 - #DF - A - 0 - Double fault.
129	dd 0 ; 9 - - F - N - Coprocessor Segment Overrun (obsolete).
130	dd 0 ; a - #TS - F - Y - Invalid TSS, Taskswitch or TSS access.
131	dd NAME(TRPMGCTrap0bHandler) ; b - #NP - F - Y - Segment not present.
132	dd 0 ; c - #SS - F - Y - Stack-Segment fault.
133	dd NAME(TRPMGCTrap0dHandler) ; d - #GP - F - Y - General protection fault.
134	dd NAME(TRPMGCTrap0eHandler) ; e - #PF - F - Y - Page fault.
135	dd 0 ; f - - - - Intel Reserved. Do not use.
136	dd 0 ; 10 - #MF - F - N - x86 FPU Floating-Point Error (Math fault), FP or (F)WAIT instruction.
137	dd 0 ; 11 - #AC - F - 0 - Alignment Check.
138	dd 0 ; 12 - #MC - A - N - Machine Check.
139	dd 0 ; 13 - #XF - F - N - SIMD Floating-Point Exception.
140	dd 0 ; 14 - - - - Intel Reserved. Do not use.
141	dd 0 ; 15 - - - - Intel Reserved. Do not use.
142	dd 0 ; 16 - - - - Intel Reserved. Do not use.
143	dd 0 ; 17 - - - - Intel Reserved. Do not use.
144	dd 0 ; 18 - - - - Intel Reserved. Do not use.
145
146
147
148	;;
149	; We start by 24 push <vector no.> + jmp <generic entry point>
150	;
151	ALIGNCODE(16)
152	BEGINPROC_EXPORTED TRPMGCHandlerGeneric
153	%macro TRPMGenericEntry 1
154	db 06ah, i ; push imm8 - note that this is a signextended value.
155	jmp %1
156	ALIGNCODE(8)
157	%assign i i+1
158	%endmacro
159
160	%assign i 0 ; start counter.
161	TRPMGenericEntry GenericTrap ; 0
162	TRPMGenericEntry GenericTrap ; 1
163	TRPMGenericEntry GenericTrap ; 2
164	TRPMGenericEntry GenericTrap ; 3
165	TRPMGenericEntry GenericTrap ; 4
166	TRPMGenericEntry GenericTrap ; 5
167	TRPMGenericEntry GenericTrap ; 6
168	TRPMGenericEntry GenericTrap ; 7
169	TRPMGenericEntry GenericTrapErrCode ; 8
170	TRPMGenericEntry GenericTrap ; 9
171	TRPMGenericEntry GenericTrapErrCode ; a
172	TRPMGenericEntry GenericTrapErrCode ; b
173	TRPMGenericEntry GenericTrapErrCode ; c
174	TRPMGenericEntry GenericTrapErrCode ; d
175	TRPMGenericEntry GenericTrapErrCode ; e
176	TRPMGenericEntry GenericTrap ; f (reserved)
177	TRPMGenericEntry GenericTrap ; 10
178	TRPMGenericEntry GenericTrapErrCode ; 11
179	TRPMGenericEntry GenericTrap ; 12
180	TRPMGenericEntry GenericTrap ; 13
181	TRPMGenericEntry GenericTrap ; 14 (reserved)
182	TRPMGenericEntry GenericTrap ; 15 (reserved)
183	TRPMGenericEntry GenericTrap ; 16 (reserved)
184	TRPMGenericEntry GenericTrap ; 17 (reserved)
185	%undef i
186	%undef TRPMGenericEntry
187
188	;;
189	; Main exception handler for the guest context
190	;
191	; Stack:
192	; 14 SS
193	; 10 ESP
194	; c EFLAGS
195	; 8 CS
196	; 4 EIP
197	; 0 vector number
198	;
199	; @uses none
200	;
201	ALIGNCODE(8)
202	GenericTrap:
203	;
204	; for the present we fake an error code ~0
205	;
206	push eax
207	mov eax, 0ffffffffh
208	xchg [esp + 4], eax ; get vector number, set error code
209	xchg [esp], eax ; get saved eax, set vector number
210	jmp short GenericTrapErrCode
211
212
213	;;
214	; Main exception handler for the guest context with error code
215	;
216	; Stack:
217	; 28 GS (V86 only)
218	; 24 FS (V86 only)
219	; 20 DS (V86 only)
220	; 1C ES (V86 only)
221	; 18 SS (only if ring transition.)
222	; 14 ESP (only if ring transition.)
223	; 10 EFLAGS
224	; c CS
225	; 8 EIP
226	; 4 Error code. (~0 for vectors which don't take an error code.)
227	; 0 vector number
228	;
229	; Error code:
230	;
231	; 31 16 15 3 2 1 0
232	;
233	; reserved segment TI IDT EXT
234	; selector GDT/LDT (1) IDT External interrupt
235	; index (IDT=0) index
236	;
237	; NOTE: Page faults (trap 14) have a different error code
238	;
239	; @uses none
240	;
241	ALIGNCODE(8)
242	GenericTrapErrCode:
243	cld
244
245	;
246	; Setup CPUMCTXCORE frame
247	;
248	; ASSUMPTION: If trap in hypervisor, we assume that we can read two dword
249	; under the bottom of the stack. This is atm safe.
250	; ASSUMPTION: There is sufficient stack space.
251	; ASSUMPTION: The stack is not write protected.
252	;
253	%define ESPOFF CPUMCTXCORE_size
254
255	sub esp, CPUMCTXCORE_size
256	mov [esp + CPUMCTXCORE.eax], eax
257	mov [esp + CPUMCTXCORE.ecx], ecx
258	mov [esp + CPUMCTXCORE.edx], edx
259	mov [esp + CPUMCTXCORE.ebx], ebx
260	mov [esp + CPUMCTXCORE.esi], esi
261	mov [esp + CPUMCTXCORE.edi], edi
262	mov [esp + CPUMCTXCORE.ebp], ebp
263
264	mov eax, [esp + 14h + ESPOFF] ; esp
265	mov [esp + CPUMCTXCORE.esp], eax
266	mov eax, [esp + 18h + ESPOFF] ; ss
267	mov dword [esp + CPUMCTXCORE.ss], eax
268
269	mov eax, [esp + 0ch + ESPOFF] ; cs
270	mov dword [esp + CPUMCTXCORE.cs], eax
271	mov eax, [esp + 08h + ESPOFF] ; eip
272	mov [esp + CPUMCTXCORE.eip], eax
273	mov eax, [esp + 10h + ESPOFF] ; eflags
274	mov [esp + CPUMCTXCORE.eflags], eax
275
276	mov eax, es
277	mov dword [esp + CPUMCTXCORE.es], eax
278	mov eax, ds
279	mov dword [esp + CPUMCTXCORE.ds], eax
280	mov eax, fs
281	mov dword [esp + CPUMCTXCORE.fs], eax
282	mov eax, gs
283	mov dword [esp + CPUMCTXCORE.gs], eax
284
285	test dword [esp + CPUMCTXCORE.eflags], X86_EFL_VM
286	jz short gt_SkipV86Entry
287
288	;
289	; The DS, ES, FS and GS registers are zeroed in V86 mode and their real values are on the stack
290	;
291	mov eax, dword [esp + ESPOFF + 1Ch]
292	mov dword [esp + CPUMCTXCORE.es], eax
293
294	mov eax, dword [esp + ESPOFF + 20h]
295	mov dword [esp + CPUMCTXCORE.ds], eax
296
297	mov eax, dword [esp + ESPOFF + 24h]
298	mov dword [esp + CPUMCTXCORE.fs], eax
299
300	mov eax, dword [esp + ESPOFF + 28h]
301	mov dword [esp + CPUMCTXCORE.gs], eax
302
303	gt_SkipV86Entry:
304	;
305	; Disable Ring-0 WP
306	;
307	mov eax, cr0 ;; @todo elimitate this read?
308	and eax, ~X86_CR0_WRITE_PROTECT
309	mov cr0, eax
310
311	;
312	; Load Hypervisor DS and ES (get it from the SS)
313	;
314	mov eax, ss
315	mov ds, eax
316	mov es, eax
317
318	%ifdef VBOX_WITH_STATISTICS
319	;
320	; Start profiling.
321	;
322	mov edx, [esp + 0h + ESPOFF] ; vector number
323	imul edx, edx, byte STAMPROFILEADV_size ; assumes < 128.
324	add edx, TRPM.aStatGCTraps
325	add edx, IMP(g_TRPM)
326	STAM_PROFILE_ADV_START edx
327	%endif
328
329	;
330	; Store the information about the active trap/interrupt.
331	;
332	mov eax, IMP(g_TRPM)
333	movzx edx, byte [esp + 0h + ESPOFF] ; vector number
334	mov [eax + TRPM.uActiveVector], edx
335	mov edx, [esp + 4h + ESPOFF] ; error code
336	mov [eax + TRPM.uActiveErrorCode], edx
337	mov dword [eax + TRPM.enmActiveType], TRPM_TRAP
338	mov edx, cr2 ;; @todo Check how expensive cr2 reads are!
339	mov dword [eax + TRPM.uActiveCR2], edx
340
341	;
342	; Check if we're in Hypervisor when this happend.
343	;
344	test dword [esp + CPUMCTXCORE.eflags], X86_EFL_VM
345	jnz short gt_NotHyperVisor
346
347	test byte [esp + 0ch + ESPOFF], 3h ; check CPL of the cs selector
348	jz near gt_InHypervisor
349
350	;
351	; Trap in guest code.
352	;
353	gt_NotHyperVisor:
354	%ifdef DEBUG_STUFF_TRPG
355	mov ebx, [esp + 4h + ESPOFF] ; error code
356	mov ecx, 'trpG' ; indicate trap.
357	mov edx, [esp + 0h + ESPOFF] ; vector number
358	lea eax, [esp]
359	call trpmDbgDumpRegisterFrame
360	%endif
361
362	;
363	; Do we have a GC handler for these traps?
364	;
365	mov edx, [esp + 0h + ESPOFF] ; vector number
366	mov eax, [g_apfnStaticTrapHandlersGuest + edx * 4]
367	or eax, eax
368	jnz short gt_HaveHandler
369	mov eax, VINF_EM_RAW_GUEST_TRAP
370	jmp short gt_GuestTrap
371
372	;
373	; Call static handler.
374	;
375	gt_HaveHandler:
376	push esp ; Param 2 - CPUMCTXCORE pointer.
377	push dword IMP(g_TRPM) ; Param 1 - Pointer to TRPM
378	call eax
379	add esp, byte 8 ; cleanup stack (cdecl)
380	or eax, eax
381	je near gt_continue_guest
382
383	;
384	; Switch back to the host and process it there.
385	;
386	gt_GuestTrap:
387	%ifdef VBOX_WITH_STATISTICS
388	mov edx, [esp + 0h + ESPOFF] ; vector number
389	imul edx, edx, byte STAMPROFILEADV_size ; assume < 128
390	add edx, IMP(g_TRPM)
391	add edx, TRPM.aStatGCTraps
392	STAM_PROFILE_ADV_STOP edx
393	%endif
394	mov edx, IMP(g_VM)
395	call [edx + VM.pfnVMMGCGuestToHostAsmGuestCtx]
396
397	;; @todo r=bird: is this path actually every taken? if not we should replace this code with a panic.
398	;
399	; We've returned!
400	; N.B. The stack has been changed now! No CPUMCTXCORE any longer. esp = vector number.
401	; N.B. Current scheduling design causes this code path to be unused.
402	; N.B. Better not use it when in V86 mode!
403	;
404
405	; Enable WP
406	mov eax, cr0 ;; @todo try elimiate this read.
407	or eax, X86_CR0_WRITE_PROTECT
408	mov cr0, eax
409	; Restore guest context and continue execution.
410	mov edx, IMP(g_CPUM)
411	lea eax, [esp + 8]
412	push eax
413	call NAME(CPUMGCRestoreInt)
414	lea esp, [esp + 0ch] ; cleanup call and skip vector & error code.
415
416	iret
417
418
419	;
420	; Continue(/Resume/Restart/Whatever) guest execution.
421	;
422	ALIGNCODE(16)
423	gt_continue_guest:
424	%ifdef VBOX_WITH_STATISTICS
425	mov edx, [esp + 0h + ESPOFF] ; vector number
426	imul edx, edx, byte STAMPROFILEADV_size ; assumes < 128
427	add edx, TRPM.aStatGCTraps
428	add edx, IMP(g_TRPM)
429	STAM_PROFILE_ADV_STOP edx
430	%endif
431
432	; enable WP
433	mov eax, cr0 ;; @todo try elimiate this read.
434	or eax, X86_CR0_WRITE_PROTECT
435	mov cr0, eax
436
437	; restore guest state and start executing again.
438	test dword [esp + CPUMCTXCORE.eflags], X86_EFL_VM
439	jnz gt_V86Return
440
441	mov ecx, [esp + CPUMCTXCORE.ecx]
442	mov edx, [esp + CPUMCTXCORE.edx]
443	mov ebx, [esp + CPUMCTXCORE.ebx]
444	mov ebp, [esp + CPUMCTXCORE.ebp]
445	mov esi, [esp + CPUMCTXCORE.esi]
446	mov edi, [esp + CPUMCTXCORE.edi]
447
448	mov eax, [esp + CPUMCTXCORE.esp]
449	mov [esp + 14h + ESPOFF], eax ; esp
450	mov eax, dword [esp + CPUMCTXCORE.ss]
451	mov [esp + 18h + ESPOFF], eax ; ss
452
453	mov eax, dword [esp + CPUMCTXCORE.gs]
454	TRPM_NP_GP_HANDLER NAME(trpmGCTrapInGeneric), TRPM_TRAP_IN_MOV_GS
455	mov gs, eax
456
457	mov eax, dword [esp + CPUMCTXCORE.fs]
458	TRPM_NP_GP_HANDLER NAME(trpmGCTrapInGeneric), TRPM_TRAP_IN_MOV_FS
459	mov fs, eax
460
461	mov eax, dword [esp + CPUMCTXCORE.es]
462	TRPM_NP_GP_HANDLER NAME(trpmGCTrapInGeneric), TRPM_TRAP_IN_MOV_ES
463	mov es, eax
464
465	mov eax, dword [esp + CPUMCTXCORE.ds]
466	TRPM_NP_GP_HANDLER NAME(trpmGCTrapInGeneric), TRPM_TRAP_IN_MOV_DS
467	mov ds, eax
468
469	mov eax, dword [esp + CPUMCTXCORE.cs]
470	mov [esp + 0ch + ESPOFF], eax ; cs
471	mov eax, [esp + CPUMCTXCORE.eflags]
472	mov [esp + 10h + ESPOFF], eax ; eflags
473	mov eax, [esp + CPUMCTXCORE.eip]
474	mov [esp + 08h + ESPOFF], eax ; eip
475
476	; finally restore our scratch register eax
477	mov eax, [esp + CPUMCTXCORE.eax]
478
479	add esp, ESPOFF + 8 ; skip CPUMCTXCORE structure, error code and vector number
480
481	TRPM_NP_GP_HANDLER NAME(trpmGCTrapInGeneric), TRPM_TRAP_IN_IRET
482	iret
483
484	ALIGNCODE(16)
485	gt_V86Return:
486	mov ecx, [esp + CPUMCTXCORE.ecx]
487	mov edx, [esp + CPUMCTXCORE.edx]
488	mov ebx, [esp + CPUMCTXCORE.ebx]
489	mov ebp, [esp + CPUMCTXCORE.ebp]
490	mov esi, [esp + CPUMCTXCORE.esi]
491	mov edi, [esp + CPUMCTXCORE.edi]
492
493	mov eax, [esp + CPUMCTXCORE.esp]
494	mov [esp + 14h + ESPOFF], eax ; esp
495	mov eax, dword [esp + CPUMCTXCORE.ss]
496	mov [esp + 18h + ESPOFF], eax ; ss
497
498	mov eax, dword [esp + CPUMCTXCORE.es]
499	mov [esp + 1ch + ESPOFF], eax ; es
500	mov eax, dword [esp + CPUMCTXCORE.ds]
501	mov [esp + 20h + ESPOFF], eax ; ds
502	mov eax, dword [esp + CPUMCTXCORE.fs]
503	mov [esp + 24h + ESPOFF], eax ; fs
504	mov eax, dword [esp + CPUMCTXCORE.gs]
505	mov [esp + 28h + ESPOFF], eax ; gs
506
507	mov eax, [esp + CPUMCTXCORE.eip]
508	mov [esp + 08h + ESPOFF], eax ; eip
509	mov eax, dword [esp + CPUMCTXCORE.cs]
510	mov [esp + 0ch + ESPOFF], eax ; cs
511	mov eax, [esp + CPUMCTXCORE.eflags]
512	mov [esp + 10h + ESPOFF], eax ; eflags
513
514	; finally restore our scratch register eax
515	mov eax, [esp + CPUMCTXCORE.eax]
516
517	add esp, ESPOFF + 8 ; skip CPUMCTXCORE structure, error code and vector number
518
519	TRPM_NP_GP_HANDLER NAME(trpmGCTrapInGeneric), TRPM_TRAP_IN_IRET \| TRPM_TRAP_IN_V86
520	iret
521
522	;
523	; Trap in Hypervisor, try to handle it.
524	;
525	; (eax = pTRPM)
526	;
527	ALIGNCODE(16)
528	gt_InHypervisor:
529	; fix ss:esp.
530	lea ebx, [esp + 14h + ESPOFF] ; calc esp at trap
531	mov [esp + CPUMCTXCORE.esp], ebx; update esp in register frame
532	mov [esp + CPUMCTXCORE.ss], ss ; update ss in register frame
533
534	; tell cpum about the context core.
535	xchg esi, eax ; save pTRPM - @todo reallocate this variable to esi, edi, or ebx
536	push esp ; Param 2 - The new CPUMCTXCORE pointer.
537	push IMP(g_VM) ; Param 1 - Pointer to the VM.
538	call NAME(CPUMHyperSetCtxCore)
539	add esp, byte 8 ; stack cleanup (cdecl)
540	xchg eax, esi ; restore pTRPM
541
542	; check for temporary handler.
543	movzx ebx, byte [eax + TRPM.uActiveVector]
544	xor ecx, ecx
545	xchg ecx, [eax + TRPM.aTmpTrapHandlers + ebx * 4] ; ecx = Temp handler pointer or 0
546	or ecx, ecx
547	jnz short gt_Hyper_HaveTemporaryHandler
548
549	; check for static trap handler.
550	mov ecx, [g_apfnStaticTrapHandlersHyper + ebx * 4] ; ecx = Static handler pointer or 0
551	or ecx, ecx
552	jnz short gt_Hyper_HaveStaticHandler
553	jmp gt_Hyper_AbandonShip
554
555
556	;
557	; Temporary trap handler present, call it (CDECL).
558	;
559	gt_Hyper_HaveTemporaryHandler:
560	push esp ; Param 2 - Pointer to CPUMCTXCORE.
561	push IMP(g_VM) ; Param 1 - Pointer to VM.
562	call ecx
563	add esp, byte 8 ; cleanup stack (cdecl)
564
565	cmp eax, byte VINF_SUCCESS ; If completely handled Then resume execution.
566	je near gt_Hyper_Continue
567	;; @todo Handle ALL returns types from temporary handlers!
568	jmp gt_Hyper_AbandonShip
569
570
571	;
572	; Static trap handler present, call it (CDECL).
573	;
574	gt_Hyper_HaveStaticHandler:
575	push esp ; Param 2 - Pointer to CPUMCTXCORE.
576	push eax ; Param 1 - Pointer to TRPM
577	call ecx
578	add esp, byte 8 ; cleanup stack (cdecl)
579
580	cmp eax, byte VINF_SUCCESS ; If completely handled Then resume execution.
581	je short gt_Hyper_Continue
582	cmp eax, VINF_EM_DBG_HYPER_STEPPED
583	je short gt_Hyper_ToHost
584	cmp eax, VINF_EM_DBG_HYPER_BREAKPOINT
585	je short gt_Hyper_ToHost
586	cmp eax, VINF_EM_DBG_HYPER_ASSERTION
587	je short gt_Hyper_ToHost
588	jmp gt_Hyper_AbandonShip
589
590	;
591	; Pop back to the host to service the error.
592	;
593	gt_Hyper_ToHost:
594	mov ecx, esp
595	mov edx, IMP(g_VM)
596	call [edx + VM.pfnVMMGCGuestToHostAsm]
597	jmp short gt_Hyper_Continue
598
599	;
600	; Continue(/Resume/Restart/Whatever) hypervisor execution.
601	; Don't reset the TRPM state. Caller takes care of that.
602	;
603	ALIGNCODE(16)
604	gt_Hyper_Continue:
605	%ifdef DEBUG_STUFF
606	mov ebx, [esp + 4h + ESPOFF] ; error code
607	mov ecx, 'resH' ; indicate trap.
608	mov edx, [esp + 0h + ESPOFF] ; vector number
609	lea eax, [esp]
610	call trpmDbgDumpRegisterFrame
611	%endif
612	; tell CPUM to use the default CPUMCTXCORE.
613	push byte 0 ; Param 2 - NULL indicating use default context core.
614	push IMP(g_VM) ; Param 1 - The VM pointer.
615	call NAME(CPUMHyperSetCtxCore)
616	add esp, byte 8 ; stack cleanup (cdecl)
617
618	%ifdef VBOX_WITH_STATISTICS
619	mov edx, [esp + 0h + ESPOFF] ; vector number
620	imul edx, edx, byte STAMPROFILEADV_size ; assumes < 128
621	add edx, TRPM.aStatGCTraps
622	add edx, IMP(g_TRPM)
623	STAM_PROFILE_ADV_STOP edx
624	%endif
625
626	; restore
627	mov ecx, [esp + CPUMCTXCORE.ecx]
628	mov edx, [esp + CPUMCTXCORE.edx]
629	mov ebx, [esp + CPUMCTXCORE.ebx]
630	mov ebp, [esp + CPUMCTXCORE.ebp]
631	mov esi, [esp + CPUMCTXCORE.esi]
632	mov edi, [esp + CPUMCTXCORE.edi]
633
634	mov eax, dword [esp + CPUMCTXCORE.gs]
635	TRPM_NP_GP_HANDLER NAME(trpmGCTrapInGeneric), TRPM_TRAP_IN_MOV_GS \| TRPM_TRAP_IN_HYPER
636	mov gs, eax
637
638	mov eax, dword [esp + CPUMCTXCORE.fs]
639	TRPM_NP_GP_HANDLER NAME(trpmGCTrapInGeneric), TRPM_TRAP_IN_MOV_FS \| TRPM_TRAP_IN_HYPER
640	mov fs, eax
641
642	mov eax, dword [esp + CPUMCTXCORE.es]
643	mov es, eax
644	mov eax, dword [esp + CPUMCTXCORE.ds]
645	mov ds, eax
646
647	; skip esp & ss
648
649	mov eax, [esp + CPUMCTXCORE.eip]
650	mov [esp + 08h + ESPOFF], eax ; eip
651	mov eax, dword [esp + CPUMCTXCORE.cs]
652	mov [esp + 0ch + ESPOFF], eax ; cs
653	mov eax, [esp + CPUMCTXCORE.eflags]
654	mov [esp + 10h + ESPOFF], eax ; eflags
655
656	; finally restore our scratch register eax
657	mov eax, [esp + CPUMCTXCORE.eax]
658
659	add esp, ESPOFF + 8 ; skip CPUMCTXCORE structure, error code and vector number
660
661	iret
662
663
664	;
665	; ABANDON SHIP! DON'T PANIC!
666	;
667	gt_Hyper_AbandonShip:
668	%ifdef DEBUG_STUFF
669	mov ebx, [esp + 4h + ESPOFF] ; error code
670	mov ecx, 'trpH' ; indicate trap.
671	mov edx, [esp + 0h + ESPOFF] ; vector number
672	lea eax, [esp]
673	call trpmDbgDumpRegisterFrame
674	%endif
675
676	gt_Hyper_DontPanic:
677	mov ecx, esp
678	mov edx, IMP(g_VM)
679	mov eax, VERR_TRPM_DONT_PANIC
680	call [edx + VM.pfnVMMGCGuestToHostAsmHyperCtx]
681	%ifdef DEBUG_STUFF
682	COM_S_PRINT 'bad!!!'
683	%endif
684	jmp gt_Hyper_DontPanic ; this shall never ever happen!
685	%undef ESPOFF
686	ENDPROC TRPMGCHandlerGeneric
687
688
689
690
691
692	;;
693	; We start by 256 push <vector no.> + jmp interruptworker
694	;
695	ALIGNCODE(16)
696	BEGINPROC_EXPORTED TRPMGCHandlerInterupt
697	; NASM has some nice features, here an example of a loop.
698	%assign i 0
699	%rep 256
700	db 06ah, i ; push imm8 - note that this is a signextended value.
701	jmp ti_GenericInterrupt
702	ALIGNCODE(8)
703	%assign i i+1
704	%endrep
705
706	;;
707	; Main interrupt handler for the guest context
708	;
709	; Stack:
710	; 24 GS (V86 only)
711	; 20 FS (V86 only)
712	; 1C DS (V86 only)
713	; 18 ES (V86 only)
714	; 14 SS
715	; 10 ESP
716	; c EFLAGS
717	; 8 CS
718	; 4 EIP
719	; ESP -> 0 Vector number (only use low byte!).
720	;
721	; @uses none
722	ti_GenericInterrupt:
723	cld
724
725	;
726	; Setup CPUMCTXCORE frame
727	;
728	; ASSUMPTION: If trap in hypervisor, we assume that we can read two dword
729	; under the bottom of the stack. This is atm safe.
730	; ASSUMPTION: There is sufficient stack space.
731	; ASSUMPTION: The stack is not write protected.
732	;
733	%define ESPOFF CPUMCTXCORE_size
734
735	sub esp, CPUMCTXCORE_size
736	mov [esp + CPUMCTXCORE.eax], eax
737	mov [esp + CPUMCTXCORE.ecx], ecx
738	mov [esp + CPUMCTXCORE.edx], edx
739	mov [esp + CPUMCTXCORE.ebx], ebx
740	mov [esp + CPUMCTXCORE.esi], esi
741	mov [esp + CPUMCTXCORE.edi], edi
742	mov [esp + CPUMCTXCORE.ebp], ebp
743
744	mov eax, [esp + 04h + ESPOFF] ; eip
745	mov [esp + CPUMCTXCORE.eip], eax
746	mov eax, dword [esp + 08h + ESPOFF] ; cs
747	mov [esp + CPUMCTXCORE.cs], eax
748	mov eax, [esp + 0ch + ESPOFF] ; eflags
749	mov [esp + CPUMCTXCORE.eflags], eax
750
751	mov eax, [esp + 10h + ESPOFF] ; esp
752	mov [esp + CPUMCTXCORE.esp], eax
753	mov eax, dword [esp + 14h + ESPOFF] ; ss
754	mov [esp + CPUMCTXCORE.ss], eax
755
756	mov eax, es
757	mov dword [esp + CPUMCTXCORE.es], eax
758	mov eax, ds
759	mov dword [esp + CPUMCTXCORE.ds], eax
760	mov eax, fs
761	mov dword [esp + CPUMCTXCORE.fs], eax
762	mov eax, gs
763	mov dword [esp + CPUMCTXCORE.gs], eax
764
765	test dword [esp + CPUMCTXCORE.eflags], X86_EFL_VM
766	jz short ti_SkipV86Entry
767
768	;
769	; The DS, ES, FS and GS registers are zeroed in V86 mode and their real values are on the stack
770	;
771	mov eax, dword [esp + ESPOFF + 18h]
772	mov dword [esp + CPUMCTXCORE.es], eax
773
774	mov eax, dword [esp + ESPOFF + 1Ch]
775	mov dword [esp + CPUMCTXCORE.ds], eax
776
777	mov eax, dword [esp + ESPOFF + 20h]
778	mov dword [esp + CPUMCTXCORE.fs], eax
779
780	mov eax, dword [esp + ESPOFF + 24h]
781	mov dword [esp + CPUMCTXCORE.gs], eax
782
783	ti_SkipV86Entry:
784
785	;
786	; Disable Ring-0 WP
787	;
788	mov eax, cr0 ;; @todo try elimiate this read.
789	and eax, ~X86_CR0_WRITE_PROTECT
790	mov cr0, eax
791
792	;
793	; Load Hypervisor DS and ES (get it from the SS)
794	;
795	mov eax, ss
796	mov ds, eax
797	mov es, eax
798
799	;
800	; Store the information about the active trap/interrupt.
801	;
802	mov eax, IMP(g_TRPM)
803	movzx edx, byte [esp + 0h + ESPOFF] ; vector number
804	mov [eax + TRPM.uActiveVector], edx
805	xor edx, edx
806	mov dword [eax + TRPM.enmActiveType], TRPM_HARDWARE_INT
807	dec edx
808	mov [eax + TRPM.uActiveErrorCode], edx
809	mov [eax + TRPM.uActiveCR2], edx
810
811	;
812	; Check if we're in Hypervisor when this happend.
813	;
814	test byte [esp + 08h + ESPOFF], 3h ; check CPL of the cs selector
815	jnz short gi_NotHyperVisor
816	jmp gi_HyperVisor
817
818	;
819	; Trap in guest code.
820	;
821	gi_NotHyperVisor:
822	and dword [esp + CPUMCTXCORE.eflags], ~010000h ; Clear RF (Resume Flag). @todo make %defines for eflags.
823	; The guest shall not see this in it's state.
824	%ifdef DEBUG_STUFF_INT
825	mov ecx, 'intG' ; indicate trap.
826	movzx edx, byte [esp + 0h + ESPOFF] ; vector number
827	lea eax, [esp]
828	call trpmDbgDumpRegisterFrame
829	%endif
830
831	;
832	; Switch back to the host and process it there.
833	;
834	mov edx, IMP(g_VM)
835	mov eax, VINF_EM_RAW_INTERRUPT
836	call [edx + VM.pfnVMMGCGuestToHostAsmGuestCtx]
837
838	;
839	; We've returned!
840	; NOTE that the stack has been changed now!
841	; there is no longer any CPUMCTXCORE around and esp points to vector number!
842	;
843	; Reset TRPM state
844	mov eax, IMP(g_TRPM)
845	xor edx, edx
846	dec edx ; edx = 0ffffffffh
847	xchg [eax + TRPM.uActiveVector], edx
848	mov [eax + TRPM.uPrevVector], edx
849
850	; Enable WP
851	mov eax, cr0 ;; @todo try elimiate this read.
852	or eax, X86_CR0_WRITE_PROTECT
853	mov cr0, eax
854	; restore guest context and continue execution.
855	lea eax, [esp + 8]
856	push eax
857	call NAME(CPUMGCRestoreInt)
858	lea esp, [esp + 0ch] ; cleanup call and skip vector & error code.
859
860	iret
861
862	; -+- Entry point -+-
863	;
864	; We're in hypervisor mode which means no guest context
865	; and special care to be taken to restore the hypervisor
866	; context correctely.
867	;
868	; ATM the only place this can happen is when entering a trap handler.
869	; We make ASSUMPTIONS about this in respects to the WP CR0 bit
870	;
871	gi_HyperVisor:
872	lea eax, [esp + 14h + ESPOFF] ; calc esp at trap
873	mov [esp + CPUMCTXCORE.esp], eax ; update esp in register frame
874	mov [esp + CPUMCTXCORE.ss], ss ; update ss in register frame
875
876	%ifdef DEBUG_STUFF_INT
877	mov ebx, [esp + 4h + ESPOFF] ; error code
878	mov ecx, 'intH' ; indicate hypervisor interrupt.
879	movzx edx, byte [esp + 0h + ESPOFF] ; vector number
880	lea eax, [esp]
881	call trpmDbgDumpRegisterFrame
882	%endif
883
884	mov ecx, esp
885	mov edx, IMP(g_VM)
886	mov eax, VINF_EM_RAW_INTERRUPT_HYPER
887	call [edx + VM.pfnVMMGCGuestToHostAsm]
888	%ifdef DEBUG_STUFF_INT
889	COM_CHAR '!'
890	%endif
891
892	;
893	; We've returned!
894	;
895	; Reset TRPM state - don't record this.
896	mov eax, IMP(g_TRPM)
897	mov dword [eax + TRPM.uActiveVector], 0ffffffffh
898
899	;
900	; Restore the hypervisor context and return.
901	;
902	mov ecx, [esp + CPUMCTXCORE.ecx]
903	mov edx, [esp + CPUMCTXCORE.edx]
904	mov ebx, [esp + CPUMCTXCORE.ebx]
905	mov ebp, [esp + CPUMCTXCORE.ebp]
906	mov esi, [esp + CPUMCTXCORE.esi]
907	mov edi, [esp + CPUMCTXCORE.edi]
908
909	; In V86 mode DS, ES, FS & GS are restored by the iret
910	test dword [esp + CPUMCTXCORE.eflags], X86_EFL_VM
911	jnz short ti_SkipSelRegs
912
913	mov eax, [esp + CPUMCTXCORE.gs]
914	TRPM_NP_GP_HANDLER NAME(trpmGCTrapInGeneric), TRPM_TRAP_IN_MOV_GS \| TRPM_TRAP_IN_HYPER
915	mov gs, eax
916
917	mov eax, [esp + CPUMCTXCORE.fs]
918	TRPM_NP_GP_HANDLER NAME(trpmGCTrapInGeneric), TRPM_TRAP_IN_MOV_FS \| TRPM_TRAP_IN_HYPER
919	mov fs, eax
920
921	mov eax, [esp + CPUMCTXCORE.es]
922	mov es, eax
923	mov eax, [esp + CPUMCTXCORE.ds]
924	mov ds, eax
925
926	ti_SkipSelRegs:
927	; finally restore our scratch register eax
928	mov eax, [esp + CPUMCTXCORE.eax]
929
930	; skip esp, ss, cs, eip & eflags. Done by iret
931
932	add esp, ESPOFF + 4h ; skip CPUMCTXCORE structure & vector number.
933
934	iret
935	%undef ESPOFF
936	ENDPROC TRPMGCHandlerInterupt
937
938
939
940	;;
941	; Trap handler for #MC
942	;
943	; This handler will forward the #MC to the host OS. Since this
944	; is generalized in the generic interrupt handler, we just disable
945	; interrupts and push vector number and jump to the generic code.
946	;
947	; Stack:
948	; 10 SS (only if ring transition.)
949	; c ESP (only if ring transition.)
950	; 8 EFLAGS
951	; 4 CS
952	; 0 EIP
953	;
954	; @uses none
955	;
956	ALIGNCODE(16)
957	BEGINPROC_EXPORTED TRPMGCHandlerTrap12
958	push byte 12h
959	jmp ti_GenericInterrupt
960	ENDPROC TRPMGCHandlerTrap12
961
962
963
964
965	;;
966	; Trap handler for double fault (#DF).
967	;
968	; This is a special trap handler executes in separate task with own TSS, with
969	; one of the intermediate memory contexts instead of the shadow context.
970	; The handler will unconditionally print an report to the comport configured
971	; for the COM_S_* macros before attempting to return to the host. If it it ends
972	; up double faulting more than 10 times, it will simply cause an tripple fault
973	; to get us out of the mess.
974	;
975	; @param esp Half way down the hypvervisor stack + the trap frame.
976	; @param ebp Half way down the hypvervisor stack.
977	; @param eflags Interrupts disabled, nested flag is probably set (we don't care).
978	; @param ecx The address of the hypervisor TSS.
979	; @param edi Same as ecx.
980	; @param eax Same as ecx.
981	; @param edx Address of the VM structure.
982	; @param esi Same as edx.
983	; @param ebx Same as edx.
984	; @param ss Hypervisor DS.
985	; @param ds Hypervisor DS.
986	; @param es Hypervisor DS.
987	; @param fs 0
988	; @param gs 0
989	;
990	;
991	; @remark To be able to catch errors with WP turned off, it is required that the
992	; TSS GDT descriptor and the TSSes are writable (X86_PTE_RW). See SELM.cpp
993	; for how to enable this.
994	;
995	; @remark It is not safe to resume the VMM after a double fault. (At least not
996	; without clearing the busy flag of the TssTrap8 and fixing whatever cause it.)
997	;
998	ALIGNCODE(16)
999	BEGINPROC_EXPORTED TRPMGCHandlerTrap08
1000	; be careful.
1001	cli
1002	cld
1003
1004	;
1005	; Load Hypervisor DS and ES (get it from the SS) - paranoia, but the TSS could be overwritten.. :)
1006	;
1007	mov eax, ss
1008	mov ds, eax
1009	mov es, eax
1010
1011	COM_S_PRINT 10,13,'* Guru Mediation 00000008 - Double Fault! *',10,13
1012
1013	;
1014	; Disable write protection.
1015	;
1016	mov eax, cr0
1017	and eax, ~X86_CR0_WRITE_PROTECT
1018	mov cr0, eax
1019
1020
1021	COM_S_PRINT 'VM='
1022	COM_S_DWORD_REG edx
1023	COM_S_PRINT ' prevTSS='
1024	COM_S_DWORD_REG ecx
1025	COM_S_PRINT ' prevCR3='
1026	mov eax, [ecx + VBOXTSS.cr3]
1027	COM_S_DWORD_REG eax
1028	COM_S_PRINT ' prevLdtr='
1029	movzx eax, word [ecx + VBOXTSS.selLdt]
1030	COM_S_DWORD_REG eax
1031	COM_S_NEWLINE
1032
1033	;
1034	; Create CPUMCTXCORE structure.
1035	;
1036	sub esp, CPUMCTXCORE_size
1037
1038	mov eax, [ecx + VBOXTSS.eip]
1039	mov [esp + CPUMCTXCORE.eip], eax
1040	mov eax, [ecx + VBOXTSS.eflags]
1041	mov [esp + CPUMCTXCORE.eflags], eax
1042
1043	movzx eax, word [ecx + VBOXTSS.cs]
1044	mov dword [esp + CPUMCTXCORE.cs], eax
1045	movzx eax, word [ecx + VBOXTSS.ds]
1046	mov dword [esp + CPUMCTXCORE.ds], eax
1047	movzx eax, word [ecx + VBOXTSS.es]
1048	mov dword [esp + CPUMCTXCORE.es], eax
1049	movzx eax, word [ecx + VBOXTSS.fs]
1050	mov dword [esp + CPUMCTXCORE.fs], eax
1051	movzx eax, word [ecx + VBOXTSS.gs]
1052	mov dword [esp + CPUMCTXCORE.gs], eax
1053	movzx eax, word [ecx + VBOXTSS.ss]
1054	mov [esp + CPUMCTXCORE.ss], eax
1055	mov eax, [ecx + VBOXTSS.esp]
1056	mov [esp + CPUMCTXCORE.esp], eax
1057	mov eax, [ecx + VBOXTSS.ecx]
1058	mov [esp + CPUMCTXCORE.ecx], eax
1059	mov eax, [ecx + VBOXTSS.edx]
1060	mov [esp + CPUMCTXCORE.edx], eax
1061	mov eax, [ecx + VBOXTSS.ebx]
1062	mov [esp + CPUMCTXCORE.ebx], eax
1063	mov eax, [ecx + VBOXTSS.eax]
1064	mov [esp + CPUMCTXCORE.eax], eax
1065	mov eax, [ecx + VBOXTSS.ebp]
1066	mov [esp + CPUMCTXCORE.ebp], eax
1067	mov eax, [ecx + VBOXTSS.esi]
1068	mov [esp + CPUMCTXCORE.esi], eax
1069	mov eax, [ecx + VBOXTSS.edi]
1070	mov [esp + CPUMCTXCORE.edi], eax
1071
1072	;
1073	; Show regs
1074	;
1075	mov ebx, 0ffffffffh
1076	mov ecx, 'trpH' ; indicate trap.
1077	mov edx, 08h ; vector number
1078	lea eax, [esp]
1079	call trpmDbgDumpRegisterFrame
1080
1081	;
1082	; Should we try go back?
1083	;
1084	inc dword [df_Count]
1085	cmp dword [df_Count], byte 10
1086	jb df_to_host
1087	jmp df_tripple_fault
1088	df_Count: dd 0
1089
1090	;
1091	; Try return to the host.
1092	;
1093	df_to_host:
1094	COM_S_PRINT 'Trying to return to host...',10,13
1095	mov ecx, esp
1096	mov edx, IMP(g_VM)
1097	mov eax, VERR_TRPM_PANIC
1098	call [edx + VM.pfnVMMGCGuestToHostAsmHyperCtx]
1099	jmp short df_to_host
1100
1101	;
1102	; Perform a tripple fault.
1103	;
1104	df_tripple_fault:
1105	COM_S_PRINT 'Giving up - tripple faulting the machine...',10,13
1106	push byte 0
1107	push byte 0
1108	sidt [esp]
1109	mov word [esp], 0
1110	lidt [esp]
1111	xor eax, eax
1112	mov dword [eax], 0
1113	jmp df_tripple_fault
1114
1115	ENDPROC TRPMGCHandlerTrap08
1116
1117
1118
1119
1120	;;
1121	; Internal procedure used to dump registers.
1122	;
1123	; @param eax Pointer to CPUMCTXCORE.
1124	; @param edx Vector number
1125	; @param ecx 'trap' if trap, 'int' if interrupt.
1126	; @param ebx Error code if trap.
1127	;
1128	trpmDbgDumpRegisterFrame:
1129	sub esp, byte 8 ; working space for sidt/sgdt/etc
1130
1131	; Init _must_ be done on host before crashing!
1132	; push edx
1133	; push eax
1134	; COM_INIT
1135	; pop eax
1136	; pop edx
1137
1138	cmp ecx, 'trpH'
1139	je near tddrf_trpH
1140	cmp ecx, 'trpG'
1141	je near tddrf_trpG
1142	cmp ecx, 'intH'
1143	je near tddrf_intH
1144	cmp ecx, 'intG'
1145	je near tddrf_intG
1146	cmp ecx, 'resH'
1147	je near tddrf_resH
1148	COM_S_PRINT 10,13,'*** Bogus Dump Code '
1149	jmp tddrf_regs
1150
1151	%if 1 ; the verbose version
1152
1153	tddrf_intG:
1154	COM_S_PRINT 10,13,'*** Interrupt (Guest) '
1155	COM_S_DWORD_REG edx
1156	jmp tddrf_regs
1157
1158	tddrf_intH:
1159	COM_S_PRINT 10,13,'*** Interrupt (Hypervisor) '
1160	COM_S_DWORD_REG edx
1161	jmp tddrf_regs
1162
1163	tddrf_trpG:
1164	COM_S_PRINT 10,13,'*** Trap '
1165	jmp tddrf_trap_rest
1166
1167	%else ; the short version
1168
1169	tddrf_intG:
1170	COM_S_CHAR 'I'
1171	jmp tddrf_ret
1172
1173	tddrf_intH:
1174	COM_S_CHAR 'i'
1175	jmp tddrf_ret
1176
1177	tddrf_trpG:
1178	COM_S_CHAR 'T'
1179	jmp tddrf_ret
1180
1181	%endif ; the short version
1182
1183	tddrf_trpH:
1184	COM_S_PRINT 10,13,'*** Guru Meditation '
1185	jmp tddrf_trap_rest
1186
1187	tddrf_resH:
1188	COM_S_PRINT 10,13,'*** Resuming Hypervisor Trap '
1189	jmp tddrf_trap_rest
1190
1191	tddrf_trap_rest:
1192	COM_S_DWORD_REG edx
1193	COM_S_PRINT ' ErrorCode='
1194	COM_S_DWORD_REG ebx
1195	COM_S_PRINT ' cr2='
1196	mov ecx, cr2
1197	COM_S_DWORD_REG ecx
1198
1199	tddrf_regs:
1200	COM_S_PRINT ' ***',10,13,'cs:eip='
1201	movzx ecx, word [eax + CPUMCTXCORE.cs]
1202	COM_S_DWORD_REG ecx
1203	COM_S_CHAR ':'
1204	mov ecx, [eax + CPUMCTXCORE.eip]
1205	COM_S_DWORD_REG ecx
1206
1207	COM_S_PRINT ' ss:esp='
1208	movzx ecx, word [eax + CPUMCTXCORE.ss]
1209	COM_S_DWORD_REG ecx
1210	COM_S_CHAR ':'
1211	mov ecx, [eax + CPUMCTXCORE.esp]
1212	COM_S_DWORD_REG ecx
1213
1214
1215	sgdt [esp]
1216	COM_S_PRINT 10,13,' gdtr='
1217	movzx ecx, word [esp]
1218	COM_S_DWORD_REG ecx
1219	COM_S_CHAR ':'
1220	mov ecx, [esp + 2]
1221	COM_S_DWORD_REG ecx
1222
1223	sidt [esp]
1224	COM_S_PRINT ' idtr='
1225	movzx ecx, word [esp]
1226	COM_S_DWORD_REG ecx
1227	COM_S_CHAR ':'
1228	mov ecx, [esp + 2]
1229	COM_S_DWORD_REG ecx
1230
1231
1232	str [esp] ; yasm BUG! it generates sldt [esp] here! YASMCHECK!
1233	COM_S_PRINT 10,13,' tr='
1234	movzx ecx, word [esp]
1235	COM_S_DWORD_REG ecx
1236
1237	sldt [esp]
1238	COM_S_PRINT ' ldtr='
1239	movzx ecx, word [esp]
1240	COM_S_DWORD_REG ecx
1241
1242	COM_S_PRINT ' eflags='
1243	mov ecx, [eax + CPUMCTXCORE.eflags]
1244	COM_S_DWORD_REG ecx
1245
1246
1247	COM_S_PRINT 10,13,'cr0='
1248	mov ecx, cr0
1249	COM_S_DWORD_REG ecx
1250
1251	COM_S_PRINT ' cr2='
1252	mov ecx, cr2
1253	COM_S_DWORD_REG ecx
1254
1255	COM_S_PRINT ' cr3='
1256	mov ecx, cr3
1257	COM_S_DWORD_REG ecx
1258	COM_S_PRINT ' cr4='
1259	mov ecx, cr4
1260	COM_S_DWORD_REG ecx
1261
1262
1263	COM_S_PRINT 10,13,' ds='
1264	movzx ecx, word [eax + CPUMCTXCORE.ds]
1265	COM_S_DWORD_REG ecx
1266
1267	COM_S_PRINT ' es='
1268	movzx ecx, word [eax + CPUMCTXCORE.es]
1269	COM_S_DWORD_REG ecx
1270
1271	COM_S_PRINT ' fs='
1272	movzx ecx, word [eax + CPUMCTXCORE.fs]
1273	COM_S_DWORD_REG ecx
1274
1275	COM_S_PRINT ' gs='
1276	movzx ecx, word [eax + CPUMCTXCORE.gs]
1277	COM_S_DWORD_REG ecx
1278
1279
1280	COM_S_PRINT 10,13,'eax='
1281	mov ecx, [eax + CPUMCTXCORE.eax]
1282	COM_S_DWORD_REG ecx
1283
1284	COM_S_PRINT ' ebx='
1285	mov ecx, [eax + CPUMCTXCORE.ebx]
1286	COM_S_DWORD_REG ecx
1287
1288	COM_S_PRINT ' ecx='
1289	mov ecx, [eax + CPUMCTXCORE.ecx]
1290	COM_S_DWORD_REG ecx
1291
1292	COM_S_PRINT ' edx='
1293	mov ecx, [eax + CPUMCTXCORE.edx]
1294	COM_S_DWORD_REG ecx
1295
1296
1297	COM_S_PRINT 10,13,'esi='
1298	mov ecx, [eax + CPUMCTXCORE.esi]
1299	COM_S_DWORD_REG ecx
1300
1301	COM_S_PRINT ' edi='
1302	mov ecx, [eax + CPUMCTXCORE.edi]
1303	COM_S_DWORD_REG ecx
1304
1305	COM_S_PRINT ' ebp='
1306	mov ecx, [eax + CPUMCTXCORE.ebp]
1307	COM_S_DWORD_REG ecx
1308
1309
1310	COM_S_NEWLINE
1311
1312	tddrf_ret:
1313	add esp, byte 8
1314	ret
1315

Note: See TracBrowser for help on using the repository browser.

source: vbox/trunk/src/VBox/VMM/VMMGC/TRPMGCHandlersA.asm@ 8707

Download in other formats: