VirtualBox

source: vbox/trunk/src/VBox/Main/idl/midl.xsl@ 6851

Last change on this file since 6851 was 6851, checked in by vboxsync, 17 years ago

Ported r27277:27975 (array support) from branches/dmik/s2.
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 21.0 KB
Line 
1<?xml version="1.0"?>
2
3<!--
4 * A template to generate a MS IDL compatible interface definition file
5 * from the generic interface definition expressed in XML.
6
7 Copyright (C) 2006-2007 innotek GmbH
8
9 This file is part of VirtualBox Open Source Edition (OSE), as
10 available from http://www.virtualbox.org. This file is free software;
11 you can redistribute it and/or modify it under the terms of the GNU
12 General Public License (GPL) as published by the Free Software
13 Foundation, in version 2 as it comes in the "COPYING" file of the
14 VirtualBox OSE distribution. VirtualBox OSE is distributed in the
15 hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
16-->
17
18<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
19<xsl:output method="text"/>
20
21<xsl:strip-space elements="*"/>
22
23
24<!--
25// helper definitions
26/////////////////////////////////////////////////////////////////////////////
27-->
28
29<!--
30 * capitalizes the first letter
31-->
32<xsl:template name="capitalize">
33 <xsl:param name="str" select="."/>
34 <xsl:value-of select="
35 concat(
36 translate(substring($str,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ'),
37 substring($str,2)
38 )
39 "/>
40</xsl:template>
41
42<!--
43 * uncapitalizes the first letter only if the second one is not capital
44 * otherwise leaves the string unchanged
45-->
46<xsl:template name="uncapitalize">
47 <xsl:param name="str" select="."/>
48 <xsl:choose>
49 <xsl:when test="not(contains('ABCDEFGHIJKLMNOPQRSTUVWXYZ', substring($str,2,1)))">
50 <xsl:value-of select="
51 concat(
52 translate(substring($str,1,1),'ABCDEFGHIJKLMNOPQRSTUVWXYZ','abcdefghijklmnopqrstuvwxyz'),
53 substring($str,2)
54 )
55 "/>
56 </xsl:when>
57 <xsl:otherwise>
58 <xsl:value-of select="string($str)"/>
59 </xsl:otherwise>
60 </xsl:choose>
61</xsl:template>
62
63
64<!--
65// templates
66/////////////////////////////////////////////////////////////////////////////
67-->
68
69
70<!--
71 * header
72-->
73<xsl:template match="/idl">
74 <xsl:text>
75/*
76 * DO NOT EDIT! This is a generated file.
77 *
78 * MS IDL (MIDL) definition for VirualBox Main API (COM interfaces)
79 * generated from XIDL (XML interface definition).
80 *
81 * Source : src/VBox/Main/idl/VirtualBox.xidl
82 * Generator : src/VBox/Main/idl/midl.xsl
83 */
84 </xsl:text>
85 <xsl:text>&#x0A;</xsl:text>
86 <xsl:text>import "unknwn.idl";&#x0A;&#x0A;</xsl:text>
87 <xsl:apply-templates/>
88</xsl:template>
89
90
91<!--
92 * ignore all |if|s except those for MIDL target
93-->
94<xsl:template match="if">
95 <xsl:if test="@target='midl'">
96 <xsl:apply-templates/>
97 </xsl:if>
98</xsl:template>
99<xsl:template match="if" mode="forward">
100 <xsl:if test="@target='midl'">
101 <xsl:apply-templates mode="forward"/>
102 </xsl:if>
103</xsl:template>
104
105
106<!--
107 * cpp_quote
108-->
109<xsl:template match="cpp">
110 <xsl:text>cpp_quote("</xsl:text>
111 <xsl:value-of select="@line"/>
112 <xsl:text>")&#x0A;&#x0A;</xsl:text>
113</xsl:template>
114
115
116<!--
117 * #if statement (@if attribute)
118-->
119<xsl:template match="@if" mode="begin">
120 <xsl:text>#if </xsl:text>
121 <xsl:value-of select="."/>
122 <xsl:text>&#x0A;</xsl:text>
123</xsl:template>
124<xsl:template match="@if" mode="end">
125 <xsl:text>#endif&#x0A;</xsl:text>
126</xsl:template>
127
128
129<!--
130 * libraries
131-->
132<xsl:template match="library">[
133 uuid(<xsl:value-of select="@uuid"/>),
134 version(<xsl:value-of select="@version"/>),
135 helpstring("<xsl:value-of select="@desc"/>")
136]
137<xsl:text>library </xsl:text>
138 <xsl:value-of select="@name"/>
139 <xsl:text>&#x0A;{&#x0A;</xsl:text>
140 <xsl:text>&#x0A;importlib("stdole2.tlb");&#x0A;&#x0A;</xsl:text>
141 <!-- forward declarations -->
142 <xsl:apply-templates select="if | interface | collection | enumerator" mode="forward"/>
143 <xsl:text>&#x0A;</xsl:text>
144 <!-- all enums go first -->
145 <xsl:apply-templates select="enum | if/enum"/>
146 <!-- everything else but enums -->
147 <xsl:apply-templates select="*[not(self::enum) and not(self::if[enum])]"/>
148 <!-- -->
149 <xsl:text>}; /* library </xsl:text>
150 <xsl:value-of select="@name"/>
151 <xsl:text> */&#x0A;&#x0A;</xsl:text>
152</xsl:template>
153
154
155<!--
156 * forward declarations
157-->
158<xsl:template match="interface | collection | enumerator" mode="forward">
159 <xsl:text>interface </xsl:text>
160 <xsl:value-of select="@name"/>
161 <xsl:text>;&#x0A;</xsl:text>
162</xsl:template>
163
164
165<!--
166 * interfaces
167-->
168<xsl:template match="interface">[
169 uuid(<xsl:value-of select="@uuid"/>),
170 object,
171 dual
172]
173<xsl:text>interface </xsl:text>
174 <xsl:value-of select="@name"/>
175 <xsl:text> : </xsl:text>
176 <xsl:choose>
177 <xsl:when test="@extends='$unknown'">IUnknown</xsl:when>
178 <xsl:when test="@extends='$dispatched'">IDispatch</xsl:when>
179 <xsl:when test="@extends='$errorinfo'">IErrorInfo</xsl:when>
180 <xsl:otherwise><xsl:value-of select="@extends"/></xsl:otherwise>
181 </xsl:choose>
182 <xsl:text>&#x0A;{&#x0A;</xsl:text>
183 <!-- attributes (properties) -->
184 <xsl:apply-templates select="attribute"/>
185 <!-- methods -->
186 <xsl:apply-templates select="method"/>
187 <!-- 'if' enclosed elements, unsorted -->
188 <xsl:apply-templates select="if"/>
189 <!-- -->
190 <xsl:text>}; /* interface </xsl:text>
191 <xsl:value-of select="@name"/>
192 <xsl:text> */&#x0A;&#x0A;</xsl:text>
193</xsl:template>
194
195
196<!--
197 * attributes
198-->
199<xsl:template match="interface//attribute | collection//attribute">
200 <xsl:apply-templates select="@if" mode="begin"/>
201 <xsl:if test="@array">
202 <xsl:message terminate="yes">
203 <xsl:value-of select="concat(../@name,'::',@name,': ')"/>
204 <xsl:text>'array' attributes are not supported, use 'safearray="yes"' instead.</xsl:text>
205 </xsl:message>
206 </xsl:if>
207 <!-- getter -->
208 <xsl:text> [propget] HRESULT </xsl:text>
209 <xsl:call-template name="capitalize">
210 <xsl:with-param name="str" select="@name"/>
211 </xsl:call-template>
212 <xsl:text> ([out, retval] </xsl:text>
213 <xsl:if test="@safearray='yes'">
214 <xsl:text>SAFEARRAY(</xsl:text>
215 </xsl:if>
216 <xsl:apply-templates select="@type"/>
217 <xsl:if test="@safearray='yes'">
218 <xsl:text>)</xsl:text>
219 </xsl:if>
220 <xsl:text> * a</xsl:text>
221 <xsl:call-template name="capitalize">
222 <xsl:with-param name="str" select="@name"/>
223 </xsl:call-template>
224 <xsl:text>);&#x0A;</xsl:text>
225 <!-- setter -->
226 <xsl:if test="not(@readonly='yes')">
227 <xsl:text> [propput] HRESULT </xsl:text>
228 <xsl:call-template name="capitalize">
229 <xsl:with-param name="str" select="@name"/>
230 </xsl:call-template>
231 <xsl:text> ([in</xsl:text>
232 <xsl:if test="@safearray='yes'">
233 <!-- VB supports only [in, out], [out] and [out, retval] arrays -->
234 <xsl:text>, out</xsl:text>
235 </xsl:if>
236 <xsl:text>] </xsl:text>
237 <xsl:if test="@safearray='yes'">
238 <xsl:text>SAFEARRAY(</xsl:text>
239 </xsl:if>
240 <xsl:apply-templates select="@type"/>
241 <xsl:if test="@safearray='yes'">
242 <xsl:text>) *</xsl:text>
243 </xsl:if>
244 <xsl:text> a</xsl:text>
245 <xsl:call-template name="capitalize">
246 <xsl:with-param name="str" select="@name"/>
247 </xsl:call-template>
248 <xsl:text>);&#x0A;</xsl:text>
249 </xsl:if>
250 <xsl:apply-templates select="@if" mode="end"/>
251 <xsl:text>&#x0A;</xsl:text>
252</xsl:template>
253
254
255<!--
256 * methods
257-->
258<xsl:template match="interface//method | collection//method">
259 <xsl:apply-templates select="@if" mode="begin"/>
260 <xsl:text> HRESULT </xsl:text>
261 <xsl:call-template name="capitalize">
262 <xsl:with-param name="str" select="@name"/>
263 </xsl:call-template>
264 <xsl:if test="param">
265 <xsl:text> (&#x0A;</xsl:text>
266 <xsl:for-each select="param [position() != last()]">
267 <xsl:text> </xsl:text>
268 <xsl:apply-templates select="."/>
269 <xsl:text>,&#x0A;</xsl:text>
270 </xsl:for-each>
271 <xsl:text> </xsl:text>
272 <xsl:apply-templates select="param [last()]"/>
273 <xsl:text>&#x0A; );&#x0A;</xsl:text>
274 </xsl:if>
275 <xsl:if test="not(param)">
276 <xsl:text>();&#x0A;</xsl:text>
277 </xsl:if>
278 <xsl:apply-templates select="@if" mode="end"/>
279 <xsl:text>&#x0A;</xsl:text>
280</xsl:template>
281
282
283<!--
284 * co-classes
285-->
286<xsl:template match="module/class">[
287 uuid(<xsl:value-of select="@uuid"/>)
288]
289<xsl:text>coclass </xsl:text>
290 <xsl:value-of select="@name"/>
291 <xsl:text>&#x0A;{&#x0A;</xsl:text>
292 <xsl:for-each select="interface">
293 <xsl:text> </xsl:text>
294 <xsl:if test="@default='yes'">
295 <xsl:text>[default] </xsl:text>
296 </xsl:if>
297 <xsl:text>interface </xsl:text>
298 <xsl:value-of select="@name"/>
299 <xsl:text>;&#x0A;</xsl:text>
300 </xsl:for-each>
301 <xsl:text>&#x0A;}; /* coclass </xsl:text>
302 <xsl:value-of select="@name"/>
303 <xsl:text> */&#x0A;&#x0A;</xsl:text>
304</xsl:template>
305
306
307<!--
308 * enumerators
309-->
310<xsl:template match="enumerator">[
311 uuid(<xsl:value-of select="@uuid"/>),
312 object,
313 dual
314]
315<xsl:text>interface </xsl:text>
316 <xsl:value-of select="@name"/>
317 <xsl:text> : IUnknown&#x0A;{&#x0A;</xsl:text>
318 <!-- HasMore -->
319 <xsl:text> HRESULT HasMore ([out, retval] BOOL * more);&#x0A;&#x0A;</xsl:text>
320 <!-- GetNext -->
321 <xsl:text> HRESULT GetNext ([out, retval] </xsl:text>
322 <xsl:apply-templates select="@type"/>
323 <xsl:text> * next);&#x0A;&#x0A;</xsl:text>
324 <!-- -->
325 <xsl:text>&#x0A;}; /* interface </xsl:text>
326 <xsl:value-of select="@name"/>
327 <xsl:text> */&#x0A;&#x0A;</xsl:text>
328</xsl:template>
329
330
331<!--
332 * collections
333-->
334<xsl:template match="collection">
335 <xsl:if test="not(@readonly='yes')">
336 <xsl:message terminate="yes">
337 <xsl:value-of select="concat(@name,': ')"/>
338 <xsl:text>non-readonly collections are not currently supported</xsl:text>
339 </xsl:message>
340 </xsl:if>[
341 uuid(<xsl:value-of select="@uuid"/>),
342 object,
343 dual
344]
345<xsl:text>interface </xsl:text>
346 <xsl:value-of select="@name"/>
347 <xsl:text> : IUnknown&#x0A;{&#x0A;</xsl:text>
348 <!-- Count -->
349 <xsl:text> [propget] HRESULT Count ([out, retval] ULONG * count);&#x0A;&#x0A;</xsl:text>
350 <!-- GetItemAt -->
351 <xsl:text> HRESULT GetItemAt ([in] ULONG index, [out, retval] </xsl:text>
352 <xsl:apply-templates select="@type"/>
353 <xsl:text> * item);&#x0A;&#x0A;</xsl:text>
354 <!-- Enumerate -->
355 <xsl:text> HRESULT Enumerate ([out, retval] </xsl:text>
356 <xsl:apply-templates select="@enumerator"/>
357 <xsl:text> * enumerator);&#x0A;&#x0A;</xsl:text>
358 <!-- other extra attributes (properties) -->
359 <xsl:apply-templates select="attribute"/>
360 <!-- other extra methods -->
361 <xsl:apply-templates select="method"/>
362 <!-- 'if' enclosed elements, unsorted -->
363 <xsl:apply-templates select="if"/>
364 <!-- -->
365 <xsl:text>&#x0A;}; /* interface </xsl:text>
366 <xsl:value-of select="@name"/>
367 <xsl:text> */&#x0A;&#x0A;</xsl:text>
368</xsl:template>
369
370
371<!--
372 * enums
373-->
374<xsl:template match="enum">[
375 uuid(<xsl:value-of select="@uuid"/>),
376 v1_enum
377]
378<xsl:text>typedef enum &#x0A;{&#x0A;</xsl:text>
379 <xsl:for-each select="const">
380 <xsl:text> </xsl:text>
381 <xsl:value-of select="@name"/> = <xsl:value-of select="@value"/>
382 <xsl:choose>
383 <xsl:when test="position()!=last()"><xsl:text>,&#x0A;</xsl:text></xsl:when>
384 <xsl:otherwise><xsl:text>&#x0A;</xsl:text></xsl:otherwise>
385 </xsl:choose>
386 </xsl:for-each>
387 <xsl:text>} </xsl:text>
388 <xsl:value-of select="@name"/>
389 <xsl:text>;&#x0A;&#x0A;</xsl:text>
390 <!-- -->
391 <xsl:value-of select="concat('/* cross-platform type name for ', @name, ' */&#x0A;')"/>
392 <xsl:value-of select="concat('cpp_quote(&quot;#define ', @name, '_T', ' ',
393 @name, '&quot;)&#x0A;&#x0A;')"/>
394 <xsl:text>cpp_quote("")&#x0A;</xsl:text>
395 <!-- -->
396 <xsl:value-of select="concat('/* cross-platform constants for ', @name, ' */&#x0A;')"/>
397 <xsl:for-each select="const">
398 <xsl:value-of select="concat('cpp_quote(&quot;#define ', ../@name, '_', @name, ' ',
399 @name, '&quot;)&#x0A;')"/>
400 <xsl:choose>
401 <xsl:when test="position()=last()"><xsl:text>cpp_quote("")&#x0A;</xsl:text></xsl:when>
402 </xsl:choose>
403 </xsl:for-each>
404 <xsl:text>&#x0A;&#x0A;</xsl:text>
405</xsl:template>
406
407
408<!--
409 * method parameters
410-->
411<xsl:template match="method/param">
412 <xsl:text>[</xsl:text>
413 <xsl:choose>
414 <xsl:when test="@dir='in'">in</xsl:when>
415 <xsl:when test="@dir='out'">out</xsl:when>
416 <xsl:when test="@dir='return'">out, retval</xsl:when>
417 <xsl:otherwise>in</xsl:otherwise>
418 </xsl:choose>
419 <xsl:if test="@safearray='yes'">
420 <!-- VB supports only [in, out], [out] and [out, retval] arrays -->
421 <xsl:if test="@dir='in'">, out</xsl:if>
422 </xsl:if>
423 <xsl:if test="@array">
424 <xsl:if test="@dir='return'">
425 <xsl:message terminate="yes">
426 <xsl:value-of select="concat(../../@name,'::',../@name,'::',@name,': ')"/>
427 <xsl:text>return 'array' parameters are not supported, use 'safearray="yes"' instead.</xsl:text>
428 </xsl:message>
429 </xsl:if>
430 <xsl:choose>
431 <xsl:when test="../param[@name=current()/@array]">
432 <xsl:if test="../param[@name=current()/@array]/@dir != @dir">
433 <xsl:message terminate="yes">
434 <xsl:value-of select="concat(../../@name,'::',../@name,': ')"/>
435 <xsl:value-of select="concat(@name,' and ',../param[@name=current()/@array]/@name)"/>
436 <xsl:text> must have the same direction</xsl:text>
437 </xsl:message>
438 </xsl:if>
439 <xsl:text>, size_is(</xsl:text>
440 <xsl:if test="@dir='out'">
441 <xsl:text>, *</xsl:text>
442 </xsl:if>
443 <xsl:text>a</xsl:text>
444 <xsl:call-template name="capitalize">
445 <xsl:with-param name="str" select="@array"/>
446 </xsl:call-template>
447 <xsl:text>)</xsl:text>
448 </xsl:when>
449 <xsl:otherwise>
450 <xsl:message terminate="yes">
451 <xsl:value-of select="concat(../../@name,'::',../@name,'::',@name,': ')"/>
452 <xsl:text>array attribute refers to non-existent param: </xsl:text>
453 <xsl:value-of select="@array"/>
454 </xsl:message>
455 </xsl:otherwise>
456 </xsl:choose>
457 </xsl:if>
458 <xsl:text>] </xsl:text>
459 <xsl:if test="@safearray='yes'">
460 <xsl:text>SAFEARRAY(</xsl:text>
461 </xsl:if>
462 <xsl:apply-templates select="@type"/>
463 <xsl:if test="@safearray='yes'">
464 <xsl:text>)</xsl:text>
465 </xsl:if>
466 <xsl:if test="@array">
467 <xsl:text> *</xsl:text>
468 </xsl:if>
469 <xsl:if test="@dir='out' or @dir='return' or @safearray='yes'">
470 <xsl:text> *</xsl:text>
471 </xsl:if>
472 <xsl:text> a</xsl:text>
473 <xsl:call-template name="capitalize">
474 <xsl:with-param name="str" select="@name"/>
475 </xsl:call-template>
476</xsl:template>
477
478
479<!--
480 * attribute/parameter type conversion
481-->
482<xsl:template match="
483 attribute/@type | param/@type |
484 enumerator/@type | collection/@type | collection/@enumerator
485">
486 <xsl:variable name="self_target" select="current()/ancestor::if/@target"/>
487
488 <xsl:if test="../@array and ../@safearray='yes'">
489 <xsl:message terminate="yes">
490 <xsl:value-of select="concat(../../../@name,'::',../../@name,'::',../@name,': ')"/>
491 <xsl:text>either 'array' or 'safearray="yes"' attribute is allowed, but not both!</xsl:text>
492 </xsl:message>
493 </xsl:if>
494
495 <xsl:choose>
496 <!-- modifiers (ignored for 'enumeration' attributes)-->
497 <xsl:when test="name(current())='type' and ../@mod">
498 <xsl:choose>
499 <xsl:when test="../@mod='ptr'">
500 <xsl:choose>
501 <!-- standard types -->
502 <!--xsl:when test=".='result'">??</xsl:when-->
503 <xsl:when test=".='boolean'">BOOL *</xsl:when>
504 <xsl:when test=".='octet'">BYTE *</xsl:when>
505 <xsl:when test=".='short'">SHORT *</xsl:when>
506 <xsl:when test=".='unsigned short'">USHORT *</xsl:when>
507 <xsl:when test=".='long'">LONG *</xsl:when>
508 <xsl:when test=".='long long'">LONG64 *</xsl:when>
509 <xsl:when test=".='unsigned long'">ULONG *</xsl:when>
510 <xsl:when test=".='unsigned long long'">ULONG64 *</xsl:when>
511 <xsl:when test=".='char'">CHAR *</xsl:when>
512 <!--xsl:when test=".='string'">??</xsl:when-->
513 <xsl:when test=".='wchar'">OLECHAR *</xsl:when>
514 <!--xsl:when test=".='wstring'">??</xsl:when-->
515 <xsl:otherwise>
516 <xsl:message terminate="yes">
517 <xsl:value-of select="concat(../../../@name,'::',../../@name,'::',../@name,': ')"/>
518 <xsl:text>attribute 'mod=</xsl:text>
519 <xsl:value-of select="concat('&quot;',../@mod,'&quot;')"/>
520 <xsl:text>' cannot be used with type </xsl:text>
521 <xsl:value-of select="concat('&quot;',current(),'&quot;!')"/>
522 </xsl:message>
523 </xsl:otherwise>
524 </xsl:choose>
525 </xsl:when>
526 <xsl:otherwise>
527 <xsl:message terminate="yes">
528 <xsl:value-of select="concat(../../../@name,'::',../../@name,'::',../@name,': ')"/>
529 <xsl:value-of select="concat('value &quot;',../@mod,'&quot; ')"/>
530 <xsl:text>of attribute 'mod' is invalid!</xsl:text>
531 </xsl:message>
532 </xsl:otherwise>
533 </xsl:choose>
534 </xsl:when>
535 <!-- no modifiers -->
536 <xsl:otherwise>
537 <xsl:choose>
538 <!-- standard types -->
539 <xsl:when test=".='result'">HRESULT</xsl:when>
540 <xsl:when test=".='boolean'">BOOL</xsl:when>
541 <xsl:when test=".='octet'">BYTE</xsl:when>
542 <xsl:when test=".='short'">SHORT</xsl:when>
543 <xsl:when test=".='unsigned short'">USHORT</xsl:when>
544 <xsl:when test=".='long'">LONG</xsl:when>
545 <xsl:when test=".='long long'">LONG64</xsl:when>
546 <xsl:when test=".='unsigned long'">ULONG</xsl:when>
547 <xsl:when test=".='unsigned long long'">ULONG64</xsl:when>
548 <xsl:when test=".='char'">CHAR</xsl:when>
549 <xsl:when test=".='string'">CHAR *</xsl:when>
550 <xsl:when test=".='wchar'">OLECHAR</xsl:when>
551 <xsl:when test=".='wstring'">BSTR</xsl:when>
552 <!-- UUID type -->
553 <xsl:when test=".='uuid'">GUID</xsl:when>
554 <!-- system interface types -->
555 <xsl:when test=".='$unknown'">IUnknown *</xsl:when>
556 <xsl:otherwise>
557 <xsl:choose>
558 <!-- enum types -->
559 <xsl:when test="
560 (ancestor::library/enum[@name=current()]) or
561 (ancestor::library/if[@target=$self_target]/enum[@name=current()])
562 ">
563 <xsl:value-of select="."/>
564 </xsl:when>
565 <!-- custom interface types -->
566 <xsl:when test="
567 (name(current())='enumerator' and
568 ((ancestor::library/enumerator[@name=current()]) or
569 (ancestor::library/if[@target=$self_target]/enumerator[@name=current()]))
570 ) or
571 ((ancestor::library/interface[@name=current()]) or
572 (ancestor::library/if[@target=$self_target]/interface[@name=current()])
573 ) or
574 ((ancestor::library/collection[@name=current()]) or
575 (ancestor::library/if[@target=$self_target]/collection[@name=current()])
576 )
577 ">
578 <xsl:value-of select="."/><xsl:text> *</xsl:text>
579 </xsl:when>
580 <!-- other types -->
581 <xsl:otherwise>
582 <xsl:message terminate="yes">
583 <xsl:text>Unknown parameter type: </xsl:text>
584 <xsl:value-of select="."/>
585 </xsl:message>
586 </xsl:otherwise>
587 </xsl:choose>
588 </xsl:otherwise>
589 </xsl:choose>
590 </xsl:otherwise>
591 </xsl:choose>
592</xsl:template>
593
594</xsl:stylesheet>
595
Note: See TracBrowser for help on using the repository browser.

© 2024 Oracle Support Privacy / Do Not Sell My Info Terms of Use Trademark Policy Automated Access Etiquette