VBoxGuestAdditionsW2KXP.nsh@ 76553

Last change on this file since 76553 was 76553, checked in by vboxsync, 6 years ago
scm --update-copyright-year
Property svn:eol-style set to `native` Property svn:keywords set to `Id Revision`
File size: 32.1 KB

Line
1	; $Id: VBoxGuestAdditionsW2KXP.nsh 76553 2019-01-01 01:45:53Z vboxsync $
2	;; @file
3	; VBoxGuestAdditionsW2KXP.nsh - Guest Additions installation for Windows 2000/XP.
4	;
5
6	;
7	; Copyright (C) 2006-2019 Oracle Corporation
8	;
9	; This file is part of VirtualBox Open Source Edition (OSE), as
10	; available from http://www.virtualbox.org. This file is free software;
11	; you can redistribute it and/or modify it under the terms of the GNU
12	; General Public License (GPL) as published by the Free Software
13	; Foundation, in version 2 as it comes in the "COPYING" file of the
14	; VirtualBox OSE distribution. VirtualBox OSE is distributed in the
15	; hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
16	;
17
18	Function W2K_SetVideoResolution
19
20	; NSIS only supports global vars, even in functions -- great
21	Var /GLOBAL i
22	Var /GLOBAL tmp
23	Var /GLOBAL tmppath
24	Var /GLOBAL dev_id
25	Var /GLOBAL dev_desc
26
27	; Check for all required parameters
28	StrCmp $g_iScreenX "0" exit
29	StrCmp $g_iScreenY "0" exit
30	StrCmp $g_iScreenBpp "0" exit
31
32	${LogVerbose} "Setting display parameters ($g_iScreenXx$g_iScreenY, $g_iScreenBpp BPP) ..."
33
34	; Enumerate all video devices (up to 32 at the moment, use key "MaxObjectNumber" key later)
35	${For} $i 0 32
36
37	ReadRegStr $tmp HKLM "HARDWARE\DEVICEMAP\VIDEO" "\Device\Video$i"
38	StrCmp $tmp "" dev_not_found
39
40	; Extract path to video settings
41	; Ex: \Registry\Machine\System\CurrentControlSet\Control\Video\{28B74D2B-F0A9-48E0-8028-D76F6BB1AE65}\0000
42	; Or: \Registry\Machine\System\CurrentControlSet\Control\Video\vboxvideo\Device0
43	; Result: Machine\System\CurrentControlSet\Control\Video\{28B74D2B-F0A9-48E0-8028-D76F6BB1AE65}\0000
44	Push "$tmp" ; String
45	Push "\" ; SubString
46	Push ">" ; SearchDirection
47	Push ">" ; StrInclusionDirection
48	Push "0" ; IncludeSubString
49	Push "2" ; Loops
50	Push "0" ; CaseSensitive
51	Call StrStrAdv
52	Pop $tmppath ; $1 only contains the full path
53	StrCmp $tmppath "" dev_not_found
54
55	; Get device description
56	ReadRegStr $dev_desc HKLM "$tmppath" "Device Description"
57	!ifdef _DEBUG
58	${LogVerbose} "Registry path: $tmppath"
59	${LogVerbose} "Registry path to device name: $temp"
60	!endif
61	${LogVerbose} "Detected video device: $dev_desc"
62
63	${If} $dev_desc == "VirtualBox Graphics Adapter"
64	${LogVerbose} "VirtualBox video device found!"
65	Goto dev_found
66	${EndIf}
67	${Next}
68	Goto dev_not_found
69
70	dev_found:
71
72	; If we're on Windows 2000, skip the ID detection ...
73	${If} $g_strWinVersion == "2000"
74	Goto change_res
75	${EndIf}
76	Goto dev_found_detect_id
77
78	dev_found_detect_id:
79
80	StrCpy $i 0 ; Start at index 0
81	${LogVerbose} "Detecting device ID ..."
82
83	dev_found_detect_id_loop:
84
85	; Resolve real path to hardware instance "{GUID}"
86	EnumRegKey $dev_id HKLM "SYSTEM\CurrentControlSet\Control\Video" $i
87	StrCmp $dev_id "" dev_not_found ; No more entries? Jump out
88	!ifdef _DEBUG
89	${LogVerbose} "Got device ID: $dev_id"
90	!endif
91	ReadRegStr $dev_desc HKLM "SYSTEM\CurrentControlSet\Control\Video\$dev_id\0000" "Device Description" ; Try to read device name
92	${If} $dev_desc == "VirtualBox Graphics Adapter"
93	${LogVerbose} "Device ID of $dev_desc: $dev_id"
94	Goto change_res
95	${EndIf}
96
97	IntOp $i $i + 1 ; Increment index
98	goto dev_found_detect_id_loop
99
100	dev_not_found:
101
102	${LogVerbose} "No VirtualBox video device (yet) detected! No custom mode set."
103	Goto exit
104
105	change_res:
106
107	!ifdef _DEBUG
108	${LogVerbose} "Device description: $dev_desc"
109	${LogVerbose} "Device ID: $dev_id"
110	!endif
111
112	Var /GLOBAL reg_path_device
113	Var /GLOBAL reg_path_monitor
114
115	${LogVerbose} "Custom mode set: Platform is Windows $g_strWinVersion"
116	${If} $g_strWinVersion == "2000"
117	${OrIf} $g_strWinVersion == "Vista"
118	StrCpy $reg_path_device "SYSTEM\CurrentControlSet\SERVICES\VBoxVideo\Device0"
119	StrCpy $reg_path_monitor "SYSTEM\CurrentControlSet\SERVICES\VBoxVideo\Device0\Mon00000001"
120	${ElseIf} $g_strWinVersion == "XP"
121	${OrIf} $g_strWinVersion == "7"
122	${OrIf} $g_strWinVersion == "8"
123	${OrIf} $g_strWinVersion == "8_1"
124	${OrIf} $g_strWinVersion == "10"
125	StrCpy $reg_path_device "SYSTEM\CurrentControlSet\Control\Video\$dev_id\0000"
126	StrCpy $reg_path_monitor "SYSTEM\CurrentControlSet\Control\VIDEO\$dev_id\0000\Mon00000001"
127	${Else}
128	${LogVerbose} "Custom mode set: Windows $g_strWinVersion not supported yet"
129	Goto exit
130	${EndIf}
131
132	; Write the new value in the adapter config (VBoxVideo.sys) using hex values in binary format
133	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" registry write HKLM $reg_path_device CustomXRes REG_BIN $g_iScreenX DWORD" "false"
134	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" registry write HKLM $reg_path_device CustomYRes REG_BIN $g_iScreenY DWORD" "false"
135	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" registry write HKLM $reg_path_device CustomBPP REG_BIN $g_iScreenBpp DWORD" "false"
136
137	; ... and tell Windows to use that mode on next start!
138	WriteRegDWORD HKCC $reg_path_device "DefaultSettings.XResolution" "$g_iScreenX"
139	WriteRegDWORD HKCC $reg_path_device "DefaultSettings.YResolution" "$g_iScreenY"
140	WriteRegDWORD HKCC $reg_path_device "DefaultSettings.BitsPerPixel" "$g_iScreenBpp"
141
142	WriteRegDWORD HKCC $reg_path_monitor "DefaultSettings.XResolution" "$g_iScreenX"
143	WriteRegDWORD HKCC $reg_path_monitor "DefaultSettings.YResolution" "$g_iScreenY"
144	WriteRegDWORD HKCC $reg_path_monitor "DefaultSettings.BitsPerPixel" "$g_iScreenBpp"
145
146	${LogVerbose} "Custom mode set to $g_iScreenXx$g_iScreenY, $g_iScreenBpp BPP on next restart."
147
148	exit:
149
150	FunctionEnd
151
152	Function W2K_Prepare
153
154	${If} $g_bNoVBoxServiceExit == "false"
155	; Stop / kill VBoxService
156	Call StopVBoxService
157	${EndIf}
158
159	${If} $g_bNoVBoxTrayExit == "false"
160	; Stop / kill VBoxTray
161	Call StopVBoxTray
162	${EndIf}
163
164	; Delete VBoxService from registry
165	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxService"
166
167	; Delete old VBoxService.exe from install directory (replaced by VBoxTray.exe)
168	Delete /REBOOTOK "$INSTDIR\VBoxService.exe"
169
170	FunctionEnd
171
172	Function W2K_CopyFiles
173
174	Push $0
175	SetOutPath "$INSTDIR"
176
177	; Video driver
178	FILE "$%PATH_OUT%\bin\additions\VBoxVideo.sys"
179	FILE "$%PATH_OUT%\bin\additions\VBoxDisp.dll"
180
181	; Mouse driver
182	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.sys"
183	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.inf"
184	!ifdef VBOX_SIGN_ADDITIONS
185	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.cat"
186	!endif
187
188	; Guest driver
189	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.sys"
190	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.inf"
191	!ifdef VBOX_SIGN_ADDITIONS
192	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.cat"
193	!endif
194
195	; Guest driver files
196	FILE "$%PATH_OUT%\bin\additions\VBoxTray.exe"
197	FILE "$%PATH_OUT%\bin\additions\VBoxControl.exe" ; Not used by W2K and up, but required by the .INF file
198
199	; WHQL fake
200	!ifdef WHQL_FAKE
201	FILE "$%PATH_OUT%\bin\additions\VBoxWHQLFake.exe"
202	!endif
203
204	SetOutPath $g_strSystemDir
205
206	; VBoxService
207	${If} $g_bNoVBoxServiceExit == "false"
208	; VBoxService has been terminated before, so just install the file
209	; in the regular way
210	FILE "$%PATH_OUT%\bin\additions\VBoxService.exe"
211	${Else}
212	; VBoxService is in use and wasn't terminated intentionally. So extract the
213	; new version into a temporary location and install it on next reboot
214	Push $0
215	ClearErrors
216	GetTempFileName $0
217	IfErrors 0 +3
218	${LogVerbose} "Error getting temp file for VBoxService.exe"
219	StrCpy "$0" "$INSTDIR\VBoxServiceTemp.exe"
220	${LogVerbose} "VBoxService is in use, will be installed on next reboot (from '$0')"
221	File "/oname=$0" "$%PATH_OUT%\bin\additions\VBoxService.exe"
222	IfErrors 0 +2
223	${LogVerbose} "Error copying VBoxService.exe to '$0'"
224	Rename /REBOOTOK "$0" "$g_strSystemDir\VBoxService.exe"
225	IfErrors 0 +2
226	${LogVerbose} "Error renaming '$0' to '$g_strSystemDir\VBoxService.exe'"
227	Pop $0
228	${EndIf}
229
230	!if $%VBOX_WITH_WDDM% == "1"
231	${If} $g_bWithWDDM == "true"
232	; WDDM Video driver
233	SetOutPath "$INSTDIR"
234
235	!ifdef VBOX_SIGN_ADDITIONS
236	FILE "$%PATH_OUT%\bin\additions\VBoxWddm.cat"
237	!endif
238	FILE "$%PATH_OUT%\bin\additions\VBoxWddm.sys"
239	FILE "$%PATH_OUT%\bin\additions\VBoxWddm.inf"
240
241	FILE "$%PATH_OUT%\bin\additions\VBoxDispD3D.dll"
242	!if $%VBOX_WITH_MESA3D% == "1"
243	FILE "$%PATH_OUT%\bin\additions\VBoxNine.dll"
244	FILE "$%PATH_OUT%\bin\additions\VBoxSVGA.dll"
245	FILE "$%PATH_OUT%\bin\additions\VBoxICD.dll"
246	FILE "$%PATH_OUT%\bin\additions\VBoxGL.dll"
247	!endif
248
249	!if $%VBOX_WITH_CROGL% == "1"
250	FILE "$%PATH_OUT%\bin\additions\VBoxOGLarrayspu.dll"
251	FILE "$%PATH_OUT%\bin\additions\VBoxOGLcrutil.dll"
252	FILE "$%PATH_OUT%\bin\additions\VBoxOGLerrorspu.dll"
253	FILE "$%PATH_OUT%\bin\additions\VBoxOGLpackspu.dll"
254	FILE "$%PATH_OUT%\bin\additions\VBoxOGLpassthroughspu.dll"
255	FILE "$%PATH_OUT%\bin\additions\VBoxOGLfeedbackspu.dll"
256	FILE "$%PATH_OUT%\bin\additions\VBoxOGL.dll"
257
258	FILE "$%PATH_OUT%\bin\additions\VBoxD3D9wddm.dll"
259	FILE "$%PATH_OUT%\bin\additions\wined3dwddm.dll"
260	!endif ; $%VBOX_WITH_CROGL% == "1"
261
262	!if $%BUILD_TARGET_ARCH% == "amd64"
263	FILE "$%PATH_OUT%\bin\additions\VBoxDispD3D-x86.dll"
264	!if $%VBOX_WITH_MESA3D% == "1"
265	FILE "$%PATH_OUT%\bin\additions\VBoxNine-x86.dll"
266	FILE "$%PATH_OUT%\bin\additions\VBoxSVGA-x86.dll"
267	FILE "$%PATH_OUT%\bin\additions\VBoxICD-x86.dll"
268	FILE "$%PATH_OUT%\bin\additions\VBoxGL-x86.dll"
269	!endif
270
271	!if $%VBOX_WITH_CROGL% == "1"
272	FILE "$%PATH_OUT%\bin\additions\VBoxOGLarrayspu-x86.dll"
273	FILE "$%PATH_OUT%\bin\additions\VBoxOGLcrutil-x86.dll"
274	FILE "$%PATH_OUT%\bin\additions\VBoxOGLerrorspu-x86.dll"
275	FILE "$%PATH_OUT%\bin\additions\VBoxOGLpackspu-x86.dll"
276	FILE "$%PATH_OUT%\bin\additions\VBoxOGLpassthroughspu-x86.dll"
277	FILE "$%PATH_OUT%\bin\additions\VBoxOGLfeedbackspu-x86.dll"
278	FILE "$%PATH_OUT%\bin\additions\VBoxOGL-x86.dll"
279
280	FILE "$%PATH_OUT%\bin\additions\VBoxD3D9wddm-x86.dll"
281	FILE "$%PATH_OUT%\bin\additions\wined3dwddm-x86.dll"
282	!endif ; $%VBOX_WITH_CROGL% == "1"
283	!endif ; $%BUILD_TARGET_ARCH% == "amd64"
284
285	Goto doneCr
286	${EndIf}
287	!endif ; $%VBOX_WITH_WDDM% == "1"
288
289	!if $%VBOX_WITH_CROGL% == "1"
290	; crOpenGL
291	!if $%BUILD_TARGET_ARCH% == "amd64"
292	!define LIBRARY_X64 ; Enable installation of 64-bit libraries
293	!endif
294	StrCpy $0 "$TEMP\VBoxGuestAdditions\VBoxOGL"
295	CreateDirectory "$0"
296	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGLarrayspu.dll" "$g_strSystemDir\VBoxOGLarrayspu.dll" "$0"
297	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGLcrutil.dll" "$g_strSystemDir\VBoxOGLcrutil.dll" "$0"
298	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGLerrorspu.dll" "$g_strSystemDir\VBoxOGLerrorspu.dll" "$0"
299	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGLpackspu.dll" "$g_strSystemDir\VBoxOGLpackspu.dll" "$0"
300	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGLpassthroughspu.dll" "$g_strSystemDir\VBoxOGLpassthroughspu.dll" "$0"
301	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGLfeedbackspu.dll" "$g_strSystemDir\VBoxOGLfeedbackspu.dll" "$0"
302	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGL.dll" "$g_strSystemDir\VBoxOGL.dll" "$0"
303	!if $%BUILD_TARGET_ARCH% == "amd64"
304	!undef LIBRARY_X64 ; Disable installation of 64-bit libraries
305	!endif
306
307	!if $%BUILD_TARGET_ARCH% == "amd64"
308	StrCpy $0 "$TEMP\VBoxGuestAdditions\VBoxOGL32"
309	CreateDirectory "$0"
310	; Only 64-bit installer: Also copy 32-bit DLLs on 64-bit target arch in
311	; Wow64 node (32-bit sub system). Note that $SYSDIR contains the 32-bit
312	; path after calling EnableX64FSRedirection
313	${EnableX64FSRedirection}
314	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGLarrayspu.dll" "$SYSDIR\VBoxOGLarrayspu.dll" "$0"
315	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGLcrutil.dll" "$SYSDIR\VBoxOGLcrutil.dll" "$0"
316	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGLerrorspu.dll" "$SYSDIR\VBoxOGLerrorspu.dll" "$0"
317	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGLpackspu.dll" "$SYSDIR\VBoxOGLpackspu.dll" "$0"
318	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGLpassthroughspu.dll" "$SYSDIR\VBoxOGLpassthroughspu.dll" "$0"
319	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGLfeedbackspu.dll" "$SYSDIR\VBoxOGLfeedbackspu.dll" "$0"
320	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGL.dll" "$SYSDIR\VBoxOGL.dll" "$0"
321	${DisableX64FSRedirection}
322	!endif
323
324	!endif ; VBOX_WITH_CROGL
325
326	doneCr:
327
328	Pop $0
329
330	FunctionEnd
331
332	!ifdef WHQL_FAKE
333
334	Function W2K_WHQLFakeOn
335
336	StrCmp $g_bFakeWHQL "true" do
337	Goto exit
338
339	do:
340
341	${LogVerbose} "Turning off WHQL protection..."
342	${CmdExecute} "$\"$INSTDIR\VBoxWHQLFake.exe$\" $\"ignore$\"" "true"
343
344	exit:
345
346	FunctionEnd
347
348	Function W2K_WHQLFakeOff
349
350	StrCmp $g_bFakeWHQL "true" do
351	Goto exit
352
353	do:
354
355	${LogVerbose} "Turning back on WHQL protection..."
356	${CmdExecute} "$\"$INSTDIR\VBoxWHQLFake.exe$\" $\"warn$\"" "true"
357
358	exit:
359
360	FunctionEnd
361
362	!endif
363
364	Function W2K_InstallFiles
365
366	; The Shared Folder IFS goes to the system directory
367	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxSF.sys" "$g_strSystemDir\drivers\VBoxSF.sys" "$INSTDIR"
368	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxMRXNP.dll" "$g_strSystemDir\VBoxMRXNP.dll" "$INSTDIR"
369	AccessControl::GrantOnFile "$g_strSystemDir\VBoxMRXNP.dll" "(BU)" "GenericRead"
370	!if $%BUILD_TARGET_ARCH% == "amd64"
371	; Only 64-bit installer: Copy the 32-bit DLL for 32 bit applications.
372	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxMRXNP-x86.dll" "$g_strSysWow64\VBoxMRXNP.dll" "$INSTDIR"
373	AccessControl::GrantOnFile "$g_strSysWow64\VBoxMRXNP.dll" "(BU)" "GenericRead"
374	!endif
375
376	; The VBoxTray hook DLL also goes to the system directory; it might be locked
377	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxHook.dll" "$g_strSystemDir\VBoxHook.dll" "$INSTDIR"
378	AccessControl::GrantOnFile "$g_strSystemDir\VBoxHook.dll" "(BU)" "GenericRead"
379
380	${LogVerbose} "Installing drivers ..."
381
382	Push $0 ; For fetching results
383
384	SetOutPath "$INSTDIR"
385
386	${If} $g_bNoGuestDrv == "false"
387	${LogVerbose} "Installing guest driver ..."
388	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver install $\"$INSTDIR\VBoxGuest.inf$\" $\"$INSTDIR\install_drivers.log$\"" "false"
389	${Else}
390	${LogVerbose} "Guest driver installation skipped!"
391	${EndIf}
392
393	${If} $g_bNoVideoDrv == "false"
394	${If} $g_bWithWDDM == "true"
395	${LogVerbose} "Installing WDDM video driver..."
396	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver install $\"$INSTDIR\VBoxWddm.inf$\" $\"$INSTDIR\install_drivers.log$\"" "false"
397	${Else}
398	${LogVerbose} "Installing video driver ..."
399	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver install $\"$INSTDIR\VBoxVideo.inf$\" $\"$INSTDIR\install_drivers.log$\"" "false"
400	${EndIf}
401	${Else}
402	${LogVerbose} "Video driver installation skipped!"
403	${EndIf}
404
405	${If} $g_bNoMouseDrv == "false"
406	${LogVerbose} "Installing mouse driver ..."
407	; The mouse filter does not contain any device IDs but a "DefaultInstall" section;
408	; so this .INF file needs to be installed using "InstallHinfSection" which is implemented
409	; with VBoxDrvInst's "driver executeinf" routine
410	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver executeinf $\"$INSTDIR\VBoxMouse.inf$\"" "false"
411	${Else}
412	${LogVerbose} "Mouse driver installation skipped!"
413	${EndIf}
414
415	; Create the VBoxService service
416	; No need to stop/remove the service here! Do this only on uninstallation!
417	${LogVerbose} "Installing VirtualBox service ..."
418	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service create $\"VBoxService$\" $\"VirtualBox Guest Additions Service$\" 16 2 $\"%SystemRoot%\System32\VBoxService.exe$\" $\"Base$\"" "false"
419
420	; Set service description
421	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxService" "Description" "Manages VM runtime information, time synchronization, remote sysprep execution and miscellaneous utilities for guest operating systems."
422
423	sf:
424
425	${LogVerbose} "Installing Shared Folders service ..."
426
427	; Create the Shared Folders service ...
428	; No need to stop/remove the service here! Do this only on uninstallation!
429	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service create $\"VBoxSF$\" $\"VirtualBox Shared Folders$\" 2 1 $\"\SystemRoot\System32\drivers\VBoxSF.sys$\" $\"NetworkProvider$\"" "false"
430
431	; ... and the link to the network provider
432	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "DeviceName" "\Device\VBoxMiniRdr"
433	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "Name" "VirtualBox Shared Folders"
434	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "ProviderPath" "$SYSDIR\VBoxMRXNP.dll"
435
436	; Add default network providers (if not present or corrupted)
437	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add WebClient" "false"
438	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add LanmanWorkstation" "false"
439	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add RDPNP" "false"
440
441	; Add the shared folders network provider
442	${LogVerbose} "Adding network provider (Order = $g_iSfOrder) ..."
443	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add VBoxSF $g_iSfOrder" "false"
444
445	!if $%VBOX_WITH_CROGL% == "1"
446	cropengl:
447	${If} $g_bWithWDDM == "true"
448	; Nothing to do here
449	${Else}
450	${LogVerbose} "Installing 3D OpenGL support ..."
451	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "Version" 2
452	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "DriverVersion" 1
453	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "Flags" 1
454	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "Dll" "VBoxOGL.dll"
455	!if $%BUILD_TARGET_ARCH% == "amd64"
456	SetRegView 32
457	; Write additional keys required for Windows XP, Vista and 7 64-bit (but for 32-bit stuff)
458	${If} $g_strWinVersion == '10'
459	${OrIf} $g_strWinVersion == '8_1'
460	${OrIf} $g_strWinVersion == '8'
461	${OrIf} $g_strWinVersion == '7'
462	${OrIf} $g_strWinVersion == 'Vista'
463	${OrIf} $g_strWinVersion == '2003' ; Windows XP 64-bit is a renamed Windows 2003 really
464	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "Version" 2
465	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "DriverVersion" 1
466	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "Flags" 1
467	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "Dll" "VBoxOGL.dll"
468	${EndIf}
469	SetRegView 64
470	!endif
471	${Endif}
472	!endif
473
474	Goto done
475
476	done:
477
478	Pop $0
479
480	FunctionEnd
481
482	Function W2K_Main
483
484	SetOutPath "$INSTDIR"
485	SetOverwrite on
486
487	Call W2K_Prepare
488	Call W2K_CopyFiles
489
490	!ifdef WHQL_FAKE
491	Call W2K_WHQLFakeOn
492	!endif
493
494	Call W2K_InstallFiles
495
496	!ifdef WHQL_FAKE
497	Call W2K_WHQLFakeOff
498	!endif
499
500	Call W2K_SetVideoResolution
501
502	FunctionEnd
503
504	!macro W2K_UninstallInstDir un
505	Function ${un}W2K_UninstallInstDir
506
507	Delete /REBOOTOK "$INSTDIR\VBoxVideo.sys"
508	Delete /REBOOTOK "$INSTDIR\VBoxVideo.inf"
509	Delete /REBOOTOK "$INSTDIR\VBoxVideo.cat"
510	Delete /REBOOTOK "$INSTDIR\VBoxDisp.dll"
511
512	Delete /REBOOTOK "$INSTDIR\VBoxMouse.sys"
513	Delete /REBOOTOK "$INSTDIR\VBoxMouse.inf"
514	Delete /REBOOTOK "$INSTDIR\VBoxMouse.cat"
515
516	Delete /REBOOTOK "$INSTDIR\VBoxTray.exe"
517
518	Delete /REBOOTOK "$INSTDIR\VBoxGuest.sys"
519	Delete /REBOOTOK "$INSTDIR\VBoxGuest.inf"
520	Delete /REBOOTOK "$INSTDIR\VBoxGuest.cat"
521
522	Delete /REBOOTOK "$INSTDIR\VBCoInst.dll" ; Deprecated, does not get installed anymore
523	Delete /REBOOTOK "$INSTDIR\VBoxControl.exe"
524	Delete /REBOOTOK "$INSTDIR\VBoxService.exe" ; Deprecated, does not get installed anymore
525
526	!if $%VBOX_WITH_WDDM% == "1"
527	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxWddm.cat"
528	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxWddm.sys"
529	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxWddm.inf"
530	; Obsolete files begin
531	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxVideoWddm.cat"
532	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxVideoWddm.sys"
533	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxVideoWddm.inf"
534	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxVideoW8.cat"
535	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxVideoW8.sys"
536	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxVideoW8.inf"
537	; Obsolete files end
538	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxDispD3D.dll"
539	!if $%VBOX_WITH_MESA3D% == "1"
540	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxNine.dll"
541	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxSVGA.dll"
542	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxICD.dll"
543	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxGL.dll"
544	!endif
545
546	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLarrayspu.dll"
547	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLcrutil.dll"
548	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLerrorspu.dll"
549	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLpackspu.dll"
550	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLpassthroughspu.dll"
551	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLfeedbackspu.dll"
552	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGL.dll"
553
554	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxD3D9wddm.dll"
555	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\wined3dwddm.dll"
556	; Try to delete libWine in case it is there from old installation
557	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\libWine.dll"
558
559	!if $%BUILD_TARGET_ARCH% == "amd64"
560	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxDispD3D-x86.dll"
561	!if $%VBOX_WITH_MESA3D% == "1"
562	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxNine-x86.dll"
563	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxSVGA-x86.dll"
564	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxICD-x86.dll"
565	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxGL-x86.dll"
566	!endif
567
568	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLarrayspu-x86.dll"
569	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLcrutil-x86.dll"
570	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLerrorspu-x86.dll"
571	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLpackspu-x86.dll"
572	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLpassthroughspu-x86.dll"
573	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLfeedbackspu-x86.dll"
574	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGL-x86.dll"
575
576	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxD3D9wddm-x86.dll"
577	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\wined3dwddm-x86.dll"
578	!endif ; $%BUILD_TARGET_ARCH% == "amd64"
579	!endif ; $%VBOX_WITH_WDDM% == "1"
580
581	; WHQL fake
582	!ifdef WHQL_FAKE
583	Delete /REBOOTOK "$INSTDIR\VBoxWHQLFake.exe"
584	!endif
585
586	; Log file
587	Delete /REBOOTOK "$INSTDIR\install.log"
588	Delete /REBOOTOK "$INSTDIR\install_ui.log"
589
590	FunctionEnd
591	!macroend
592	!insertmacro W2K_UninstallInstDir ""
593	!insertmacro W2K_UninstallInstDir "un."
594
595	!macro W2K_Uninstall un
596	Function ${un}W2K_Uninstall
597
598	Push $0
599
600	; Remove VirtualBox video driver
601	${LogVerbose} "Uninstalling video driver ..."
602	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxVideo.inf$\"" "true"
603	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxVideo" "true"
604	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxVideo.sys"
605	Delete /REBOOTOK "$g_strSystemDir\VBoxDisp.dll"
606
607	; Remove video driver
608	!if $%VBOX_WITH_WDDM% == "1"
609
610	${LogVerbose} "Uninstalling WDDM video driver..."
611	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxWddm.inf$\"" "true"
612	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxWddm" "true"
613	;misha> @todo driver file removal (as well as service removal) should be done as driver package uninstall
614	; could be done with "VBoxDrvInst.exe /u", e.g. by passing additional arg to it denoting that driver package is to be uninstalled
615	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxWddm.sys"
616
617	; Obsolete files begin
618	${LogVerbose} "Uninstalling WDDM video driver for Windows 8..."
619	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxVideoW8.inf$\"" "true"
620	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxVideoW8" "true"
621	;misha> @todo driver file removal (as well as service removal) should be done as driver package uninstall
622	; could be done with "VBoxDrvInst.exe /u", e.g. by passing additional arg to it denoting that driver package is to be uninstalled
623	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxVideoW8.sys"
624
625	${LogVerbose} "Uninstalling WDDM video driver for Windows Vista and 7..."
626	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxVideoWddm.inf$\"" "true"
627	; Always try to remove both VBoxVideoWddm & VBoxVideo services no matter what is installed currently
628	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxVideoWddm" "true"
629	;misha> @todo driver file removal (as well as service removal) should be done as driver package uninstall
630	; could be done with "VBoxDrvInst.exe /u", e.g. by passing additional arg to it denoting that driver package is to be uninstalled
631	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxVideoWddm.sys"
632	; Obsolete files end
633
634	Delete /REBOOTOK "$g_strSystemDir\VBoxDispD3D.dll"
635	!if $%VBOX_WITH_MESA3D% == "1"
636	Delete /REBOOTOK "$g_strSystemDir\VBoxNine.dll"
637	Delete /REBOOTOK "$g_strSystemDir\VBoxSVGA.dll"
638	Delete /REBOOTOK "$g_strSystemDir\VBoxICD.dll"
639	Delete /REBOOTOK "$g_strSystemDir\VBoxGL.dll"
640	!endif
641	!endif ; $%VBOX_WITH_WDDM% == "1"
642
643	!if $%VBOX_WITH_CROGL% == "1"
644
645	${LogVerbose} "Removing Direct3D support ..."
646
647	; Do file validation before we uninstall
648	Call ${un}ValidateD3DFiles
649	Pop $0
650	${If} $0 == "1" ; D3D files are invalid
651	${LogVerbose} $(VBOX_UNINST_INVALID_D3D)
652	MessageBox MB_ICONSTOP\|MB_OK $(VBOX_UNINST_INVALID_D3D) /SD IDOK
653	Goto d3d_uninstall_end
654	${EndIf}
655
656	Delete /REBOOTOK "$g_strSystemDir\VBoxOGLarrayspu.dll"
657	Delete /REBOOTOK "$g_strSystemDir\VBoxOGLcrutil.dll"
658	Delete /REBOOTOK "$g_strSystemDir\VBoxOGLerrorspu.dll"
659	Delete /REBOOTOK "$g_strSystemDir\VBoxOGLpackspu.dll"
660	Delete /REBOOTOK "$g_strSystemDir\VBoxOGLpassthroughspu.dll"
661	Delete /REBOOTOK "$g_strSystemDir\VBoxOGLfeedbackspu.dll"
662	Delete /REBOOTOK "$g_strSystemDir\VBoxOGL.dll"
663
664	; Remove D3D stuff
665	; @todo add a feature flag to only remove if installed explicitly
666	Delete /REBOOTOK "$g_strSystemDir\libWine.dll"
667	Delete /REBOOTOK "$g_strSystemDir\VBoxD3D8.dll"
668	Delete /REBOOTOK "$g_strSystemDir\VBoxD3D9.dll"
669	Delete /REBOOTOK "$g_strSystemDir\wined3d.dll"
670	; Update DLL cache
671	${If} ${FileExists} "$g_strSystemDir\dllcache\msd3d8.dll"
672	Delete /REBOOTOK "$g_strSystemDir\dllcache\d3d8.dll"
673	Rename /REBOOTOK "$g_strSystemDir\dllcache\msd3d8.dll" "$g_strSystemDir\dllcache\d3d8.dll"
674	${EndIf}
675	${If} ${FileExists} "$g_strSystemDir\dllcache\msd3d9.dll"
676	Delete /REBOOTOK "$g_strSystemDir\dllcache\d3d9.dll"
677	Rename /REBOOTOK "$g_strSystemDir\dllcache\msd3d9.dll" "$g_strSystemDir\dllcache\d3d9.dll"
678	${EndIf}
679	; Restore original DX DLLs
680	${If} ${FileExists} "$g_strSystemDir\msd3d8.dll"
681	Delete /REBOOTOK "$g_strSystemDir\d3d8.dll"
682	Rename /REBOOTOK "$g_strSystemDir\msd3d8.dll" "$g_strSystemDir\d3d8.dll"
683	${EndIf}
684	${If} ${FileExists} "$g_strSystemDir\msd3d9.dll"
685	Delete /REBOOTOK "$g_strSystemDir\d3d9.dll"
686	Rename /REBOOTOK "$g_strSystemDir\msd3d9.dll" "$g_strSystemDir\d3d9.dll"
687	${EndIf}
688
689	!if $%BUILD_TARGET_ARCH% == "amd64"
690	; Only 64-bit installer: Also remove 32-bit DLLs on 64-bit target arch in Wow64 node
691	Delete /REBOOTOK "$g_strSysWow64\VBoxOGLarrayspu.dll"
692	Delete /REBOOTOK "$g_strSysWow64\VBoxOGLcrutil.dll"
693	Delete /REBOOTOK "$g_strSysWow64\VBoxOGLerrorspu.dll"
694	Delete /REBOOTOK "$g_strSysWow64\VBoxOGLpackspu.dll"
695	Delete /REBOOTOK "$g_strSysWow64\VBoxOGLpassthroughspu.dll"
696	Delete /REBOOTOK "$g_strSysWow64\VBoxOGLfeedbackspu.dll"
697	Delete /REBOOTOK "$g_strSysWow64\VBoxOGL.dll"
698
699	; Remove D3D stuff
700	; @todo add a feature flag to only remove if installed explicitly
701	Delete /REBOOTOK "$g_strSysWow64\libWine.dll"
702	Delete /REBOOTOK "$g_strSysWow64\VBoxD3D8.dll"
703	Delete /REBOOTOK "$g_strSysWow64\VBoxD3D9.dll"
704	Delete /REBOOTOK "$g_strSysWow64\wined3d.dll"
705	; Update DLL cache
706	${If} ${FileExists} "$g_strSysWow64\dllcache\msd3d8.dll"
707	Delete /REBOOTOK "$g_strSysWow64\dllcache\d3d8.dll"
708	Rename /REBOOTOK "$g_strSysWow64\dllcache\msd3d8.dll" "$g_strSysWow64\dllcache\d3d8.dll"
709	${EndIf}
710	${If} ${FileExists} "$g_strSysWow64\dllcache\msd3d9.dll"
711	Delete /REBOOTOK "$g_strSysWow64\dllcache\d3d9.dll"
712	Rename /REBOOTOK "$g_strSysWow64\dllcache\msd3d9.dll" "$g_strSysWow64\dllcache\d3d9.dll"
713	${EndIf}
714	; Restore original DX DLLs
715	${If} ${FileExists} "$g_strSysWow64\msd3d8.dll"
716	Delete /REBOOTOK "$g_strSysWow64\d3d8.dll"
717	Rename /REBOOTOK "$g_strSysWow64\msd3d8.dll" "$g_strSysWow64\d3d8.dll"
718	${EndIf}
719	${If} ${FileExists} "$g_strSysWow64\msd3d9.dll"
720	Delete /REBOOTOK "$g_strSysWow64\d3d9.dll"
721	Rename /REBOOTOK "$g_strSysWow64\msd3d9.dll" "$g_strSysWow64\d3d9.dll"
722	${EndIf}
723	DeleteRegKey HKLM "SOFTWARE\Wow6432Node\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL"
724	!endif ; amd64
725
726	DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL"
727
728	d3d_uninstall_end:
729
730	!endif ; VBOX_WITH_CROGL
731
732	; Remove mouse driver
733	${LogVerbose} "Removing mouse driver ..."
734	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxMouse" "true"
735	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxMouse.sys"
736	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" registry delmultisz $\"SYSTEM\CurrentControlSet\Control\Class\{4D36E96F-E325-11CE-BFC1-08002BE10318}$\" $\"UpperFilters$\" $\"VBoxMouse$\"" "true"
737
738	; Delete the VBoxService service
739	Call ${un}StopVBoxService
740	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxService" "true"
741	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxService"
742	Delete /REBOOTOK "$g_strSystemDir\VBoxService.exe"
743
744	; VBoxGINA
745	Delete /REBOOTOK "$g_strSystemDir\VBoxGINA.dll"
746	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
747	${If} $0 == "VBoxGINA.dll"
748	${LogVerbose} "Removing auto-logon support ..."
749	DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
750	${EndIf}
751	DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon\Notify\VBoxGINA"
752
753	; Delete VBoxTray
754	Call ${un}StopVBoxTray
755	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxTray"
756
757	; Remove guest driver
758	${LogVerbose} "Removing guest driver ..."
759	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" driver uninstall $\"$INSTDIR\VBoxGuest.inf$\"" "true"
760
761	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxGuest" "true"
762	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxGuest.sys"
763	Delete /REBOOTOK "$g_strSystemDir\VBCoInst.dll" ; Deprecated, does not get installed anymore
764	Delete /REBOOTOK "$g_strSystemDir\VBoxTray.exe"
765	Delete /REBOOTOK "$g_strSystemDir\VBoxHook.dll"
766	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxTray" ; Remove VBoxTray autorun
767	Delete /REBOOTOK "$g_strSystemDir\VBoxControl.exe"
768
769	; Remove shared folders driver
770	${LogVerbose} "Removing shared folders driver ..."
771	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider remove VBoxSF" "true"
772	${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxSF" "true"
773	Delete /REBOOTOK "$g_strSystemDir\VBoxMRXNP.dll" ; The network provider DLL will be locked
774	!if $%BUILD_TARGET_ARCH% == "amd64"
775	; Only 64-bit installer: Also remove 32-bit DLLs on 64-bit target arch in Wow64 node
776	Delete /REBOOTOK "$g_strSysWow64\VBoxMRXNP.dll"
777	!endif ; amd64
778	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxSF.sys"
779
780	Pop $0
781
782	FunctionEnd
783	!macroend
784	!insertmacro W2K_Uninstall ""
785	!insertmacro W2K_Uninstall "un."
786

Note: See TracBrowser for help on using the repository browser.

source: vbox/trunk/src/VBox/Additions/WINNT/Installer/VBoxGuestAdditionsW2KXP.nsh@ 76553

Download in other formats: