VBoxGuestAdditionsW2KXP.nsh@ 40257

Last change on this file since 40257 was 40136, checked in by vboxsync, 13 years ago
VBoxMRXNP, Additions installer: build and install a 32 bit version for 64 bit guests.
Property svn:eol-style set to `native`
File size: 28.7 KB

Line
1	; $Id: $
2	;; @file
3	; VBoxGuestAdditionsW2KXP.nsh - Guest Additions installation for Windows 2000/XP.
4	;
5
6	;
7	; Copyright (C) 2006-2011 Oracle Corporation
8	;
9	; This file is part of VirtualBox Open Source Edition (OSE), as
10	; available from http://www.virtualbox.org. This file is free software;
11	; you can redistribute it and/or modify it under the terms of the GNU
12	; General Public License (GPL) as published by the Free Software
13	; Foundation, in version 2 as it comes in the "COPYING" file of the
14	; VirtualBox OSE distribution. VirtualBox OSE is distributed in the
15	; hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
16	;
17
18	Function W2K_SetVideoResolution
19
20	; NSIS only supports global vars, even in functions -- great
21	Var /GLOBAL i
22	Var /GLOBAL tmp
23	Var /GLOBAL tmppath
24	Var /GLOBAL dev_id
25	Var /GLOBAL dev_desc
26
27	; Check for all required parameters
28	StrCmp $g_iScreenX "0" exit
29	StrCmp $g_iScreenY "0" exit
30	StrCmp $g_iScreenBpp "0" exit
31
32	DetailPrint "Setting display parameters ($g_iScreenXx$g_iScreenY, $g_iScreenBpp BPP) ..."
33
34	; Enumerate all video devices (up to 32 at the moment, use key "MaxObjectNumber" key later)
35	${For} $i 0 32
36
37	ReadRegStr $tmp HKLM "HARDWARE\DEVICEMAP\VIDEO" "\Device\Video$i"
38	StrCmp $tmp "" dev_not_found
39
40	; Extract path to video settings
41	; Ex: \Registry\Machine\System\CurrentControlSet\Control\Video\{28B74D2B-F0A9-48E0-8028-D76F6BB1AE65}\0000
42	; Or: \Registry\Machine\System\CurrentControlSet\Control\Video\vboxvideo\Device0
43	; Result: Machine\System\CurrentControlSet\Control\Video\{28B74D2B-F0A9-48E0-8028-D76F6BB1AE65}\0000
44	Push "$tmp" ; String
45	Push "\" ; SubString
46	Push ">" ; SearchDirection
47	Push ">" ; StrInclusionDirection
48	Push "0" ; IncludeSubString
49	Push "2" ; Loops
50	Push "0" ; CaseSensitive
51	Call StrStrAdv
52	Pop $tmppath ; $1 only contains the full path
53	StrCmp $tmppath "" dev_not_found
54
55	; Get device description
56	ReadRegStr $dev_desc HKLM "$tmppath" "Device Description"
57	!ifdef _DEBUG
58	DetailPrint "Registry path: $tmppath"
59	DetailPrint "Registry path to device name: $temp"
60	!endif
61	DetailPrint "Detected video device: $dev_desc"
62
63	${If} $dev_desc == "VirtualBox Graphics Adapter"
64	DetailPrint "VirtualBox video device found!"
65	Goto dev_found
66	${EndIf}
67	${Next}
68	Goto dev_not_found
69
70	dev_found:
71
72	; If we're on Windows 2000, skip the ID detection ...
73	${If} $g_strWinVersion == "2000"
74	Goto change_res
75	${EndIf}
76	Goto dev_found_detect_id
77
78	dev_found_detect_id:
79
80	StrCpy $i 0 ; Start at index 0
81	DetailPrint "Detecting device ID ..."
82
83	dev_found_detect_id_loop:
84
85	; Resolve real path to hardware instance "{GUID}"
86	EnumRegKey $dev_id HKLM "SYSTEM\CurrentControlSet\Control\Video" $i
87	StrCmp $dev_id "" dev_not_found ; No more entries? Jump out
88	!ifdef _DEBUG
89	DetailPrint "Got device ID: $dev_id"
90	!endif
91	ReadRegStr $dev_desc HKLM "SYSTEM\CurrentControlSet\Control\Video\$dev_id\0000" "Device Description" ; Try to read device name
92	${If} $dev_desc == "VirtualBox Graphics Adapter"
93	DetailPrint "Device ID of $dev_desc: $dev_id"
94	Goto change_res
95	${EndIf}
96
97	IntOp $i $i + 1 ; Increment index
98	goto dev_found_detect_id_loop
99
100	dev_not_found:
101
102	DetailPrint "No VirtualBox video device (yet) detected! No custom mode set."
103	Goto exit
104
105	change_res:
106
107	!ifdef _DEBUG
108	DetailPrint "Device description: $dev_desc"
109	DetailPrint "Device ID: $dev_id"
110	!endif
111
112	Var /GLOBAL reg_path_device
113	Var /GLOBAL reg_path_monitor
114
115	DetailPrint "Custom mode set: Platform is Windows $g_strWinVersion"
116	${If} $g_strWinVersion == "2000"
117	${OrIf} $g_strWinVersion == "Vista"
118	StrCpy $reg_path_device "SYSTEM\CurrentControlSet\SERVICES\VBoxVideo\Device0"
119	StrCpy $reg_path_monitor "SYSTEM\CurrentControlSet\SERVICES\VBoxVideo\Device0\Mon00000001"
120	${ElseIf} $g_strWinVersion == "XP"
121	${OrIf} $g_strWinVersion == "7"
122	${OrIf} $g_strWinVersion == "8"
123	StrCpy $reg_path_device "SYSTEM\CurrentControlSet\Control\Video\$dev_id\0000"
124	StrCpy $reg_path_monitor "SYSTEM\CurrentControlSet\Control\VIDEO\$dev_id\0000\Mon00000001"
125	${Else}
126	DetailPrint "Custom mode set: Windows $g_strWinVersion not supported yet"
127	Goto exit
128	${EndIf}
129
130	; Write the new value in the adapter config (VBoxVideo.sys) using hex values in binary format
131	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" registry write HKLM $reg_path_device CustomXRes REG_BIN $g_iScreenX DWORD'
132	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" registry write HKLM $reg_path_device CustomYRes REG_BIN $g_iScreenY DWORD'
133	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" registry write HKLM $reg_path_device CustomBPP REG_BIN $g_iScreenBpp DWORD'
134
135	; ... and tell Windows to use that mode on next start!
136	WriteRegDWORD HKCC $reg_path_device "DefaultSettings.XResolution" "$g_iScreenX"
137	WriteRegDWORD HKCC $reg_path_device "DefaultSettings.YResolution" "$g_iScreenY"
138	WriteRegDWORD HKCC $reg_path_device "DefaultSettings.BitsPerPixel" "$g_iScreenBpp"
139
140	WriteRegDWORD HKCC $reg_path_monitor "DefaultSettings.XResolution" "$g_iScreenX"
141	WriteRegDWORD HKCC $reg_path_monitor "DefaultSettings.YResolution" "$g_iScreenY"
142	WriteRegDWORD HKCC $reg_path_monitor "DefaultSettings.BitsPerPixel" "$g_iScreenBpp"
143
144	DetailPrint "Custom mode set to $g_iScreenXx$g_iScreenY, $g_iScreenBpp BPP on next restart."
145
146	exit:
147
148	FunctionEnd
149
150	Function W2K_Prepare
151
152	${If} $g_bNoVBoxServiceExit == "false"
153	; Stop / kill VBoxService
154	Call StopVBoxService
155	${EndIf}
156
157	${If} $g_bNoVBoxTrayExit == "false"
158	; Stop / kill VBoxTray
159	Call StopVBoxTray
160	${EndIf}
161
162	; Delete VBoxService from registry
163	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxService"
164
165	; Delete old VBoxService.exe from install directory (replaced by VBoxTray.exe)
166	Delete /REBOOTOK "$INSTDIR\VBoxService.exe"
167
168	FunctionEnd
169
170	Function W2K_CopyFiles
171
172	Push $0
173	SetOutPath "$INSTDIR"
174
175	; Video driver
176	FILE "$%PATH_OUT%\bin\additions\VBoxVideo.sys"
177	FILE "$%PATH_OUT%\bin\additions\VBoxDisp.dll"
178
179	; Mouse driver
180	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.sys"
181	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.inf"
182	!ifdef VBOX_SIGN_ADDITIONS
183	FILE "$%PATH_OUT%\bin\additions\VBoxMouse.cat"
184	!endif
185
186	; Guest driver
187	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.sys"
188	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.inf"
189	!ifdef VBOX_SIGN_ADDITIONS
190	FILE "$%PATH_OUT%\bin\additions\VBoxGuest.cat"
191	!endif
192
193	; Guest driver files
194	FILE "$%PATH_OUT%\bin\additions\VBoxTray.exe"
195	FILE "$%PATH_OUT%\bin\additions\VBoxControl.exe" ; Not used by W2K and up, but required by the .INF file
196
197	; WHQL fake
198	!ifdef WHQL_FAKE
199	FILE "$%PATH_OUT%\bin\additions\VBoxWHQLFake.exe"
200	!endif
201
202	SetOutPath $g_strSystemDir
203
204	; VBoxService
205	FILE "$%PATH_OUT%\bin\additions\VBoxService.exe" ; Only used by W2K and up (for Shared Folders at the moment)
206
207	!if $%VBOX_WITH_WDDM% == "1"
208	${If} $g_bWithWDDM == "true"
209	; WDDM Video driver
210	SetOutPath "$INSTDIR"
211
212	!ifdef VBOX_SIGN_ADDITIONS
213	FILE "$%PATH_OUT%\bin\additions\VBoxVideoWddm.cat"
214	!endif
215	FILE "$%PATH_OUT%\bin\additions\VBoxVideoWddm.sys"
216	FILE "$%PATH_OUT%\bin\additions\VBoxVideoWddm.inf"
217	FILE "$%PATH_OUT%\bin\additions\VBoxDispD3D.dll"
218
219	!if $%VBOX_WITH_CROGL% == "1"
220	FILE "$%PATH_OUT%\bin\additions\VBoxOGLarrayspu.dll"
221	FILE "$%PATH_OUT%\bin\additions\VBoxOGLcrutil.dll"
222	FILE "$%PATH_OUT%\bin\additions\VBoxOGLerrorspu.dll"
223	FILE "$%PATH_OUT%\bin\additions\VBoxOGLpackspu.dll"
224	FILE "$%PATH_OUT%\bin\additions\VBoxOGLpassthroughspu.dll"
225	FILE "$%PATH_OUT%\bin\additions\VBoxOGLfeedbackspu.dll"
226	FILE "$%PATH_OUT%\bin\additions\VBoxOGL.dll"
227
228	FILE "$%PATH_OUT%\bin\additions\VBoxD3D9wddm.dll"
229	FILE "$%PATH_OUT%\bin\additions\wined3dwddm.dll"
230	!endif ; $%VBOX_WITH_CROGL% == "1"
231
232	!if $%BUILD_TARGET_ARCH% == "amd64"
233	FILE "$%PATH_OUT%\bin\additions\VBoxDispD3D-x86.dll"
234
235	!if $%VBOX_WITH_CROGL% == "1"
236	FILE "$%PATH_OUT%\bin\additions\VBoxOGLarrayspu-x86.dll"
237	FILE "$%PATH_OUT%\bin\additions\VBoxOGLcrutil-x86.dll"
238	FILE "$%PATH_OUT%\bin\additions\VBoxOGLerrorspu-x86.dll"
239	FILE "$%PATH_OUT%\bin\additions\VBoxOGLpackspu-x86.dll"
240	FILE "$%PATH_OUT%\bin\additions\VBoxOGLpassthroughspu-x86.dll"
241	FILE "$%PATH_OUT%\bin\additions\VBoxOGLfeedbackspu-x86.dll"
242	FILE "$%PATH_OUT%\bin\additions\VBoxOGL-x86.dll"
243
244	FILE "$%PATH_OUT%\bin\additions\VBoxD3D9wddm-x86.dll"
245	FILE "$%PATH_OUT%\bin\additions\wined3dwddm-x86.dll"
246	!endif ; $%VBOX_WITH_CROGL% == "1"
247	!endif ; $%BUILD_TARGET_ARCH% == "amd64"
248
249	Goto doneCr
250	${EndIf}
251	!endif ; $%VBOX_WITH_WDDM% == "1"
252
253	!if $%VBOX_WITH_CROGL% == "1"
254	; crOpenGL
255	!if $%BUILD_TARGET_ARCH% == "amd64"
256	!define LIBRARY_X64 ; Enable installation of 64-bit libraries
257	!endif
258	StrCpy $0 "$TEMP\VBoxGuestAdditions\VBoxOGL"
259	CreateDirectory "$0"
260	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGLarrayspu.dll" "$g_strSystemDir\VBoxOGLarrayspu.dll" "$0"
261	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGLcrutil.dll" "$g_strSystemDir\VBoxOGLcrutil.dll" "$0"
262	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGLerrorspu.dll" "$g_strSystemDir\VBoxOGLerrorspu.dll" "$0"
263	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGLpackspu.dll" "$g_strSystemDir\VBoxOGLpackspu.dll" "$0"
264	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGLpassthroughspu.dll" "$g_strSystemDir\VBoxOGLpassthroughspu.dll" "$0"
265	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGLfeedbackspu.dll" "$g_strSystemDir\VBoxOGLfeedbackspu.dll" "$0"
266	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%PATH_OUT%\bin\additions\VBoxOGL.dll" "$g_strSystemDir\VBoxOGL.dll" "$0"
267	!if $%BUILD_TARGET_ARCH% == "amd64"
268	!undef LIBRARY_X64 ; Disable installation of 64-bit libraries
269	!endif
270
271	!if $%BUILD_TARGET_ARCH% == "amd64"
272	StrCpy $0 "$TEMP\VBoxGuestAdditions\VBoxOGL32"
273	CreateDirectory "$0"
274	; Only 64-bit installer: Also copy 32-bit DLLs on 64-bit target arch in
275	; Wow64 node (32-bit sub system). Note that $SYSDIR contains the 32-bit
276	; path after calling EnableX64FSRedirection
277	${EnableX64FSRedirection}
278	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGLarrayspu.dll" "$SYSDIR\VBoxOGLarrayspu.dll" "$0"
279	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGLcrutil.dll" "$SYSDIR\VBoxOGLcrutil.dll" "$0"
280	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGLerrorspu.dll" "$SYSDIR\VBoxOGLerrorspu.dll" "$0"
281	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGLpackspu.dll" "$SYSDIR\VBoxOGLpackspu.dll" "$0"
282	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGLpassthroughspu.dll" "$SYSDIR\VBoxOGLpassthroughspu.dll" "$0"
283	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGLfeedbackspu.dll" "$SYSDIR\VBoxOGLfeedbackspu.dll" "$0"
284	!insertmacro InstallLib DLL NOTSHARED REBOOT_PROTECTED "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxOGL.dll" "$SYSDIR\VBoxOGL.dll" "$0"
285	${DisableX64FSRedirection}
286	!endif
287
288	!endif ; VBOX_WITH_CROGL
289
290	doneCr:
291
292	Pop $0
293
294	FunctionEnd
295
296	!ifdef WHQL_FAKE
297
298	Function W2K_WHQLFakeOn
299
300	StrCmp $g_bFakeWHQL "true" do
301	Goto exit
302
303	do:
304
305	DetailPrint "Turning off WHQL protection..."
306	nsExec::ExecToLog '"$INSTDIR\VBoxWHQLFake.exe" "ignore"'
307
308	exit:
309
310	FunctionEnd
311
312	Function W2K_WHQLFakeOff
313
314	StrCmp $g_bFakeWHQL "true" do
315	Goto exit
316
317	do:
318
319	DetailPrint "Turning back on WHQL protection..."
320	nsExec::ExecToLog '"$INSTDIR\VBoxWHQLFake.exe" "warn"'
321
322	exit:
323
324	FunctionEnd
325
326	!endif
327
328	Function W2K_InstallFiles
329
330	; The Shared Folder IFS goes to the system directory
331	FILE /oname=$g_strSystemDir\drivers\VBoxSF.sys "$%PATH_OUT%\bin\additions\VBoxSF.sys"
332	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxMRXNP.dll" "$g_strSystemDir\VBoxMRXNP.dll" "$INSTDIR"
333	AccessControl::GrantOnFile "$g_strSystemDir\VBoxMRXNP.dll" "(BU)" "GenericRead"
334	!if $%BUILD_TARGET_ARCH% == "amd64"
335	; Only 64-bit installer: Copy the 32-bit DLL for 32 bit applications.
336	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxMRXNP-x86.dll" "$g_strSysWow64\VBoxMRXNP.dll" "$INSTDIR"
337	AccessControl::GrantOnFile "$g_strSysWow64\VBoxMRXNP.dll" "(BU)" "GenericRead"
338	!endif
339
340	; The VBoxTray hook DLL also goes to the system directory; it might be locked
341	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxHook.dll" "$g_strSystemDir\VBoxHook.dll" "$INSTDIR"
342	AccessControl::GrantOnFile "$g_strSystemDir\VBoxHook.dll" "(BU)" "GenericRead"
343
344	DetailPrint "Installing drivers ..."
345
346	Push $0 ; For fetching results
347
348	SetOutPath "$INSTDIR"
349
350	${If} $g_bNoGuestDrv == "false"
351	DetailPrint "Installing guest driver ..."
352	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" driver install "$INSTDIR\VBoxGuest.inf" "$INSTDIR\install_drivers.log"'
353	Pop $0 ; Ret value
354	LogText "Guest driver returned: $0"
355	IntCmp $0 0 +1 error error ; Check ret value (0=OK, 1=Error)
356	${Else}
357	LogText "Guest driver installation skipped!"
358	${EndIf}
359
360	${If} $g_bNoVideoDrv == "false"
361	${If} $g_bWithWDDM == "true"
362	DetailPrint "Installing WDDM video driver ..."
363	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" driver install "$INSTDIR\VBoxVideoWddm.inf" "$INSTDIR\install_drivers.log"'
364	${Else}
365	DetailPrint "Installing video driver ..."
366	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" driver install "$INSTDIR\VBoxVideo.inf" "$INSTDIR\install_drivers.log"'
367	${EndIf}
368	Pop $0 ; Ret value
369	LogText "Video driver returned: $0"
370	IntCmp $0 0 +1 error error ; Check ret value (0=OK, 1=Error)
371	${Else}
372	LogText "Video driver installation skipped!"
373	${EndIf}
374
375	${If} $g_bNoMouseDrv == "false"
376	DetailPrint "Installing mouse driver ..."
377	; The mouse filter does not contain any device IDs but a "DefaultInstall" section;
378	; so this .INF file needs to be installed using "InstallHinfSection" which is implemented
379	; with VBoxDrvInst's "driver executeinf" routine
380	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" driver executeinf "$INSTDIR\VBoxMouse.inf"'
381	Pop $0 ; Ret value
382	LogText "Mouse driver returned: $0"
383	IntCmp $0 0 +1 error error ; Check ret value (0=OK, 1=Error)
384	${Else}
385	LogText "Mouse driver installation skipped!"
386	${EndIf}
387
388	; Create the VBoxService service
389	; No need to stop/remove the service here! Do this only on uninstallation!
390	DetailPrint "Installing VirtualBox service ..."
391	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" service create "VBoxService" "VirtualBox Guest Additions Service" 16 2 "system32\VBoxService.exe" "Base"'
392	Pop $0 ; Ret value
393	LogText "VBoxService returned: $0"
394
395	; Set service description
396	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxService" "Description" "Manages VM runtime information, time synchronization, remote sysprep execution and miscellaneous utilities for guest operating systems."
397
398	sf:
399
400	DetailPrint "Installing Shared Folders service ..."
401
402	; Create the Shared Folders service ...
403	; No need to stop/remove the service here! Do this only on uninstallation!
404	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" service create "VBoxSF" "VirtualBox Shared Folders" 2 1 "system32\drivers\VBoxSF.sys" "NetworkProvider"'
405
406	; ... and the link to the network provider
407	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "DeviceName" "\Device\VBoxMiniRdr"
408	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "Name" "VirtualBox Shared Folders"
409	WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "ProviderPath" "$SYSDIR\VBoxMRXNP.dll"
410
411	; Add default network providers (if not present or corrupted)
412	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" netprovider add WebClient'
413	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" netprovider add LanmanWorkstation'
414	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" netprovider add RDPNP'
415
416	; Add the shared folders network provider
417	DetailPrint "Adding network provider (Order = $g_iSfOrder) ..."
418	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" netprovider add VBoxSF $g_iSfOrder'
419	Pop $0 ; Ret value
420	IntCmp $0 0 +1 error error ; Check ret value (0=OK, 1=Error)
421
422	!if $%VBOX_WITH_CROGL% == "1"
423	cropengl:
424	${If} $g_bWithWDDM == "true"
425	; Nothing to do here
426	${Else}
427	DetailPrint "Installing 3D OpenGL support ..."
428	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "Version" 2
429	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "DriverVersion" 1
430	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "Flags" 1
431	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "Dll" "VBoxOGL.dll"
432	!if $%BUILD_TARGET_ARCH% == "amd64"
433	SetRegView 32
434	; Write additional keys required for Windows XP, Vista and 7 64-bit (but for 32-bit stuff)
435	${If} $g_strWinVersion == '8'
436	${OrIf} $g_strWinVersion == '7'
437	${OrIf} $g_strWinVersion == 'Vista'
438	${OrIf} $g_strWinVersion == '2003' ; Windows XP 64-bit is a renamed Windows 2003 really
439	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "Version" 2
440	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "DriverVersion" 1
441	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "Flags" 1
442	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL" "Dll" "VBoxOGL.dll"
443	${EndIf}
444	SetRegView 64
445	!endif
446	${Endif}
447	!endif
448
449	Goto done
450
451	error:
452
453	Abort "ERROR: Could not install files for Windows 2000 / XP / Vista! Installation aborted."
454
455	done:
456
457	Pop $0
458
459	FunctionEnd
460
461	Function W2K_Main
462
463	SetOutPath "$INSTDIR"
464	SetOverwrite on
465
466	Call W2K_Prepare
467	Call W2K_CopyFiles
468
469	!ifdef WHQL_FAKE
470	Call W2K_WHQLFakeOn
471	!endif
472
473	Call W2K_InstallFiles
474
475	!ifdef WHQL_FAKE
476	Call W2K_WHQLFakeOff
477	!endif
478
479	Call W2K_SetVideoResolution
480
481	FunctionEnd
482
483	!macro W2K_UninstallInstDir un
484	Function ${un}W2K_UninstallInstDir
485
486	Delete /REBOOTOK "$INSTDIR\VBoxVideo.sys"
487	Delete /REBOOTOK "$INSTDIR\VBoxVideo.inf"
488	Delete /REBOOTOK "$INSTDIR\VBoxVideo.cat"
489	Delete /REBOOTOK "$INSTDIR\VBoxDisp.dll"
490
491	Delete /REBOOTOK "$INSTDIR\VBoxMouse.sys"
492	Delete /REBOOTOK "$INSTDIR\VBoxMouse.inf"
493	Delete /REBOOTOK "$INSTDIR\VBoxMouse.cat"
494
495	Delete /REBOOTOK "$INSTDIR\VBoxTray.exe"
496
497	Delete /REBOOTOK "$INSTDIR\VBoxGuest.sys"
498	Delete /REBOOTOK "$INSTDIR\VBoxGuest.inf"
499	Delete /REBOOTOK "$INSTDIR\VBoxGuest.cat"
500
501	Delete /REBOOTOK "$INSTDIR\VBCoInst.dll" ; Deprecated, does not get installed anymore
502	Delete /REBOOTOK "$INSTDIR\VBoxControl.exe"
503	Delete /REBOOTOK "$INSTDIR\VBoxService.exe" ; Deprecated, does not get installed anymore
504
505	!if $%VBOX_WITH_WDDM% == "1"
506	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxVideoWddm.cat"
507	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxVideoWddm.sys"
508	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxVideoWddm.inf"
509	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxDispD3D.dll"
510
511	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLarrayspu.dll"
512	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLcrutil.dll"
513	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLerrorspu.dll"
514	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLpackspu.dll"
515	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLpassthroughspu.dll"
516	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLfeedbackspu.dll"
517	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGL.dll"
518
519	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxD3D9wddm.dll"
520	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\wined3dwddm.dll"
521	; Try to delete libWine in case it is there from old installation
522	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\libWine.dll"
523
524	!if $%BUILD_TARGET_ARCH% == "amd64"
525	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxDispD3D-x86.dll"
526
527	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLarrayspu-x86.dll"
528	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLcrutil-x86.dll"
529	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLerrorspu-x86.dll"
530	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLpackspu-x86.dll"
531	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLpassthroughspu-x86.dll"
532	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGLfeedbackspu-x86.dll"
533	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxOGL-x86.dll"
534
535	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\VBoxD3D9wddm-x86.dll"
536	Delete /REBOOTOK "$%PATH_OUT%\bin\additions\wined3dwddm-x86.dll"
537	!endif ; $%BUILD_TARGET_ARCH% == "amd64"
538	!endif ; $%VBOX_WITH_WDDM% == "1"
539
540	; WHQL fake
541	!ifdef WHQL_FAKE
542	Delete /REBOOTOK "$INSTDIR\VBoxWHQLFake.exe"
543	!endif
544
545	; Log file
546	Delete /REBOOTOK "$INSTDIR\install.log"
547	Delete /REBOOTOK "$INSTDIR\install_ui.log"
548
549	FunctionEnd
550	!macroend
551	!insertmacro W2K_UninstallInstDir ""
552	!insertmacro W2K_UninstallInstDir "un."
553
554	!macro W2K_Uninstall un
555	Function ${un}W2K_Uninstall
556
557	Push $0
558
559	; Remove VirtualBox video driver
560	DetailPrint "Uninstalling video driver ..."
561	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" driver uninstall "$INSTDIR\VBoxVideo.inf'
562	Pop $0 ; Ret value
563	; @todo Add error handling here!
564	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" service delete VBoxVideo'
565	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxVideo.sys"
566	Delete /REBOOTOK "$g_strSystemDir\VBoxDisp.dll"
567
568	; Remove video driver
569	!if $%VBOX_WITH_WDDM% == "1"
570	DetailPrint "Uninstalling WDDM video driver ..."
571	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" driver uninstall "$INSTDIR\VBoxVideoWddm.inf"'
572	Pop $0 ; Ret value
573	; Always try to remove both VBoxVideoWddm & VBoxVideo services no matter what is installed currently
574	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" service delete VBoxVideoWddm'
575	Pop $0 ; Ret value
576	;misha> @todo driver file removal (as well as service removal) should be done as driver package uninstall
577	; could be done with "VBoxDrvInst.exe /u", e.g. by passing additional arg to it denoting that driver package is to be uninstalled
578	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxVideoWddm.sys"
579	Delete /REBOOTOK "$g_strSystemDir\VBoxDispD3D.dll"
580	!endif ; $%VBOX_WITH_WDDM% == "1"
581
582	!if $%VBOX_WITH_CROGL% == "1"
583
584	DetailPrint "Removing Direct3D support ..."
585
586	; Do file validation before we uninstall
587	Call ${un}ValidateD3DFiles
588	Pop $0
589	${If} $0 == "1" ; D3D files are invalid
590	DetailPrint $(VBOX_UNINST_INVALID_D3D)
591	MessageBox MB_ICONSTOP\|MB_OK $(VBOX_UNINST_INVALID_D3D) /SD IDOK
592	Goto d3d_uninstall_end
593	${EndIf}
594
595	Delete /REBOOTOK "$g_strSystemDir\VBoxOGLarrayspu.dll"
596	Delete /REBOOTOK "$g_strSystemDir\VBoxOGLcrutil.dll"
597	Delete /REBOOTOK "$g_strSystemDir\VBoxOGLerrorspu.dll"
598	Delete /REBOOTOK "$g_strSystemDir\VBoxOGLpackspu.dll"
599	Delete /REBOOTOK "$g_strSystemDir\VBoxOGLpassthroughspu.dll"
600	Delete /REBOOTOK "$g_strSystemDir\VBoxOGLfeedbackspu.dll"
601	Delete /REBOOTOK "$g_strSystemDir\VBoxOGL.dll"
602
603	; Remove D3D stuff
604	; @todo add a feature flag to only remove if installed explicitly
605	Delete /REBOOTOK "$g_strSystemDir\libWine.dll"
606	Delete /REBOOTOK "$g_strSystemDir\VBoxD3D8.dll"
607	Delete /REBOOTOK "$g_strSystemDir\VBoxD3D9.dll"
608	Delete /REBOOTOK "$g_strSystemDir\wined3d.dll"
609	; Update DLL cache
610	${If} ${FileExists} "$g_strSystemDir\dllcache\msd3d8.dll"
611	Delete /REBOOTOK "$g_strSystemDir\dllcache\d3d8.dll"
612	Rename /REBOOTOK "$g_strSystemDir\dllcache\msd3d8.dll" "$g_strSystemDir\dllcache\d3d8.dll"
613	${EndIf}
614	${If} ${FileExists} "$g_strSystemDir\dllcache\msd3d9.dll"
615	Delete /REBOOTOK "$g_strSystemDir\dllcache\d3d9.dll"
616	Rename /REBOOTOK "$g_strSystemDir\dllcache\msd3d9.dll" "$g_strSystemDir\dllcache\d3d9.dll"
617	${EndIf}
618	; Restore original DX DLLs
619	${If} ${FileExists} "$g_strSystemDir\msd3d8.dll"
620	Delete /REBOOTOK "$g_strSystemDir\d3d8.dll"
621	Rename /REBOOTOK "$g_strSystemDir\msd3d8.dll" "$g_strSystemDir\d3d8.dll"
622	${EndIf}
623	${If} ${FileExists} "$g_strSystemDir\msd3d9.dll"
624	Delete /REBOOTOK "$g_strSystemDir\d3d9.dll"
625	Rename /REBOOTOK "$g_strSystemDir\msd3d9.dll" "$g_strSystemDir\d3d9.dll"
626	${EndIf}
627
628	!if $%BUILD_TARGET_ARCH% == "amd64"
629	; Only 64-bit installer: Also remove 32-bit DLLs on 64-bit target arch in Wow64 node
630	Delete /REBOOTOK "$g_strSysWow64\VBoxOGLarrayspu.dll"
631	Delete /REBOOTOK "$g_strSysWow64\VBoxOGLcrutil.dll"
632	Delete /REBOOTOK "$g_strSysWow64\VBoxOGLerrorspu.dll"
633	Delete /REBOOTOK "$g_strSysWow64\VBoxOGLpackspu.dll"
634	Delete /REBOOTOK "$g_strSysWow64\VBoxOGLpassthroughspu.dll"
635	Delete /REBOOTOK "$g_strSysWow64\VBoxOGLfeedbackspu.dll"
636	Delete /REBOOTOK "$g_strSysWow64\VBoxOGL.dll"
637
638	; Remove D3D stuff
639	; @todo add a feature flag to only remove if installed explicitly
640	Delete /REBOOTOK "$g_strSysWow64\libWine.dll"
641	Delete /REBOOTOK "$g_strSysWow64\VBoxD3D8.dll"
642	Delete /REBOOTOK "$g_strSysWow64\VBoxD3D9.dll"
643	Delete /REBOOTOK "$g_strSysWow64\wined3d.dll"
644	; Update DLL cache
645	${If} ${FileExists} "$g_strSysWow64\dllcache\msd3d8.dll"
646	Delete /REBOOTOK "$g_strSysWow64\dllcache\d3d8.dll"
647	Rename /REBOOTOK "$g_strSysWow64\dllcache\msd3d8.dll" "$g_strSysWow64\dllcache\d3d8.dll"
648	${EndIf}
649	${If} ${FileExists} "$g_strSysWow64\dllcache\msd3d9.dll"
650	Delete /REBOOTOK "$g_strSysWow64\dllcache\d3d9.dll"
651	Rename /REBOOTOK "$g_strSysWow64\dllcache\msd3d9.dll" "$g_strSysWow64\dllcache\d3d9.dll"
652	${EndIf}
653	; Restore original DX DLLs
654	${If} ${FileExists} "$g_strSysWow64\msd3d8.dll"
655	Delete /REBOOTOK "$g_strSysWow64\d3d8.dll"
656	Rename /REBOOTOK "$g_strSysWow64\msd3d8.dll" "$g_strSysWow64\d3d8.dll"
657	${EndIf}
658	${If} ${FileExists} "$g_strSysWow64\msd3d9.dll"
659	Delete /REBOOTOK "$g_strSysWow64\d3d9.dll"
660	Rename /REBOOTOK "$g_strSysWow64\msd3d9.dll" "$g_strSysWow64\d3d9.dll"
661	${EndIf}
662	DeleteRegKey HKLM "SOFTWARE\Wow6432Node\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL"
663	!endif ; amd64
664
665	DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\OpenGLDrivers\VBoxOGL"
666
667	d3d_uninstall_end:
668
669	!endif ; VBOX_WITH_CROGL
670
671	; Remove mouse driver
672	DetailPrint "Removing mouse driver ..."
673	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" service delete VBoxMouse'
674	Pop $0 ; Ret value
675	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxMouse.sys"
676	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" registry delmultisz "SYSTEM\CurrentControlSet\Control\Class\{4D36E96F-E325-11CE-BFC1-08002BE10318}" "UpperFilters" "VBoxMouse"'
677	Pop $0 ; Ret value
678	; @todo Add error handling here!
679
680	; Delete the VBoxService service
681	Call ${un}StopVBoxService
682	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" service delete VBoxService'
683	Pop $0 ; Ret value
684	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxService"
685	Delete /REBOOTOK "$g_strSystemDir\VBoxService.exe"
686
687	; VBoxGINA
688	Delete /REBOOTOK "$g_strSystemDir\VBoxGINA.dll"
689	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
690	${If} $0 == "VBoxGINA.dll"
691	DetailPrint "Removing auto-logon support ..."
692	DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
693	${EndIf}
694
695	; Delete VBoxTray
696	Call ${un}StopVBoxTray
697	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxTray"
698
699	; Remove guest driver
700	DetailPrint "Removing guest driver ..."
701	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" driver uninstall "$INSTDIR\VBoxGuest.inf"'
702	Pop $0 ; Ret value
703	; @todo Add error handling here!
704
705	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" service delete VBoxGuest'
706	Pop $0 ; Ret value
707	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxGuest.sys"
708	Delete /REBOOTOK "$g_strSystemDir\VBCoInst.dll" ; Deprecated, does not get installed anymore
709	Delete /REBOOTOK "$g_strSystemDir\VBoxTray.exe"
710	Delete /REBOOTOK "$g_strSystemDir\VBoxHook.dll"
711	DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxTray" ; Remove VBoxTray autorun
712	Delete /REBOOTOK "$g_strSystemDir\VBoxControl.exe"
713
714	; Remove shared folders driver
715	DetailPrint "Removing shared folders driver ..."
716	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" netprovider remove VBoxSF'
717	Pop $0 ; Ret value
718	nsExec::ExecToLog '"$INSTDIR\VBoxDrvInst.exe" service delete VBoxSF'
719	Pop $0 ; Ret value
720	Delete /REBOOTOK "$g_strSystemDir\VBoxMRXNP.dll" ; The network provider DLL will be locked
721	!if $%BUILD_TARGET_ARCH% == "amd64"
722	; Only 64-bit installer: Also remove 32-bit DLLs on 64-bit target arch in Wow64 node
723	Delete /REBOOTOK "$g_strSysWow64\VBoxMRXNP.dll"
724	!endif ; amd64
725	Delete /REBOOTOK "$g_strSystemDir\drivers\VBoxSF.sys"
726
727	Pop $0
728
729	FunctionEnd
730	!macroend
731	!insertmacro W2K_Uninstall ""
732	!insertmacro W2K_Uninstall "un."
733

Note: See TracBrowser for help on using the repository browser.

source: vbox/trunk/src/VBox/Additions/WINNT/Installer/VBoxGuestAdditionsW2KXP.nsh@ 40257

Download in other formats: