VirtualBox

source: vbox/trunk/src/VBox/Additions/WINNT/Installer/VBoxGuestAdditionsNT4.nsh@ 93634

Last change on this file since 93634 was 93115, checked in by vboxsync, 3 years ago

scm --update-copyright-year
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id Revision
File size: 10.8 KB
Line 
1; $Id: VBoxGuestAdditionsNT4.nsh 93115 2022-01-01 11:31:46Z vboxsync $
2;; @file
3; VBoxGuestAdditionsNT4.nsh - Guest Additions installation for NT4.
4;
5
6;
7; Copyright (C) 2006-2022 Oracle Corporation
8;
9; This file is part of VirtualBox Open Source Edition (OSE), as
10; available from http://www.virtualbox.org. This file is free software;
11; you can redistribute it and/or modify it under the terms of the GNU
12; General Public License (GPL) as published by the Free Software
13; Foundation, in version 2 as it comes in the "COPYING" file of the
14; VirtualBox OSE distribution. VirtualBox OSE is distributed in the
15; hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
16;
17
18Function NT4_SetVideoResolution
19
20 ; Check for all required parameters
21 StrCmp $g_iScreenX "0" missingParms
22 StrCmp $g_iScreenY "0" missingParms
23 StrCmp $g_iScreenBpp "0" missingParms
24 Goto haveParms
25
26missingParms:
27
28 ${LogVerbose} "Missing display parameters for NT4, setting default (640x480, 8 BPP) ..."
29
30 StrCpy $g_iScreenX '640' ; Default value
31 StrCpy $g_iScreenY '480' ; Default value
32 StrCpy $g_iScreenBpp '8' ; Default value
33
34 ; Write setting into registry to show the desktop applet on next boot
35 WriteRegStr HKLM "SYSTEM\CurrentControlSet\Control\GraphicsDrivers\NewDisplay" "" ""
36
37haveParms:
38
39 ${LogVerbose} "Setting display parameters for NT4 ($g_iScreenXx$g_iScreenY, $g_iScreenBpp BPP) ..."
40
41 WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Hardware Profiles\Current\System\CurrentControlSet\Services\vboxvideo\Device0" "DefaultSettings.BitsPerPel" $g_iScreenBpp
42 WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Hardware Profiles\Current\System\CurrentControlSet\Services\vboxvideo\Device0" "DefaultSettings.Flags" 0x00000000
43 WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Hardware Profiles\Current\System\CurrentControlSet\Services\vboxvideo\Device0" "DefaultSettings.VRefresh" 0x00000001
44 WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Hardware Profiles\Current\System\CurrentControlSet\Services\vboxvideo\Device0" "DefaultSettings.XPanning" 0x00000000
45 WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Hardware Profiles\Current\System\CurrentControlSet\Services\vboxvideo\Device0" "DefaultSettings.XResolution" $g_iScreenX
46 WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Hardware Profiles\Current\System\CurrentControlSet\Services\vboxvideo\Device0" "DefaultSettings.YPanning" 0x00000000
47 WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Hardware Profiles\Current\System\CurrentControlSet\Services\vboxvideo\Device0" "DefaultSettings.YResolution" $g_iScreenY
48
49FunctionEnd
50
51Function NT4_SaveMouseDriverInfo
52
53 Push $0
54
55 ; !!! NOTE !!!
56 ; Due to some re-branding (see functions Uninstall_Sun, Uninstall_Innotek and
57 ; Uninstall_SunXVM) the installer *has* to transport the very first saved i8042prt
58 ; value to the current installer's "uninstall" directory in both mentioned
59 ; functions above, otherwise NT4 will be screwed because it then would store
60 ; "VBoxMouseNT.sys" as the original i8042prt driver which obviously isn't there
61 ; after uninstallation anymore
62 ; !!! NOTE !!!
63
64 ; Save current mouse driver info so we may restore it on uninstallation
65 ; But first check if we already installed the additions otherwise we will
66 ; overwrite it with the VBoxMouseNT.sys
67 ReadRegStr $0 HKLM "${PRODUCT_UNINST_KEY}" ${ORG_MOUSE_PATH}
68 StrCmp $0 "" 0 exists
69
70 ${LogVerbose} "Saving mouse driver info ..."
71 ReadRegStr $0 HKLM "SYSTEM\CurrentControlSet\Services\i8042prt" "ImagePath"
72 WriteRegStr HKLM "${PRODUCT_UNINST_KEY}" ${ORG_MOUSE_PATH} $0
73 Goto exit
74
75exists:
76
77 ${LogVerbose} "Mouse driver info already saved."
78 Goto exit
79
80exit:
81
82!ifdef _DEBUG
83 ${LogVerbose} "Mouse driver info: $0"
84!endif
85
86 Pop $0
87
88FunctionEnd
89
90Function NT4_Prepare
91
92 ${If} $g_bNoVBoxServiceExit == "false"
93 ; Stop / kill VBoxService
94 Call StopVBoxService
95 ${EndIf}
96
97 ${If} $g_bNoVBoxTrayExit == "false"
98 ; Stop / kill VBoxTray
99 Call StopVBoxTray
100 ${EndIf}
101
102 ; Delete VBoxService from registry
103 DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxService"
104
105 ; Delete old VBoxService.exe from install directory (replaced by VBoxTray.exe)
106 Delete /REBOOTOK "$INSTDIR\VBoxService.exe"
107
108FunctionEnd
109
110Function NT4_CopyFiles
111
112 ${LogVerbose} "Copying files for NT4 ..."
113
114 SetOutPath "$INSTDIR"
115 FILE "$%PATH_OUT%\bin\additions\VBoxGuestDrvInst.exe"
116 AccessControl::SetOnFile "$INSTDIR\VBoxGuestDrvInst.exe" "(BU)" "GenericRead"
117 FILE "$%PATH_OUT%\bin\additions\RegCleanup.exe"
118 AccessControl::SetOnFile "$INSTDIR\RegCleanup.exe" "(BU)" "GenericRead"
119!ifdef VBOX_WITH_ADDITIONS_SHIPPING_AUDIO_TEST
120 FILE "$%PATH_OUT%\bin\additions\VBoxAudioTest.exe"
121!endif
122
123 ; The files to install for NT 4, they go into the system directories
124 SetOutPath "$SYSDIR"
125 FILE "$%PATH_OUT%\bin\additions\VBoxDisp.dll"
126 AccessControl::SetOnFile "$SYSDIR\VBoxDisp.dll" "(BU)" "GenericRead"
127 FILE "$%PATH_OUT%\bin\additions\VBoxTray.exe"
128 AccessControl::SetOnFile "$SYSDIR\VBoxTray.exe" "(BU)" "GenericRead"
129 FILE "$%PATH_OUT%\bin\additions\VBoxHook.dll"
130 AccessControl::SetOnFile "$SYSDIR\VBoxHook.dll" "(BU)" "GenericRead"
131 FILE "$%PATH_OUT%\bin\additions\VBoxControl.exe"
132 AccessControl::SetOnFile "$SYSDIR\VBoxControl.exe" "(BU)" "GenericRead"
133
134 ; VBoxService
135 FILE "$%PATH_OUT%\bin\additions\VBoxService.exe"
136 AccessControl::SetOnFile "$SYSDIR\VBoxService.exe" "(BU)" "GenericRead"
137
138 ; The drivers into the "drivers" directory
139 SetOutPath "$SYSDIR\drivers"
140 FILE "$%PATH_OUT%\bin\additions\VBoxVideo.sys"
141 AccessControl::SetOnFile "$SYSDIR\drivers\VBoxVideo.sys" "(BU)" "GenericRead"
142 FILE "$%PATH_OUT%\bin\additions\VBoxMouseNT.sys"
143 AccessControl::SetOnFile "$SYSDIR\drivers\VBoxMouseNT.sys" "(BU)" "GenericRead"
144 FILE "$%PATH_OUT%\bin\additions\VBoxGuest.sys"
145 AccessControl::SetOnFile "$SYSDIR\drivers\VBoxGuest.sys" "(BU)" "GenericRead"
146 ;FILE "$%PATH_OUT%\bin\additions\VBoxSFNT.sys" ; Shared Folders not available on NT4!
147 ;AccessControl::SetOnFile "$SYSDIR\drivers\VBoxSFNT.sys" "(BU)" "GenericRead"
148
149FunctionEnd
150
151Function NT4_InstallFiles
152
153 ${LogVerbose} "Installing drivers for NT4 ..."
154
155 ; Install guest driver
156 ${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service create $\"VBoxGuest$\" $\"VBoxGuest Support Driver$\" 1 1 $\"$SYSDIR\drivers\VBoxGuest.sys$\" $\"Base$\"" "false"
157
158 ; Bugfix: Set "Start" to 1, otherwise, VBoxGuest won't start on boot-up!
159 ; Bugfix: Correct invalid "ImagePath" (\??\C:\WINNT\...)
160 WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Services\VBoxGuest" "Start" 1
161 WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxGuest" "ImagePath" "\SystemRoot\System32\DRIVERS\VBoxGuest.sys"
162
163 ; Run VBoxTray when Windows NT starts
164 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxTray" '"$SYSDIR\VBoxTray.exe"'
165
166 ; Video driver
167 ${CmdExecute} "$\"$INSTDIR\VBoxGuestDrvInst.exe$\" /i" "false"
168
169 ${LogVerbose} "Installing VirtualBox service ..."
170
171 ; Create the VBoxService service
172 ; No need to stop/remove the service here! Do this only on uninstallation!
173 ${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service create $\"VBoxService$\" $\"VirtualBox Guest Additions Service$\" 16 2 $\"%SystemRoot%\system32\VBoxService.exe$\" $\"Base$\"" "false"
174
175 ; Create the Shared Folders service ...
176 ;nsSCM::Install /NOUNLOAD "VBoxSF" "VirtualBox Shared Folders" 1 1 "$SYSDIR\drivers\VBoxSFNT.sys" "Network" "" "" ""
177 ;Pop $0 ; Ret value
178
179!ifdef _DEBUG
180 ;${LogVerbose} "SCM::Install VBoxSFNT.sys: $0"
181!endif
182
183 ;IntCmp $0 0 +1 error error ; Check ret value (0=OK, 1=Error)
184
185 ; ... and the link to the network provider
186 ;WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "DeviceName" "\Device\VBoxMiniRdr"
187 ;WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "Name" "VirtualBox Shared Folders"
188 ;WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\VBoxSF\NetworkProvider" "ProviderPath" "$SYSDIR\VBoxMRXNP.dll"
189
190 ; Add the shared folders network provider
191 ;${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" netprovider add VBoxSF" "false"
192
193 Goto done
194
195error:
196 Abort "ERROR: Could not install files for Windows NT4! Installation aborted."
197
198done:
199
200FunctionEnd
201
202Function NT4_Main
203
204 SetOutPath "$INSTDIR"
205
206 Call NT4_Prepare
207 Call NT4_CopyFiles
208
209 ; This removes the flag "new display driver installed on the next bootup
210 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\RunOnce" "VBoxGuestInst" '"$INSTDIR\RegCleanup.exe"'
211
212 Call NT4_SaveMouseDriverInfo
213 Call NT4_InstallFiles
214 Call NT4_SetVideoResolution
215
216 ; Write mouse driver name to registry overwriting the default name
217 WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\i8042prt" "ImagePath" "\SystemRoot\System32\DRIVERS\VBoxMouseNT.sys"
218
219FunctionEnd
220
221!macro NT4_UninstallInstDir un
222Function ${un}NT4_UninstallInstDir
223
224 ; Delete remaining files
225 Delete /REBOOTOK "$INSTDIR\VBoxGuestDrvInst.exe"
226 Delete /REBOOTOK "$INSTDIR\RegCleanup.exe"
227
228FunctionEnd
229!macroend
230!insertmacro NT4_UninstallInstDir ""
231!insertmacro NT4_UninstallInstDir "un."
232
233!macro NT4_Uninstall un
234Function ${un}NT4_Uninstall
235
236 Push $0
237
238 ; Remove the guest driver service
239 ${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxGuest" "true"
240 Delete /REBOOTOK "$SYSDIR\drivers\VBoxGuest.sys"
241
242 ; Delete the VBoxService service
243 Call ${un}StopVBoxService
244 ${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxService" "true"
245 DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxService"
246 Delete /REBOOTOK "$SYSDIR\VBoxService.exe"
247
248 ; Delete the VBoxTray app
249 Call ${un}StopVBoxTray
250 DeleteRegValue HKLM "Software\Microsoft\Windows\CurrentVersion\Run" "VBoxTray"
251 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\RunOnce" "VBoxTrayDel" "$SYSDIR\cmd.exe /c del /F /Q $SYSDIR\VBoxTray.exe"
252 Delete /REBOOTOK "$SYSDIR\VBoxTray.exe" ; If it can't be removed cause it's running, try next boot with "RunOnce" key above!
253 Delete /REBOOTOK "$SYSDIR\VBoxHook.dll"
254
255 ; Delete the VBoxControl utility
256 Delete /REBOOTOK "$SYSDIR\VBoxControl.exe"
257
258 ; Delete the VBoxVideo service
259 ${CmdExecute} "$\"$INSTDIR\VBoxDrvInst.exe$\" service delete VBoxVideo" "true"
260
261 ; Delete the VBox video driver files
262 Delete /REBOOTOK "$SYSDIR\drivers\VBoxVideo.sys"
263 Delete /REBOOTOK "$SYSDIR\VBoxDisp.dll"
264
265 ; Get original mouse driver info and restore it
266 ReadRegStr $0 ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" ${ORG_MOUSE_PATH}
267 ; If we still got our driver stored in $0 then this will *never* work, so
268 ; warn the user and set it to the default driver to not screw up NT4 here
269 ${If} $0 == "System32\DRIVERS\VBoxMouseNT.sys"
270 WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\i8042prt" "ImagePath" "\SystemRoot\System32\DRIVERS\i8042prt.sys"
271 ${LogVerbose} "Old mouse driver is set to VBoxMouseNT.sys, defaulting to i8042prt.sys ..."
272 ${Else}
273 WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\i8042prt" "ImagePath" $0
274 ${EndIf}
275 Delete /REBOOTOK "$SYSDIR\drivers\VBoxMouseNT.sys"
276
277 Pop $0
278
279FunctionEnd
280!macroend
281!insertmacro NT4_Uninstall ""
282!insertmacro NT4_Uninstall "un."
Note: See TracBrowser for help on using the repository browser.

© 2024 Oracle Support Privacy / Do Not Sell My Info Terms of Use Trademark Policy Automated Access Etiquette