VirtualBox

source: vbox/trunk/src/VBox/Main/idl/xpidl.xsl@ 4071

Last change on this file since 4071 was 4071, checked in by vboxsync, 17 years ago

Biggest check-in ever. New source code headers for all (C) innotek files.
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 22.1 KB
Line 
1<?xml version="1.0"?>
2
3<!--
4 * A template to generate a XPCOM IDL compatible interface definition file
5 * from the generic interface definition expressed in XML.
6
7 Copyright (C) 2006-2007 innotek GmbH
8
9 This file is part of VirtualBox Open Source Edition (OSE), as
10 available from http://www.virtualbox.org. This file is free software;
11 you can redistribute it and/or modify it under the terms of the GNU
12 General Public License as published by the Free Software Foundation,
13 in version 2 as it comes in the "COPYING" file of the VirtualBox OSE
14 distribution. VirtualBox OSE is distributed in the hope that it will
15 be useful, but WITHOUT ANY WARRANTY of any kind.
16-->
17
18<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
19<xsl:output method="text"/>
20
21<xsl:strip-space elements="*"/>
22
23
24<!--
25// helper definitions
26/////////////////////////////////////////////////////////////////////////////
27-->
28
29<!--
30 * uncapitalizes the first letter only if the second one is not capital
31 * otherwise leaves the string unchanged
32-->
33<xsl:template name="uncapitalize">
34 <xsl:param name="str" select="."/>
35 <xsl:choose>
36 <xsl:when test="not(contains('ABCDEFGHIJKLMNOPQRSTUVWXYZ', substring($str,2,1)))">
37 <xsl:value-of select="
38 concat(
39 translate(substring($str,1,1),'ABCDEFGHIJKLMNOPQRSTUVWXYZ','abcdefghijklmnopqrstuvwxyz'),
40 substring($str,2)
41 )
42 "/>
43 </xsl:when>
44 <xsl:otherwise>
45 <xsl:value-of select="string($str)"/>
46 </xsl:otherwise>
47 </xsl:choose>
48</xsl:template>
49
50<!--
51 * translates the string to uppercase
52-->
53<xsl:template name="uppercase">
54 <xsl:param name="str" select="."/>
55 <xsl:value-of select="
56 translate($str,'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')
57 "/>
58</xsl:template>
59
60
61<!--
62// templates
63/////////////////////////////////////////////////////////////////////////////
64-->
65
66
67<!--
68 * header
69-->
70<xsl:template match="/idl">
71 <xsl:text>
72/*
73# DO NOT EDIT! This is a generated file.
74# Generated from: src/VBox/Main/idl/VirtualBox.xidl (VirtualBox's interface definitions in XML)
75# Generator: src/VBox/Main/idl/xpidl.xsl
76 */
77
78#include "nsISupports.idl"
79#include "nsIException.idl"
80</xsl:text>
81 <!-- native typedefs for the 'mod="ptr"' attribute -->
82 <xsl:text>
83[ptr] native booeanPtr (PRBool);
84[ptr] native octetPtr (PRUint8);
85[ptr] native shortPtr (PRInt16);
86[ptr] native ushortPtr (PRUint16);
87[ptr] native longPtr (PRInt32);
88[ptr] native llongPtr (PRInt64);
89[ptr] native ulongPtr (PRUint32);
90[ptr] native ullongPtr (PRUint64);
91<!-- charPtr is already defined in nsrootidl.idl -->
92<!-- [ptr] native charPtr (char) -->
93[ptr] native stringPtr (string);
94[ptr] native wcharPtr (wchar);
95[ptr] native wstringPtr (wstring);
96
97</xsl:text>
98 <xsl:apply-templates/>
99</xsl:template>
100
101
102<!--
103 * ignore all |if|s except those for XPIDL target
104-->
105<xsl:template match="if">
106 <xsl:if test="@target='xpidl'">
107 <xsl:apply-templates/>
108 </xsl:if>
109</xsl:template>
110<xsl:template match="if" mode="forward">
111 <xsl:if test="@target='xpidl'">
112 <xsl:apply-templates mode="forward"/>
113 </xsl:if>
114</xsl:template>
115
116
117<!--
118 * cpp_quote
119-->
120<xsl:template match="cpp">
121 <xsl:if test="text()">
122 <xsl:text>%{C++</xsl:text>
123 <xsl:value-of select="text()"/>
124 <xsl:text>&#x0A;%}&#x0A;&#x0A;</xsl:text>
125 </xsl:if>
126 <xsl:if test="not(text()) and @line">
127 <xsl:text>%{C++&#x0A;</xsl:text>
128 <xsl:value-of select="@line"/>
129 <xsl:text>&#x0A;%}&#x0A;&#x0A;</xsl:text>
130 </xsl:if>
131</xsl:template>
132
133
134<!--
135 * #if statement (@if attribute)
136 * @note
137 * xpidl doesn't support any preprocessor defines other than #include
138 * (it just ignores them), so the generated IDL will most likely be
139 * invalid. So for now we forbid using @if attributes
140-->
141<xsl:template match="@if" mode="begin">
142 <xsl:message terminate="yes">
143 @if attributes are not currently allowed because xpidl lacks
144 support of #ifdef and stuff.
145 </xsl:message>
146 <xsl:text>#if </xsl:text>
147 <xsl:value-of select="."/>
148 <xsl:text>&#x0A;</xsl:text>
149</xsl:template>
150<xsl:template match="@if" mode="end">
151 <xsl:text>#endif&#x0A;</xsl:text>
152</xsl:template>
153
154
155<!--
156 * libraries
157-->
158<xsl:template match="module">
159 <!-- forward declarations -->
160 <xsl:apply-templates select="if | interface | collection | enumerator" mode="forward"/>
161 <xsl:text>&#x0A;</xsl:text>
162 <!-- all enums go first -->
163 <xsl:apply-templates select="enum | if/enum"/>
164 <!-- everything else but enums -->
165 <xsl:apply-templates select="*[not(self::enum) and not(self::if[enum])]"/>
166</xsl:template>
167
168
169<!--
170 * forward declarations
171-->
172<xsl:template match="interface | collection | enumerator" mode="forward">
173 <xsl:text>interface </xsl:text>
174 <xsl:value-of select="@name"/>
175 <xsl:text>;&#x0A;</xsl:text>
176</xsl:template>
177
178
179<!--
180 * interfaces
181-->
182<xsl:template match="interface">[
183 uuid(<xsl:value-of select="@uuid"/>),
184 scriptable
185]
186<xsl:text>interface </xsl:text>
187 <xsl:value-of select="@name"/>
188 <xsl:text> : </xsl:text>
189 <xsl:choose>
190 <xsl:when test="@extends='$unknown'">nsISupports</xsl:when>
191 <xsl:when test="@extends='$dispatched'">nsISupports</xsl:when>
192 <xsl:when test="@extends='$errorinfo'">nsIException</xsl:when>
193 <xsl:otherwise><xsl:value-of select="@extends"/></xsl:otherwise>
194 </xsl:choose>
195 <xsl:text>&#x0A;{&#x0A;</xsl:text>
196 <!-- attributes (properties) -->
197 <xsl:apply-templates select="attribute"/>
198 <!-- methods -->
199 <xsl:apply-templates select="method"/>
200 <!-- 'if' enclosed elements, unsorted -->
201 <xsl:apply-templates select="if"/>
202 <!-- -->
203 <xsl:text>}; /* interface </xsl:text>
204 <xsl:value-of select="@name"/>
205 <xsl:text> */&#x0A;&#x0A;</xsl:text>
206</xsl:template>
207
208<!--
209 * attributes
210-->
211<xsl:template match="interface//attribute | collection//attribute">
212 <xsl:apply-templates select="@if" mode="begin"/>
213 <xsl:if test="@mod='ptr'">
214 <!-- attributes using native types must be non-scriptable -->
215 <xsl:text> [noscript]&#x0A;</xsl:text>
216 </xsl:if>
217 <xsl:text> </xsl:text>
218 <xsl:if test="@readonly='yes'">
219 <xsl:text>readonly </xsl:text>
220 </xsl:if>
221 <xsl:text>attribute </xsl:text>
222 <xsl:apply-templates select="@type"/>
223 <xsl:text> </xsl:text>
224 <xsl:value-of select="@name"/>
225 <xsl:text>;&#x0A;</xsl:text>
226 <xsl:apply-templates select="@if" mode="end"/>
227 <xsl:text>&#x0A;</xsl:text>
228</xsl:template>
229
230<!--
231 * methods
232-->
233<xsl:template match="interface//method | collection//method">
234 <xsl:apply-templates select="@if" mode="begin"/>
235 <xsl:if test="param/@mod='ptr'">
236 <!-- methods using native types must be non-scriptable -->
237 <xsl:text> [noscript]&#x0A;</xsl:text>
238 </xsl:if>
239 <xsl:text> void </xsl:text>
240 <xsl:value-of select="@name"/>
241 <xsl:if test="param">
242 <xsl:text> (&#x0A;</xsl:text>
243 <xsl:for-each select="param [position() != last()]">
244 <xsl:text> </xsl:text>
245 <xsl:apply-templates select="."/>
246 <xsl:text>,&#x0A;</xsl:text>
247 </xsl:for-each>
248 <xsl:text> </xsl:text>
249 <xsl:apply-templates select="param [last()]"/>
250 <xsl:text>&#x0A; );&#x0A;</xsl:text>
251 </xsl:if>
252 <xsl:if test="not(param)">
253 <xsl:text>();&#x0A;</xsl:text>
254 </xsl:if>
255 <xsl:apply-templates select="@if" mode="end"/>
256 <xsl:text>&#x0A;</xsl:text>
257</xsl:template>
258
259
260<!--
261 * co-classes
262-->
263<xsl:template match="class">
264 <!-- class and contract id -->
265 <xsl:text>%{C++&#x0A;</xsl:text>
266 <xsl:text>#define NS_</xsl:text>
267 <xsl:call-template name="uppercase">
268 <xsl:with-param name="str" select="@name"/>
269 </xsl:call-template>
270 <xsl:text>_CID { \&#x0A;</xsl:text>
271 <xsl:text> 0x</xsl:text><xsl:value-of select="substring(@uuid,1,8)"/>
272 <xsl:text>, 0x</xsl:text><xsl:value-of select="substring(@uuid,10,4)"/>
273 <xsl:text>, 0x</xsl:text><xsl:value-of select="substring(@uuid,15,4)"/>
274 <xsl:text>, \&#x0A; </xsl:text>
275 <xsl:text>{ 0x</xsl:text><xsl:value-of select="substring(@uuid,20,2)"/>
276 <xsl:text>, 0x</xsl:text><xsl:value-of select="substring(@uuid,22,2)"/>
277 <xsl:text>, 0x</xsl:text><xsl:value-of select="substring(@uuid,25,2)"/>
278 <xsl:text>, 0x</xsl:text><xsl:value-of select="substring(@uuid,27,2)"/>
279 <xsl:text>, 0x</xsl:text><xsl:value-of select="substring(@uuid,29,2)"/>
280 <xsl:text>, 0x</xsl:text><xsl:value-of select="substring(@uuid,31,2)"/>
281 <xsl:text>, 0x</xsl:text><xsl:value-of select="substring(@uuid,33,2)"/>
282 <xsl:text>, 0x</xsl:text><xsl:value-of select="substring(@uuid,35,2)"/>
283 <xsl:text> } \&#x0A;}&#x0A;</xsl:text>
284 <xsl:text>#define NS_</xsl:text>
285 <xsl:call-template name="uppercase">
286 <xsl:with-param name="str" select="@name"/>
287 </xsl:call-template>
288 <!-- Contract ID -->
289 <xsl:text>_CONTRACTID &quot;@</xsl:text>
290 <xsl:value-of select="@namespace"/>
291 <xsl:text>/</xsl:text>
292 <xsl:value-of select="@name"/>
293 <xsl:text>;1&quot;&#x0A;</xsl:text>
294 <!-- CLSID_xxx declarations for XPCOM, for compatibility with Win32 -->
295 <xsl:text>// for compatibility with Win32&#x0A;</xsl:text>
296 <xsl:text>#define CLSID_</xsl:text>
297 <xsl:value-of select="@name"/>
298 <xsl:text> (nsCID) NS_</xsl:text>
299 <xsl:call-template name="uppercase">
300 <xsl:with-param name="str" select="@name"/>
301 </xsl:call-template>
302 <xsl:text>_CID&#x0A;</xsl:text>
303 <xsl:text>%}&#x0A;&#x0A;</xsl:text>
304</xsl:template>
305
306
307<!--
308 * enumerators
309-->
310<xsl:template match="enumerator">[
311 uuid(<xsl:value-of select="@uuid"/>),
312 scriptable
313]
314<xsl:text>interface </xsl:text>
315 <xsl:value-of select="@name"/>
316 <xsl:text> : nsISupports&#x0A;{&#x0A;</xsl:text>
317 <!-- HasMore -->
318 <xsl:text> void hasMore ([retval] out boolean more);&#x0A;&#x0A;</xsl:text>
319 <!-- GetNext -->
320 <xsl:text> void getNext ([retval] out </xsl:text>
321 <xsl:apply-templates select="@type"/>
322 <xsl:text> next);&#x0A;&#x0A;</xsl:text>
323 <!-- -->
324 <xsl:text>}; /* interface </xsl:text>
325 <xsl:value-of select="@name"/>
326 <xsl:text> */&#x0A;&#x0A;</xsl:text>
327</xsl:template>
328
329
330<!--
331 * collections
332-->
333<xsl:template match="collection">
334 <xsl:if test="not(@readonly='yes')">
335 <xsl:message terminate="yes">
336 <xsl:value-of select="concat(@name,': ')"/>
337 <xsl:text>non-readonly collections are not currently supported</xsl:text>
338 </xsl:message>
339 </xsl:if>[
340 uuid(<xsl:value-of select="@uuid"/>),
341 scriptable
342]
343<xsl:text>interface </xsl:text>
344 <xsl:value-of select="@name"/>
345 <xsl:text> : nsISupports&#x0A;{&#x0A;</xsl:text>
346 <!-- Count -->
347 <xsl:text> readonly attribute unsigned long count;&#x0A;&#x0A;</xsl:text>
348 <!-- GetItemAt -->
349 <xsl:text> void getItemAt (in unsigned long index, [retval] out </xsl:text>
350 <xsl:apply-templates select="@type"/>
351 <xsl:text> item);&#x0A;&#x0A;</xsl:text>
352 <!-- Enumerate -->
353 <xsl:text> void enumerate ([retval] out </xsl:text>
354 <xsl:apply-templates select="@enumerator"/>
355 <xsl:text> enumerator);&#x0A;&#x0A;</xsl:text>
356 <!-- other extra attributes (properties) -->
357 <xsl:apply-templates select="attribute"/>
358 <!-- other extra methods -->
359 <xsl:apply-templates select="method"/>
360 <!-- 'if' enclosed elements, unsorted -->
361 <xsl:apply-templates select="if"/>
362 <!-- -->
363 <xsl:text>}; /* interface </xsl:text>
364 <xsl:value-of select="@name"/>
365 <xsl:text> */&#x0A;&#x0A;</xsl:text>
366</xsl:template>
367
368
369<!--
370 * enums
371-->
372<xsl:template match="enum">[
373 uuid(<xsl:value-of select="@uuid"/>),
374 scriptable
375]
376<xsl:text>interface </xsl:text>
377 <xsl:value-of select="@name"/>
378 <xsl:text>&#x0A;{&#x0A;</xsl:text>
379 <xsl:for-each select="const">
380 <xsl:text> const PRUint32 </xsl:text>
381 <xsl:value-of select="@name"/> = <xsl:value-of select="@value"/>
382 <xsl:text>;&#x0A;</xsl:text>
383 </xsl:for-each>
384 <xsl:text>};&#x0A;&#x0A;</xsl:text>
385 <!-- -->
386 <xsl:value-of select="concat('/* cross-platform type name for ', @name, ' */&#x0A;')"/>
387 <xsl:text>%{C++&#x0A;</xsl:text>
388 <xsl:value-of select="concat('#define ', @name, '_T', ' ',
389 'PRUint32&#x0A;')"/>
390 <xsl:text>%}&#x0A;&#x0A;</xsl:text>
391 <!-- -->
392 <xsl:value-of select="concat('/* cross-platform constants for ', @name, ' */&#x0A;')"/>
393 <xsl:text>%{C++&#x0A;</xsl:text>
394 <xsl:for-each select="const">
395 <xsl:value-of select="concat('#define ', ../@name, '_', @name, ' ',
396 ../@name, '::', @name, '&#x0A;')"/>
397 </xsl:for-each>
398 <xsl:text>%}&#x0A;&#x0A;</xsl:text>
399</xsl:template>
400
401
402<!--
403 * method parameters
404-->
405<xsl:template match="method/param">
406 <xsl:if test="@array">
407 <xsl:if test="@dir='return'">
408 <xsl:message terminate="yes">
409 <xsl:value-of select="concat(../../@name,'::',../@name,'::',@name,': ')"/>
410 <xsl:text>return array parameters are not currently supported</xsl:text>
411 </xsl:message>
412 </xsl:if>
413 <xsl:text>[array, </xsl:text>
414 <xsl:choose>
415 <xsl:when test="../param[@name=current()/@array]">
416 <xsl:if test="../param[@name=current()/@array]/@dir != @dir">
417 <xsl:message terminate="yes">
418 <xsl:value-of select="concat(../../@name,'::',../@name,': ')"/>
419 <xsl:value-of select="concat(@name,' and ',../param[@name=current()/@array]/@name)"/>
420 <xsl:text> must have the same direction</xsl:text>
421 </xsl:message>
422 </xsl:if>
423 <xsl:text>size_is(</xsl:text>
424 <xsl:if test="@dir='out'">
425 <xsl:text>, </xsl:text>
426 </xsl:if>
427 <xsl:if test="../param[@name=current()/@array]/@dir='out'">
428 <xsl:text>*</xsl:text>
429 </xsl:if>
430 <xsl:value-of select="@array"/>
431 <xsl:text>)</xsl:text>
432 </xsl:when>
433 <xsl:otherwise>
434 <xsl:message terminate="yes">
435 <xsl:value-of select="concat(../../@name,'::',../@name,'::',@name,': ')"/>
436 <xsl:text>array attribute refers to non-existent param: </xsl:text>
437 <xsl:value-of select="@array"/>
438 </xsl:message>
439 </xsl:otherwise>
440 </xsl:choose>
441 <xsl:text>] </xsl:text>
442 </xsl:if>
443 <xsl:choose>
444 <xsl:when test="@dir='in'">in </xsl:when>
445 <xsl:when test="@dir='out'">out </xsl:when>
446 <xsl:when test="@dir='return'">[retval] out </xsl:when>
447 <xsl:otherwise>in</xsl:otherwise>
448 </xsl:choose>
449 <xsl:apply-templates select="@type"/>
450 <xsl:text> </xsl:text>
451 <xsl:value-of select="@name"/>
452</xsl:template>
453
454
455<!--
456 * attribute/parameter type conversion
457-->
458<xsl:template match="
459 attribute/@type | param/@type |
460 enumerator/@type | collection/@type | collection/@enumerator
461">
462 <xsl:variable name="self_target" select="current()/ancestor::if/@target"/>
463
464 <xsl:choose>
465 <!-- modifiers (ignored for 'enumeration' attributes)-->
466 <xsl:when test="name(current())='type' and ../@mod">
467 <xsl:if test="../@array">
468 <xsl:message terminate="yes">
469 <xsl:value-of select="concat(../../../@name,'::',../../@name,'::',../@name,': ')"/>
470 <xsl:text>either 'array' or 'mod' attribute is allowed, but not both!</xsl:text>
471 </xsl:message>
472 </xsl:if>
473 <xsl:choose>
474 <xsl:when test="../@mod='ptr'">
475 <xsl:choose>
476 <!-- standard types -->
477 <!--xsl:when test=".='result'">??</xsl:when-->
478 <xsl:when test=".='boolean'">booeanPtr</xsl:when>
479 <xsl:when test=".='octet'">octetPtr</xsl:when>
480 <xsl:when test=".='short'">shortPtr</xsl:when>
481 <xsl:when test=".='unsigned short'">ushortPtr</xsl:when>
482 <xsl:when test=".='long'">longPtr</xsl:when>
483 <xsl:when test=".='long long'">llongPtr</xsl:when>
484 <xsl:when test=".='unsigned long'">ulongPtr</xsl:when>
485 <xsl:when test=".='unsigned long long'">ullongPtr</xsl:when>
486 <xsl:when test=".='char'">charPtr</xsl:when>
487 <!--xsl:when test=".='string'">??</xsl:when-->
488 <xsl:when test=".='wchar'">wcharPtr</xsl:when>
489 <!--xsl:when test=".='wstring'">??</xsl:when-->
490 <xsl:otherwise>
491 <xsl:message terminate="yes">
492 <xsl:value-of select="concat(../../../@name,'::',../../@name,'::',../@name,': ')"/>
493 <xsl:text>attribute 'mod=</xsl:text>
494 <xsl:value-of select="concat('&quot;',../@mod,'&quot;')"/>
495 <xsl:text>' cannot be used with type </xsl:text>
496 <xsl:value-of select="concat('&quot;',current(),'&quot;!')"/>
497 </xsl:message>
498 </xsl:otherwise>
499 </xsl:choose>
500 </xsl:when>
501 <xsl:otherwise>
502 <xsl:message terminate="yes">
503 <xsl:value-of select="concat(../../../@name,'::',../../@name,'::',../@name,': ')"/>
504 <xsl:value-of select="concat('value &quot;',../@mod,'&quot; ')"/>
505 <xsl:text>of attibute 'mod' is invalid!</xsl:text>
506 </xsl:message>
507 </xsl:otherwise>
508 </xsl:choose>
509 </xsl:when>
510 <!-- no modifiers -->
511 <xsl:otherwise>
512 <xsl:choose>
513 <!-- standard types -->
514 <xsl:when test=".='result'">nsresult</xsl:when>
515 <xsl:when test=".='boolean'">boolean</xsl:when>
516 <xsl:when test=".='octet'">octet</xsl:when>
517 <xsl:when test=".='short'">short</xsl:when>
518 <xsl:when test=".='unsigned short'">unsigned short</xsl:when>
519 <xsl:when test=".='long'">long</xsl:when>
520 <xsl:when test=".='long long'">long long</xsl:when>
521 <xsl:when test=".='unsigned long'">unsigned long</xsl:when>
522 <xsl:when test=".='unsigned long long'">unsigned long long</xsl:when>
523 <xsl:when test=".='char'">char</xsl:when>
524 <xsl:when test=".='wchar'">wchar</xsl:when>
525 <xsl:when test=".='string'">string</xsl:when>
526 <xsl:when test=".='wstring'">wstring</xsl:when>
527 <!-- UUID type -->
528 <xsl:when test=".='uuid'">
529 <xsl:choose>
530 <xsl:when test="name(..)='attribute'">
531 <xsl:choose>
532 <xsl:when test="../@readonly='yes'">
533 <xsl:text>nsIDPtr</xsl:text>
534 </xsl:when>
535 <xsl:otherwise>
536 <xsl:message terminate="yes">
537 <xsl:value-of select="../@name"/>
538 <xsl:text>: Non-readonly uuid attributes are not supported!</xsl:text>
539 </xsl:message>
540 </xsl:otherwise>
541 </xsl:choose>
542 </xsl:when>
543 <xsl:when test="name(..)='param'">
544 <xsl:choose>
545 <xsl:when test="../@dir='in'">
546 <xsl:text>nsIDRef</xsl:text>
547 </xsl:when>
548 <xsl:otherwise>
549 <xsl:text>nsIDPtr</xsl:text>
550 </xsl:otherwise>
551 </xsl:choose>
552 </xsl:when>
553 </xsl:choose>
554 </xsl:when>
555 <!-- system interface types -->
556 <xsl:when test=".='$unknown'">nsISupports</xsl:when>
557 <xsl:otherwise>
558 <xsl:choose>
559 <!-- enum types -->
560 <xsl:when test="
561 (ancestor::module/enum[@name=current()]) or
562 (ancestor::module/if[@target=$self_target]/enum[@name=current()])
563 ">
564 <xsl:text>PRUint32</xsl:text>
565 </xsl:when>
566 <!-- custom interface types -->
567 <xsl:when test="
568 (name(current())='enumerator' and
569 ((ancestor::module/enumerator[@name=current()]) or
570 (ancestor::module/if[@target=$self_target]/enumerator[@name=current()]))
571 ) or
572 ((ancestor::module/interface[@name=current()]) or
573 (ancestor::module/if[@target=$self_target]/interface[@name=current()])
574 ) or
575 ((ancestor::module/collection[@name=current()]) or
576 (ancestor::module/if[@target=$self_target]/collection[@name=current()])
577 )
578 ">
579 <xsl:value-of select="."/>
580 </xsl:when>
581 <!-- other types -->
582 <xsl:otherwise>
583 <xsl:message terminate="yes">
584 <xsl:text>Unknown parameter type: </xsl:text>
585 <xsl:value-of select="."/>
586 </xsl:message>
587 </xsl:otherwise>
588 </xsl:choose>
589 </xsl:otherwise>
590 </xsl:choose>
591 </xsl:otherwise>
592 </xsl:choose>
593</xsl:template>
594
595</xsl:stylesheet>
596
Note: See TracBrowser for help on using the repository browser.

© 2024 Oracle Support Privacy / Do Not Sell My Info Terms of Use Trademark Policy Automated Access Etiquette