VBoxGuestAdditions.nsi@ 76553

Last change on this file since 76553 was 76553, checked in by vboxsync, 6 years ago
scm --update-copyright-year
Property svn:eol-style set to `native` Property svn:keywords set to `Author Date Id Revision`
File size: 42.4 KB

Line
1	; $Id: VBoxGuestAdditions.nsi 76553 2019-01-01 01:45:53Z vboxsync $
2	; @file
3	; VBoxGuestAdditions.nsi - Main file for Windows Guest Additions installation.
4	;
5
6	;
7	; Copyright (C) 2012-2019 Oracle Corporation
8	;
9	; This file is part of VirtualBox Open Source Edition (OSE), as
10	; available from http://www.virtualbox.org. This file is free software;
11	; you can redistribute it and/or modify it under the terms of the GNU
12	; General Public License (GPL) as published by the Free Software
13	; Foundation, in version 2 as it comes in the "COPYING" file of the
14	; VirtualBox OSE distribution. VirtualBox OSE is distributed in the
15	; hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
16	;
17
18	!if $%BUILD_TYPE% == "debug"
19	!define _DEBUG ; Turn this on to get extra output
20	!endif
21
22	!ifdef _DEBUG
23	; Scratch directory for plugin tests
24	!addincludedir .\PluginTest
25	!addplugindir .\PluginTest
26	!endif
27
28	; Defines for special functions
29	!define WHQL_FAKE ; Enables faking of non WHQL signed / approved drivers
30	; Needs the VBoxWHQLFake.exe in the additions output directory!
31	!define WFP_FILE_EXCEPTION ; Enables setting a temporary file exception for WFP proctected files
32
33	!define VENDOR_ROOT_KEY "SOFTWARE\$%VBOX_VENDOR_SHORT%"
34
35	; Product defines
36	!define PRODUCT_NAME "$%VBOX_PRODUCT% Guest Additions"
37	!define PRODUCT_DESC "$%VBOX_PRODUCT% Guest Additions"
38	!define PRODUCT_VERSION "$%VBOX_VERSION_MAJOR%.$%VBOX_VERSION_MINOR%.$%VBOX_VERSION_BUILD%.0"
39	!define PRODUCT_PUBLISHER "$%VBOX_VENDOR%"
40	!define PRODUCT_COPYRIGHT "(C) $%VBOX_C_YEAR% $%VBOX_VENDOR%"
41	!define PRODUCT_OUTPUT "VBoxWindowsAdditions-$%BUILD_TARGET_ARCH%.exe"
42	!define PRODUCT_WEB_SITE "http://www.virtualbox.org"
43	!define PRODUCT_INSTALL_KEY "${VENDOR_ROOT_KEY}\VirtualBox Guest Additions"
44	!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
45	!define PRODUCT_UNINST_ROOT_KEY "HKLM"
46
47	!define LICENSE_FILE_RTF "license.rtf"
48
49	; Needed for InstallLib macro: Install libraries in every case
50	!define LIBRARY_IGNORE_VERSION
51
52	VIProductVersion "${PRODUCT_VERSION}"
53	VIAddVersionKey "FileVersion" "$%VBOX_VERSION_STRING%"
54	VIAddVersionKey "ProductName" "${PRODUCT_NAME}"
55	VIAddVersionKey "ProductVersion" "${PRODUCT_VERSION}"
56	VIAddVersionKey "CompanyName" "${PRODUCT_PUBLISHER}"
57	VIAddVersionKey "FileDescription" "${PRODUCT_DESC}"
58	VIAddVersionKey "LegalCopyright" "${PRODUCT_COPYRIGHT}"
59	VIAddVersionKey "InternalName" "${PRODUCT_OUTPUT}"
60
61	; This registry key will hold the mouse driver path before install (NT4 only)
62	!define ORG_MOUSE_PATH "MousePath"
63
64	; If we have our guest install helper DLL, add the
65	; plugin path so that NSIS can find it when compiling the installer
66	; Note: NSIS plugins always have to be compiled in 32-bit!
67	!if $%VBOX_WITH_GUEST_INSTALL_HELPER% == "1"
68	!addplugindir "$%PATH_TARGET_X86%\VBoxGuestInstallHelper"
69	!endif
70
71	!include "LogicLib.nsh"
72	!include "FileFunc.nsh"
73	!insertmacro GetParameters
74	!insertmacro GetOptions
75	!include "WordFunc.nsh"
76	!insertmacro WordFind
77	!insertmacro StrFilter
78
79	!include "nsProcess.nsh"
80	!include "Library.nsh"
81	!include "Sections.nsh"
82	!include "strstr.nsh" ; Function "strstr"
83	!include "servicepack.nsh" ; Function "GetServicePack"
84	!include "winver.nsh" ; Function for determining Windows version
85	!define REPLACEDLL_NOREGISTER ; Replace in use DLL function
86	!include "ReplaceDLL.nsh"
87	!include "dumplog.nsh" ; Dump log to file function
88
89	!if $%BUILD_TARGET_ARCH% == "amd64"
90	!include "x64.nsh"
91	!endif
92
93	; Set Modern UI (MUI) as default
94	!define USE_MUI
95
96	!ifdef USE_MUI
97	; Use modern UI, version 2
98	!include "MUI2.nsh"
99
100	; MUI Settings
101	!define MUI_WELCOMEFINISHPAGE_BITMAP "$%VBOX_BRAND_WIN_ADD_INST_DLGBMP%"
102	!define MUI_ABORTWARNING
103	!define MUI_WELCOMEPAGE_TITLE_3LINES "Welcome to the ${PRODUCT_NAME} Additions Setup"
104
105	; API defines
106	!define SM_CLEANBOOT 67
107
108	; Icons
109	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit
110	!define MUI_ICON "$%VBOX_NSIS_ICON_FILE%"
111	!define MUI_UNICON "$%VBOX_NSIS_ICON_FILE%"
112	!else ; 64-bit
113	!define MUI_ICON "$%VBOX_WINDOWS_ADDITIONS_ICON_FILE%"
114	!define MUI_UNICON "$%VBOX_WINDOWS_ADDITIONS_ICON_FILE%"
115	!endif
116
117	; Welcome page
118	!insertmacro MUI_PAGE_WELCOME
119	!ifdef VBOX_WITH_LICENSE_DISPLAY
120	; License page
121	!insertmacro MUI_PAGE_LICENSE "$(VBOX_LICENSE)"
122	!define MUI_LICENSEPAGE_RADIOBUTTONS
123	!endif
124	; Directory page
125	!insertmacro MUI_PAGE_DIRECTORY
126	; Components Page
127	!insertmacro MUI_PAGE_COMPONENTS
128	; Instfiles page
129	!insertmacro MUI_PAGE_INSTFILES
130
131	!ifndef _DEBUG
132	!define MUI_FINISHPAGE_TITLE_3LINES ; Have a bit more vertical space for text
133	!insertmacro MUI_PAGE_FINISH ; Only show in release mode - useful information for debugging!
134	!endif
135
136	; Uninstaller pages
137	!insertmacro MUI_UNPAGE_INSTFILES
138
139	; Define languages we will use
140	!insertmacro MUI_LANGUAGE "English"
141	!insertmacro MUI_LANGUAGE "French"
142	!insertmacro MUI_LANGUAGE "German"
143
144	; Set branding text which appears on the horizontal line at the bottom
145	!ifdef _DEBUG
146	BrandingText "VirtualBox Windows Additions $%VBOX_VERSION_STRING% (r$%VBOX_SVN_REV%) - Debug Build"
147	!else
148	BrandingText "VirtualBox Windows Additions $%VBOX_VERSION_STRING% r$%VBOX_SVN_REV%"
149	!endif
150
151	!ifdef VBOX_WITH_LICENSE_DISPLAY
152	; Set license language
153	LicenseLangString VBOX_LICENSE ${LANG_ENGLISH} "$%VBOX_BRAND_LICENSE_RTF%"
154
155	; If license files not available (OSE / PUEL) build, then use the English one as default
156	!ifdef VBOX_BRAND_fr_FR_LICENSE_RTF
157	LicenseLangString VBOX_LICENSE ${LANG_FRENCH} "$%VBOX_BRAND_fr_FR_LICENSE_RTF%"
158	!else
159	LicenseLangString VBOX_LICENSE ${LANG_FRENCH} "$%VBOX_BRAND_LICENSE_RTF%"
160	!endif
161	!ifdef VBOX_BRAND_de_DE_LICENSE_RTF
162	LicenseLangString VBOX_LICENSE ${LANG_GERMAN} "$%VBOX_BRAND_de_DE_LICENSE_RTF%"
163	!else
164	LicenseLangString VBOX_LICENSE ${LANG_GERMAN} "$%VBOX_BRAND_LICENSE_RTF%"
165	!endif
166	!endif
167
168	!insertmacro MUI_RESERVEFILE_LANGDLL
169	!else ; !USE_MUI
170	XPStyle on
171	!ifdef VBOX_WITH_LICENSE_DISPLAY
172	Page license
173	!endif
174	Page components
175	Page directory
176	Page instfiles
177	!endif
178
179	; Language files
180	!include "Languages\English.nsh"
181	!include "Languages\French.nsh"
182	!include "Languages\German.nsh"
183
184	; Variables and output files
185	Name "${PRODUCT_NAME} $%VBOX_VERSION_STRING%"
186	!ifdef UNINSTALLER_ONLY
187	!echo "Uninstaller only!"
188	OutFile "$%PATH_TARGET%\VBoxWindowsAdditions-$%BUILD_TARGET_ARCH%-uninst.exe"
189	!else
190	OutFile "VBoxWindowsAdditions-$%BUILD_TARGET_ARCH%.exe"
191	!endif ; UNINSTALLER_ONLY
192
193	; Define default installation directory
194	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit
195	InstallDir "$PROGRAMFILES32\$%VBOX_VENDOR_SHORT%\VirtualBox Guest Additions"
196	!else ; 64-bit
197	InstallDir "$PROGRAMFILES64\$%VBOX_VENDOR_SHORT%\VirtualBox Guest Additions"
198	!endif
199
200	InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" ""
201	ShowInstDetails show
202	ShowUnInstDetails show
203	RequestExecutionLevel highest
204
205	; Internal parameters
206	Var g_iSystemMode ; Current system mode (0 = Normal boot, 1 = Fail-safe boot, 2 = Fail-safe with network boot)
207	Var g_strSystemDir ; Windows system directory
208	Var g_strSysWow64 ; The SysWow64 directory on 64-bit systems
209	Var g_strCurUser ; Current user using the system
210	Var g_strAddVerMaj ; Installed Guest Additions: Major version
211	Var g_strAddVerMin ; Installed Guest Additions: Minor version
212	Var g_strAddVerBuild ; Installed Guest Additions: Build number
213	Var g_strAddVerRev ; Installed Guest Additions: SVN revision
214	Var g_strWinVersion ; Current Windows version we're running on
215	Var g_bLogEnable ; Do logging when installing? "true" or "false"
216	Var g_bWithWDDM ; Install the WDDM graphics driver instead of the XPDM one
217	Var g_bCapDllCache ; Capability: Does the (Windows) guest have have a DLL cache which needs to be taken care of?
218	Var g_bCapWDDM ; Capability: Is the guest able to handle/use our WDDM driver?
219
220	; Command line parameters - these can be set/modified
221	; on the command line
222	Var g_bFakeWHQL ; Cmd line: Fake Windows to install non WHQL certificated drivers (only for W2K and XP currently!!) ("/unsig_drv")
223	Var g_bForceInstall ; Cmd line: Force installation on unknown Windows OS version
224	Var g_bUninstall ; Cmd line: Just uninstall any previous Guest Additions and exit
225	Var g_bRebootOnExit ; Cmd line: Auto-Reboot on successful installation. Good for unattended installations ("/reboot")
226	Var g_iScreenBpp ; Cmd line: Screen depth ("/depth=X")
227	Var g_iScreenX ; Cmd line: Screen resolution X ("/resx=X")
228	Var g_iScreenY ; Cmd line: Screen resolution Y ("/resy=Y")
229	Var g_iSfOrder ; Cmd line: Order of Shared Folders network provider (0=first, 1=second, ...)
230	Var g_bIgnoreUnknownOpts ; Cmd line: Ignore unknown options (don't display the help)
231	Var g_bNoVBoxServiceExit ; Cmd line: Do not quit VBoxService before updating - install on next reboot
232	Var g_bNoVBoxTrayExit ; Cmd line: Do not quit VBoxTray before updating - install on next reboot
233	Var g_bNoVideoDrv ; Cmd line: Do not install the VBoxVideo driver
234	Var g_bNoGuestDrv ; Cmd line: Do not install the VBoxGuest driver
235	Var g_bNoMouseDrv ; Cmd line: Do not install the VBoxMouse driver
236	Var g_bNoStartMenuEntries ; Cmd line: Do not create start menu entries
237	Var g_bWithAutoLogon ; Cmd line: Install VBoxGINA / VBoxCredProv for auto logon support
238	Var g_bWithD3D ; Cmd line: Install Direct3D support
239	Var g_bOnlyExtract ; Cmd line: Only extract all files, do not install them. Only valid with param "/D" (target directory)
240	Var g_bPostInstallStatus ; Cmd line: Post the overall installation status to some external program (VBoxTray)
241
242	; Platform parts of this installer
243	!include "VBoxGuestAdditionsLog.nsh"
244	!include "VBoxGuestAdditionsExternal.nsh"
245	!include "VBoxGuestAdditionsCommon.nsh"
246	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit only
247	!include "VBoxGuestAdditionsNT4.nsh"
248	!endif
249	!include "VBoxGuestAdditionsW2KXP.nsh"
250	!include "VBoxGuestAdditionsVista.nsh"
251	!include "VBoxGuestAdditionsUninstall.nsh" ; Product uninstallation
252	!include "VBoxGuestAdditionsUninstallOld.nsh" ; Uninstallation of deprecated versions which must be removed first
253
254	Function HandleCommandLine
255
256	Push $0 ; Command line (without process name)
257	Push $1 ; Number of parameters
258	Push $2 ; Current parameter index
259	Push $3 ; Current parameter pair (name=value)
260	Push $4 ; Current parameter name
261	Push $5 ; Current parameter value (if present)
262
263	StrCpy $1 "0" ; Init param counter
264	StrCpy $2 "1" ; Init current param counter
265
266	${GetParameters} $0 ; Extract command line
267	${If} $0 == "" ; If no parameters at all exit
268	Goto exit
269	${EndIf}
270
271	; Enable for debugging
272	;MessageBox MB_OK "CmdLine: $0"
273
274	${WordFind} $0 " " "#" $1 ; Get number of parameters in cmd line
275	${If} $0 == $1 ; If result matches the input then
276	StrCpy $1 "1" ; no delimiter was found. Correct to 1 word total
277	${EndIf}
278
279	${While} $2 <= $1 ; Loop through all params
280
281	${WordFind} $0 " " "+$2" $3 ; Get current name=value pair
282	${WordFind} $3 "=" "+1" $4 ; Get current param name
283	${WordFind} $3 "=" "+2" $5 ; Get current param value
284
285	${StrFilter} $4 "-" "" "" $4 ; Transfer param name to lowercase
286
287	; Enable for debugging
288	;MessageBox MB_OK "#$2 of #$1, param='$3', name=$4, val=$5"
289
290	${Switch} $4
291
292	${Case} '/d' ; NSIS: /D=<instdir> switch, skip
293	${Break}
294
295	${Case} '/depth'
296	${Case} 'depth'
297	StrCpy $g_iScreenBpp $5
298	${Break}
299
300	${Case} '/extract'
301	StrCpy $g_bOnlyExtract "true"
302	${Break}
303
304	${Case} '/force'
305	StrCpy $g_bForceInstall "true"
306	${Break}
307
308	${Case} '/help'
309	${Case} '/H'
310	${Case} '/h'
311	${Case} '/?'
312	Goto usage
313	${Break}
314
315	${Case} '/ignore_unknownopts' ; Not officially documented
316	StrCpy $g_bIgnoreUnknownOpts "true"
317	${Break}
318
319	${Case} '/l'
320	${Case} '/log'
321	${Case} '/logging'
322	StrCpy $g_bLogEnable "true"
323	${Break}
324
325	${Case} '/ncrc' ; NSIS: /NCRC switch, skip
326	${Break}
327
328	${Case} '/no_vboxservice_exit' ; Not officially documented
329	StrCpy $g_bNoVBoxServiceExit "true"
330	${Break}
331
332	${Case} '/no_vboxtray_exit' ; Not officially documented
333	StrCpy $g_bNoVBoxTrayExit "true"
334	${Break}
335
336	${Case} '/no_videodrv' ; Not officially documented
337	StrCpy $g_bNoVideoDrv "true"
338	${Break}
339
340	${Case} '/no_guestdrv' ; Not officially documented
341	StrCpy $g_bNoGuestDrv "true"
342	${Break}
343
344	${Case} '/no_mousedrv' ; Not officially documented
345	StrCpy $g_bNoMouseDrv "true"
346	${Break}
347
348	${Case} '/no_startmenuentries' ; Not officially documented
349	StrCpy $g_bNoStartMenuEntries "true"
350	${Break}
351
352	!if $%VBOX_WITH_GUEST_INSTALL_HELPER% == "1"
353	; This switch tells our installer that it
354	; - should not quit VBoxTray during the update, because ...
355	; - ... it should show the overall installation status
356	; using VBoxTray's balloon message feature (since VBox 4.0)
357	${Case} '/post_installstatus' ; Not officially documented
358	StrCpy $g_bNoVBoxTrayExit "true"
359	StrCpy $g_bPostInstallStatus "true"
360	${Break}
361	!endif
362
363	${Case} '/reboot'
364	StrCpy $g_bRebootOnExit "true"
365	${Break}
366
367	${Case} '/s' ; NSIS: /S switch, skip
368	${Break}
369
370	${Case} '/sforder'
371	${Case} 'sforder'
372	StrCpy $g_iSfOrder $5
373	${Break}
374
375	!ifdef WHQL_FAKE
376	${Case} '/unsig_drv'
377	StrCpy $g_bFakeWHQL "true"
378	${Break}
379	!endif
380
381	${Case} '/uninstall'
382	StrCpy $g_bUninstall "true"
383	${Break}
384
385	${Case} '/with_autologon'
386	StrCpy $g_bWithAutoLogon "true"
387	${Break}
388
389	!if $%VBOX_WITH_CROGL% == "1"
390	${Case} '/with_d3d'
391	${Case} '/with_direct3d'
392	StrCpy $g_bWithD3D "true"
393	${Break}
394	!endif
395
396	!if $%VBOX_WITH_WDDM% == "1"
397	${Case} '/with_wddm'
398	StrCpy $g_bWithWDDM "true"
399	${Break}
400	!endif
401
402	${Case} '/xres'
403	${Case} 'xres'
404	StrCpy $g_iScreenX $5
405	${Break}
406
407	${Case} '/yres'
408	${Case} 'yres'
409	StrCpy $g_iScreenY $5
410	${Break}
411
412	${Default} ; Unknown parameter, print usage message
413	; Prevent popping up usage message on (yet) unknown parameters
414	; in silent mode, just skip
415	IfSilent +1 +2
416	${Break}
417	goto usage
418	${Break}
419
420	${EndSwitch}
421
422	next_param:
423
424	IntOp $2 $2 + 1
425
426	${EndWhile}
427	Goto exit
428
429	usage:
430
431	; If we were told to ignore unknown (invalid) options, just return to
432	; the parsing loop ...
433	${If} $g_bIgnoreUnknownOpts == "true"
434	Goto next_param
435	${EndIf}
436	MessageBox MB_OK "${PRODUCT_NAME} Installer$\r$\n$\r$\n \
437	Usage: VBoxWindowsAdditions-$%BUILD_TARGET_ARCH% [OPTIONS] [/l] [/S] [/D=<PATH>]$\r$\n$\r$\n \
438	Options:$\r$\n \
439	/depth=BPP$\tSets the guest's display color depth (bits per pixel)$\r$\n \
440	/extract$\t$\tOnly extract installation files$\r$\n \
441	/force$\t$\tForce installation on unknown/undetected Windows versions$\r$\n \
442	/uninstall$\t$\tJust uninstalls the Guest Additions and exits$\r$\n \
443	/with_autologon$\tInstalls auto-logon support$\r$\n \
444	/with_d3d$\tInstalls D3D support$\r$\n \
445	/with_wddm$\tInstalls the WDDM instead of the XPDM graphics driver$\r$\n \
446	/xres=X$\t$\tSets the guest's display resolution (width in pixels)$\r$\n \
447	/yres=Y$\t$\tSets the guest's display resolution (height in pixels)$\r$\n \
448	$\r$\n \
449	Installer parameters:$\r$\n \
450	/l$\t$\tEnables logging$\r$\n \
451	/S$\t$\tSilent install$\r$\n \
452	/D=<PATH>$\tSets the default install path$\r$\n \
453	$\r$\n \
454	Note: Order of options and installer parameters is fixed, options first." /SD IDOK
455
456	; No stack restore needed, we're about to quit
457	Quit
458
459	done:
460
461	!ifdef _DEBUG
462	${LogVerbose} "Property: XRes: $g_iScreenX"
463	${LogVerbose} "Property: YRes: $g_iScreenY"
464	${LogVerbose} "Property: BPP: $g_iScreenBpp"
465	${LogVerbose} "Property: Logging enabled: $g_bLogEnable"
466	!endif
467
468	exit:
469
470	Pop $5
471	Pop $4
472	Pop $3
473	Pop $2
474	Pop $1
475	Pop $0
476
477	FunctionEnd
478
479	Function CheckForOldGuestAdditions
480
481	Push $0
482	Push $1
483	Push $2
484
485	begin:
486
487	${LogVerbose} "Checking for old Guest Additions ..."
488
489	sun_check:
490
491	; Check for old "Sun VirtualBox Guest Additions"
492	; - before rebranding to Oracle
493	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Sun VirtualBox Guest Additions" "UninstallString"
494	StrCmp $0 "" sun_xvm_check ; If string is empty, Sun additions are probably not installed (anymore)
495
496	MessageBox MB_YESNO $(VBOX_SUN_FOUND) /SD IDYES IDYES sun_uninstall
497	Pop $2
498	Pop $1
499	Pop $0
500	MessageBox MB_ICONSTOP $(VBOX_SUN_ABORTED) /SD IDOK
501	Quit
502
503	sun_uninstall:
504
505	Call Uninstall_Sun
506	Goto success
507
508	sun_xvm_check:
509
510	; Check for old "Sun xVM VirtualBox Guest Additions"
511	; - before getting rid of the "xVM" namespace
512	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Sun xVM VirtualBox Guest Additions" "UninstallString"
513	StrCmp $0 "" innotek_check ; If string is empty, Sun xVM additions are probably not installed (anymore)
514
515	MessageBox MB_YESNO $(VBOX_SUN_FOUND) /SD IDYES IDYES sun_xvm_uninstall
516	Pop $2
517	Pop $1
518	Pop $0
519	MessageBox MB_ICONSTOP $(VBOX_SUN_ABORTED) /SD IDOK
520	Quit
521
522	sun_xvm_uninstall:
523
524	Call Uninstall_SunXVM
525	Goto success
526
527	innotek_check:
528
529	; Check for old "innotek" Guest Additions" before rebranding to "Sun"
530	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\innotek VirtualBox Guest Additions" "UninstallString"
531	StrCmp $0 "" exit ; If string is empty, innotek Guest Additions are probably not installed (anymore)
532
533	MessageBox MB_YESNO $(VBOX_INNOTEK_FOUND) /SD IDYES IDYES innotek_uninstall
534	Pop $2
535	Pop $1
536	Pop $0
537	MessageBox MB_ICONSTOP $(VBOX_INNOTEK_ABORTED) /SD IDOK
538	Quit
539
540	innotek_uninstall:
541
542	Call Uninstall_Innotek
543	Goto success
544
545	success:
546
547	; Nothing to do here yet
548
549	exit:
550
551	Pop $2
552	Pop $1
553	Pop $0
554
555	FunctionEnd
556
557	Function CheckForInstalledComponents
558
559	Push $0
560	Push $1
561
562	${LogVerbose} "Checking for installed components ..."
563	StrCpy $1 ""
564
565	Call SetAppMode64
566
567	; VBoxGINA already installed? So we need to update the installed version as well,
568	; regardless whether the user used "/with_autologon" or not
569	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
570	${If} $0 == "VBoxGINA.dll"
571	StrCpy $1 "GINA"
572	${Else}
573	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\Credential Providers\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}" ""
574	${If} $0 == "VBoxCredProv"
575	StrCpy $1 "Credential Provider"
576	${EndIf}
577	${EndIf}
578
579	!ifdef _DEBUG
580	${LogVerbose} "Auto-logon module: $0"
581	!endif
582
583	${IfNot} $1 == ""
584	${LogVerbose} "Auto-logon support ($1) was installed previously"
585	StrCpy $g_bWithAutoLogon "true" ; Force update
586	${Else}
587	${LogVerbose} "Auto-logon support was not installed previously"
588	${EndIf}
589
590	Pop $1
591	Pop $0
592
593	FunctionEnd
594
595	; Main Files
596	Section $(VBOX_COMPONENT_MAIN) SEC01
597
598	SectionIn RO ; Section cannot be unselected (read-only)
599	${If} $g_bPostInstallStatus == "true"
600	${LogToVBoxTray} "0" "${PRODUCT_NAME} update started, please wait ..."
601	${EndIf}
602
603	IfSilent +1 +2
604	StrCpy $g_bLogEnable "true" ; Force logging in silent mode
605
606	${LogEnable} "$g_bLogEnable"
607	IfSilent +1 +2 ; NSIS will expand ${LogVerbose} before doing relative jumps!
608	LogText "Installer runs in silent mode"
609
610	SetOutPath "$INSTDIR"
611	SetOverwrite on
612
613	Call SetAppMode64
614
615	StrCpy $g_strSystemDir "$SYSDIR"
616
617	${LogVerbose} "Version: $%VBOX_VERSION_STRING% (Rev $%VBOX_SVN_REV%)"
618	${If} $g_strAddVerMaj != ""
619	${LogVerbose} "Previous version: $g_strAddVerMaj.$g_strAddVerMin.$g_strAddVerBuild (Rev $g_strAddVerRev)"
620	${Else}
621	${LogVerbose} "No previous version of ${PRODUCT_NAME} detected"
622	${EndIf}
623	!if $%BUILD_TARGET_ARCH% == "amd64"
624	${LogVerbose} "Detected OS: Windows $g_strWinVersion (64-bit)"
625	!else
626	${LogVerbose} "Detected OS: Windows $g_strWinVersion (32-bit)"
627	!endif
628	${LogVerbose} "System Directory: $g_strSystemDir"
629
630	!ifdef _DEBUG
631	${LogVerbose} "Installer runs in debug mode"
632	!endif
633
634	;
635	; Here starts the main dispatcher (based on guest OS)
636	;
637
638	; Which OS are we using?
639	; @todo Use logic lib here
640	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit
641	StrCmp $g_strWinVersion "NT4" nt4 ; Windows NT 4.0
642	!endif
643	StrCmp $g_strWinVersion "2000" w2k ; Windows 2000
644	StrCmp $g_strWinVersion "XP" w2k ; Windows XP
645	StrCmp $g_strWinVersion "2003" w2k ; Windows 2003 Server
646	StrCmp $g_strWinVersion "Vista" vista ; Windows Vista
647	StrCmp $g_strWinVersion "7" vista ; Windows 7
648	StrCmp $g_strWinVersion "8" vista ; Windows 8
649	StrCmp $g_strWinVersion "8_1" vista ; Windows 8.1 / Windows 2012 Server R2
650	StrCmp $g_strWinVersion "10" vista ; Windows 10
651
652	${If} $g_bForceInstall == "true"
653	Goto vista ; Assume newer OS than we know of ...
654	${EndIf}
655
656	Goto notsupported
657
658	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit
659	nt4: ; Windows NT4
660
661	Call GetServicePack
662	Pop $R0 ; Major version
663	Pop $R1 ; Minor version
664
665	; At least Service Pack 6 installed?
666	${If} $R0 <> "6"
667	MessageBox MB_YESNO $(VBOX_NT4_NO_SP6) /SD IDYES IDYES +2
668	Quit
669	${EndIf}
670
671	; Copy some common files ...
672	Call Common_CopyFiles
673
674	Call NT4_Main
675	goto success
676	!endif
677
678	w2k: ; Windows 2000 and XP ...
679
680	; Copy some common files ...
681	Call Common_CopyFiles
682
683	Call W2K_Main
684	goto success
685
686	vista: ; Windows Vista / Windows 7 / Windows 8(.1)
687
688	; Check requirments; this function can abort the installation if necessary!
689	Call Vista_CheckForRequirements
690
691	; Copy some common files ...
692	Call Common_CopyFiles
693
694	Call W2K_Main ; First install stuff from Windows 2000 / XP
695	Call Vista_Main ; ... and some specific stuff for Vista / Windows 7
696	goto success
697
698	notsupported:
699
700	MessageBox MB_ICONSTOP $(VBOX_PLATFORM_UNSUPPORTED) /SD IDOK
701	goto exit
702
703	success:
704
705	; Write a registry key with version and installation path for later lookup
706	WriteRegStr HKLM "${PRODUCT_INSTALL_KEY}" "Version" "$%VBOX_VERSION_STRING_RAW%"
707	WriteRegStr HKLM "${PRODUCT_INSTALL_KEY}" "VersionExt" "$%VBOX_VERSION_STRING%"
708	WriteRegStr HKLM "${PRODUCT_INSTALL_KEY}" "Revision" "$%VBOX_SVN_REV%"
709	WriteRegStr HKLM "${PRODUCT_INSTALL_KEY}" "InstallDir" "$INSTDIR"
710
711	; Set the reboot flag to tell the finish page that is should
712	; default to the "reboot now" entry
713	SetRebootFlag true
714
715	exit:
716
717	SectionEnd
718
719	; Auto-logon support (section is hidden at the moment -- only can be enabled via command line switch)
720	Section /o -$(VBOX_COMPONENT_AUTOLOGON) SEC02
721
722	Call SetAppMode64
723
724	Call GetWindowsVersion
725	Pop $R0 ; Windows Version
726
727	${LogVerbose} "Installing auto-logon support ..."
728
729	; Another GINA already is installed? Check if this is ours, otherwise let the user decide (unless it's a silent setup)
730	; whether to replace it with the VirtualBox one or not
731	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
732	${If} $0 != ""
733	${If} $0 != "VBoxGINA.dll"
734	${LogVerbose} "Found another already installed GINA module: $0"
735	MessageBox MB_ICONQUESTION\|MB_YESNO\|MB_DEFBUTTON1 $(VBOX_COMPONENT_AUTOLOGON_WARN_3RDPARTY) /SD IDYES IDYES install
736	${LogVerbose} "Skipping GINA installation, keeping: $0"
737	goto skip
738	${EndIf}
739	${EndIf}
740
741	install:
742
743	; Do we need VBoxCredProv or VBoxGINA?
744	${If} $R0 == 'Vista' ; Windows Vista.
745	${OrIf} $R0 == '7' ; Windows 7.
746	${OrIf} $R0 == '8' ; Windows 8.
747	${OrIf} $R0 == '8_1' ; Windows 8.1 / Windows Server 2012 R2.
748	${OrIf} $R0 == '10' ; Windows 10.
749	; Use VBoxCredProv on Vista and up.
750	${LogVerbose} "Installing VirtualBox credential provider ..."
751	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxCredProv.dll" "$g_strSystemDir\VBoxCredProv.dll" "$INSTDIR"
752	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\Credential Providers\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}" "" "VBoxCredProv" ; adding to (default) key
753	WriteRegStr HKCR "CLSID\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}" "" "VBoxCredProv" ; adding to (Default) key
754	WriteRegStr HKCR "CLSID\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}\InprocServer32" "" "VBoxCredProv.dll" ; adding to (Default) key
755	WriteRegStr HKCR "CLSID\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}\InprocServer32" "ThreadingModel" "Apartment"
756	${Else} ; Use VBoxGINA on older Windows OSes (< Vista)
757	${LogVerbose} "Installing VirtualBox GINA ..."
758	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxGINA.dll" "$g_strSystemDir\VBoxGINA.dll" "$INSTDIR"
759	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL" "VBoxGINA.dll"
760	; Add Windows notification package callbacks for VBoxGINA
761	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon\Notify\VBoxGINA" "DLLName" "VBoxGINA.dll"
762	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon\Notify\VBoxGINA" "Impersonate" 0
763	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon\Notify\VBoxGINA" "StopScreenSaver" "WnpScreenSaverStop"
764	${EndIf}
765
766	skip:
767
768	; Nothing to do here right now
769
770	exit:
771
772	SectionEnd
773
774	; Direct3D support
775	Section /o $(VBOX_COMPONENT_D3D) SEC03
776
777	!if $%VBOX_WITH_WDDM% == "1"
778	${If} $g_bWithWDDM == "true"
779	${LogVerbose} "Installing WDDM Direct3D support ..."
780
781	; Do we need to restore the original d3d8.dll/d3d9.dll files because the guest
782	; installation was upgraded from XPDM to WDDM driver? In a XPDM installation
783	; those DLLs were replaced by our own stub files.
784	Call RestoreFilesDirect3D
785	Return
786	${EndIf}
787	!endif
788
789	Call SetAppMode64
790	SetOverwrite on
791
792	${If} $g_strSystemDir == ''
793	StrCpy $g_strSystemDir "$SYSDIR"
794	${EndIf}
795
796	SetOutPath $g_strSystemDir
797	${LogVerbose} "Installing XPDM Direct3D support ..."
798	FILE "$%PATH_OUT%\bin\additions\VBoxD3D8.dll"
799	FILE "$%PATH_OUT%\bin\additions\VBoxD3D9.dll"
800	FILE "$%PATH_OUT%\bin\additions\wined3d.dll"
801
802	;
803	; Update DLL cache
804	;
805	${If} $g_bCapDllCache == "true"
806	${If} ${FileExists} "$g_strSystemDir\dllcache"
807	SetOutPath "$g_strSystemDir\dllcache"
808	${CopyFileEx} "" "$g_strSystemDir\dllcache\d3d8.dll" "$g_strSystemDir\dllcache\msd3d8.dll" "Microsoft Corporation" "$%BUILD_TARGET_ARCH%"
809	${CopyFileEx} "" "$g_strSystemDir\dllcache\d3d9.dll" "$g_strSystemDir\dllcache\msd3d9.dll" "Microsoft Corporation" "$%BUILD_TARGET_ARCH%"
810
811	; Exchange DLLs
812	${PrepareWRPFileEx} "" "$g_strSystemDir\dllcache\d3d8.dll"
813	${InstallFileEx} "" "$%PATH_OUT%\bin\additions\d3d8.dll" "$g_strSystemDir\dllcache\d3d8.dll" "$TEMP"
814	${PrepareWRPFileEx} "" "$g_strSystemDir\dllcache\d3d9.dll"
815	${InstallFileEx} "" "$%PATH_OUT%\bin\additions\d3d9.dll" "$g_strSystemDir\dllcache\d3d9.dll" "$TEMP"
816	${Else}
817	${LogVerbose} "DLL cache does not exist, skipping"
818	${EndIf}
819	${EndIf}
820
821	;
822	; Save original DLLs (only if msd3d*.dll does not exist) ...
823	;
824	SetOutPath $g_strSystemDir
825	${CopyFileEx} "" "$g_strSystemDir\d3d8.dll" "$g_strSystemDir\msd3d8.dll" "Microsoft Corporation" "$%BUILD_TARGET_ARCH%"
826	${CopyFileEx} "" "$g_strSystemDir\d3d9.dll" "$g_strSystemDir\msd3d9.dll" "Microsoft Corporation" "$%BUILD_TARGET_ARCH%"
827
828	; Exchange DLLs
829	${PrepareWRPFileEx} "" "$g_strSystemDir\d3d8.dll"
830	${InstallFileEx} "" "$%PATH_OUT%\bin\additions\d3d8.dll" "$g_strSystemDir\d3d8.dll" "$TEMP"
831	${PrepareWRPFileEx} "" "$g_strSystemDir\d3d9.dll"
832	${InstallFileEx} "" "$%PATH_OUT%\bin\additions\d3d9.dll" "$g_strSystemDir\d3d9.dll" "$TEMP"
833
834	!if $%BUILD_TARGET_ARCH% == "amd64"
835	; Only 64-bit installer:
836	; Also copy 32-bit DLLs on 64-bit Windows in SysWOW64 node
837	SetOutPath $g_strSysWow64
838	${LogVerbose} "Installing Direct3D support for 32-bit applications (SysWOW64: $g_strSysWow64) ..."
839	FILE "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxD3D8.dll"
840	FILE "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxD3D9.dll"
841	FILE "$%VBOX_PATH_ADDITIONS_WIN_X86%\wined3d.dll"
842
843	;
844	; Update DLL cache
845	;
846	${If} $g_bCapDllCache == "true"
847	${If} ${FileExists} "$g_strSysWow64\dllcache"
848	SetOutPath "$g_strSysWow64\dllcache"
849	${CopyFileEx} "" "$g_strSysWow64\dllcache\d3d8.dll" "$g_strSysWow64\dllcache\msd3d8.dll" "Microsoft Corporation" "x86"
850	${CopyFileEx} "" "$g_strSysWow64\dllcache\d3d9.dll" "$g_strSysWow64\dllcache\msd3d9.dll" "Microsoft Corporation" "x86"
851
852	; Exchange DLLs
853	${PrepareWRPFileEx} "" "$g_strSysWow64\dllcache\d3d8.dll"
854	${InstallFileEx} "" "$%VBOX_PATH_ADDITIONS_WIN_X86%\d3d8.dll" "$g_strSysWow64\dllcache\d3d8.dll" "$TEMP"
855	${PrepareWRPFileEx} "" "$g_strSysWow64\dllcache\d3d9.dll"
856	${InstallFileEx} "" "$%VBOX_PATH_ADDITIONS_WIN_X86%\d3d9.dll" "$g_strSysWow64\dllcache\d3d9.dll" "$TEMP"
857	${Else}
858	${LogVerbose} "DLL cache does not exist, skipping"
859	${EndIf}
860	${EndIf}
861
862	;
863	; Update original DLLs
864	;
865
866	; Save original DLLs (only if msd3d*.dll does not exist) ...
867	${CopyFileEx} "" "$g_strSysWow64\d3d8.dll" "$g_strSysWow64\msd3d8.dll" "Microsoft Corporation" "x86"
868	${CopyFileEx} "" "$g_strSysWow64\d3d9.dll" "$g_strSysWow64\msd3d9.dll" "Microsoft Corporation" "x86"
869
870	${PrepareWRPFileEx} "" "$g_strSysWow64\d3d8.dll"
871	${InstallFileEx} "" "$%VBOX_PATH_ADDITIONS_WIN_X86%\d3d8.dll" "$g_strSysWow64\d3d8.dll" "$TEMP"
872	${PrepareWRPFileEx} "" "$g_strSysWow64\d3d9.dll"
873	${InstallFileEx} "" "$%VBOX_PATH_ADDITIONS_WIN_X86%\d3d9.dll" "$g_strSysWow64\d3d9.dll" "$TEMP"
874
875	!endif ; amd64
876	Goto done
877
878	error:
879	; @todo
880	Goto exit
881
882	done:
883
884	!ifndef WFP_FILE_EXCEPTION
885	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_WFP_WARN_REPLACE) /SD IDOK
886	!endif
887	Goto exit
888
889	exit:
890
891	SectionEnd
892
893	!ifdef USE_MUI
894	;Assign language strings to sections
895	!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
896	!insertmacro MUI_DESCRIPTION_TEXT ${SEC01} $(VBOX_COMPONENT_MAIN_DESC)
897	!insertmacro MUI_DESCRIPTION_TEXT ${SEC02} $(VBOX_COMPONENT_AUTOLOGON_DESC)
898	!if $%VBOX_WITH_CROGL% == "1"
899	!insertmacro MUI_DESCRIPTION_TEXT ${SEC03} $(VBOX_COMPONENT_D3D_DESC)
900	!endif
901	!insertmacro MUI_DESCRIPTION_TEXT ${SEC04} $(VBOX_COMPONENT_STARTMENU_DESC)
902	!insertmacro MUI_FUNCTION_DESCRIPTION_END
903	!endif ; USE_MUI
904
905	Section -Content
906
907	WriteIniStr "$INSTDIR\${PRODUCT_NAME}.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
908
909	SectionEnd
910
911	; Start menu entries. Enabled by default and can be disabled by the user.
912	Section /o $(VBOX_COMPONENT_STARTMENU) SEC04
913
914	CreateDirectory "$SMPROGRAMS\${PRODUCT_NAME}"
915	CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Website.lnk" "$INSTDIR\${PRODUCT_NAME}.url" "" "$INSTDIR\iexplore.ico"
916	CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Uninstall.lnk" "$INSTDIR\uninst.exe"
917
918	SectionEnd
919
920	; This section is called after all the files are in place
921	Section -Post
922
923	!ifdef _DEBUG
924	${LogVerbose} "Doing post install ..."
925	!endif
926
927	!ifdef EXTERNAL_UNINSTALLER
928	SetOutPath "$INSTDIR"
929	FILE "$%PATH_TARGET%\uninst.exe"
930	!else
931	WriteUninstaller "$INSTDIR\uninst.exe"
932	!endif
933
934	; Write uninstaller in "Add / Remove programs"
935	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
936	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
937	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
938	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
939	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
940
941	; Tune TcpWindowSize for a better network throughput
942	WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Services\Tcpip\Parameters" "TcpWindowSize" 64240
943
944	!ifdef _DEBUG
945	${LogVerbose} "Enable Backdoor logging for debug build."
946	WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Services\VBoxGuest" "LoggingEnabled" 255
947	!endif
948
949	; Add Sun Ray client info keys
950	; Note: We only need 32-bit keys (HKLM\Software / HKLM\Software\Wow6432Node)
951	!if $%BUILD_TARGET_ARCH% == "amd64"
952	WriteRegStr HKLM "SOFTWARE\Wow6432Node\Oracle\Sun Ray\ClientInfoAgent\ReconnectActions" "" ""
953	WriteRegStr HKLM "SOFTWARE\Wow6432Node\Oracle\Sun Ray\ClientInfoAgent\DisconnectActions" "" ""
954	!else
955	WriteRegStr HKLM "SOFTWARE\Oracle\Sun Ray\ClientInfoAgent\ReconnectActions" "" ""
956	WriteRegStr HKLM "SOFTWARE\Oracle\Sun Ray\ClientInfoAgent\DisconnectActions" "" ""
957	!endif
958
959	${LogVerbose} "Installation completed."
960
961	SectionEnd
962
963	; !!! NOTE: This function has to be right under the last section; otherwise it does
964	; not get called! Don't ask me why ... !!!
965	Function .onSelChange
966
967	Push $0
968
969	; Handle selection of D3D component
970	SectionGetFlags ${SEC03} $0
971	${If} $0 == ${SF_SELECTED}
972
973	StrCpy $g_bWithD3D "true"
974
975	!if $%VBOX_WITH_WDDM% == "1"
976	; If we're able to use the WDDM driver just use it instead of the replaced
977	; D3D components below
978	${If} $g_bCapWDDM == "true"
979	;
980	; Temporary solution: Since WDDM is marked as experimental yet we notify the user
981	; that WDDM (Aero) support is available but not recommended for production use. He now
982	; can opt-in for installing WDDM or still go for the old (XPDM) way -- safe mode still required!
983	;
984	MessageBox MB_ICONQUESTION\|MB_YESNO $(VBOX_COMPONENT_D3D_OR_WDDM) /SD IDNO IDYES d3d_install
985	; Display an unconditional hint about needed VRAM sizes
986	; Note: We also could use the PCI configuration space (WMI: Win32_SystemSlot Class) for querying
987	; the current VRAM size, but let's keep it simple for now
988	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_COMPONENT_D3D_HINT_VRAM) /SD IDOK
989	StrCpy $g_bWithWDDM "true"
990	Goto exit
991	${EndIf}
992
993	d3d_install:
994
995	!endif ; $%VBOX_WITH_WDDM% == "1"
996
997	${If} $g_bForceInstall != "true"
998	; Do not install on < XP
999	${If} $g_strWinVersion == "NT4"
1000	${OrIf} $g_strWinVersion == "2000"
1001	${OrIf} $g_strWinVersion == ""
1002	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_COMPONENT_D3D_NOT_SUPPORTED) /SD IDOK
1003	Goto d3d_disable
1004	${EndIf}
1005	${EndIf}
1006
1007	; If force flag is set skip the safe mode check
1008	${If} $g_bForceInstall != "true"
1009	; If we're not in safe mode, print a warning and don't install D3D support
1010	${If} $g_iSystemMode == '0'
1011	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_COMPONENT_D3D_NO_SM) /SD IDOK
1012	Goto d3d_disable
1013	${EndIf}
1014	${EndIf}
1015
1016	${Else} ; D3D unselected again
1017
1018	${If} $g_strWinVersion != "8" ; On Windows 8 WDDM is mandatory
1019	${AndIf} $g_strWinVersion != "8_1" ; ... also on Windows 8.1 / Windows 2012 Server R2
1020	${AndIf} $g_strWinVersion != "10" ; ... also on Windows 10
1021	StrCpy $g_bWithWDDM "false"
1022	${EndIf}
1023
1024	${EndIf}
1025	Goto exit
1026
1027	d3d_disable:
1028
1029	StrCpy $g_bWithD3D "false"
1030	IntOp $0 $0 & ${SECTION_OFF} ; Unselect section again
1031	SectionSetFlags ${SEC03} $0
1032	Goto exit
1033
1034	exit:
1035
1036	Pop $0
1037
1038	FunctionEnd
1039
1040	; This function is called when a critical error occurred, caused by
1041	; the Abort command
1042	Function .onInstFailed
1043
1044	${LogVerbose} "$(VBOX_ERROR_INST_FAILED)"
1045	MessageBox MB_ICONSTOP $(VBOX_ERROR_INST_FAILED) /SD IDOK
1046
1047	${If} $g_bPostInstallStatus == "true"
1048	${LogToVBoxTray} "2" "Error while installing ${PRODUCT_NAME}!"
1049	${EndIf}
1050
1051	; Set overall exit code
1052	SetErrorLevel 1
1053
1054	FunctionEnd
1055
1056	; This function is called when installation was successful!
1057	Function .onInstSuccess
1058
1059	${LogVerbose} "${PRODUCT_NAME} successfully installed"
1060
1061	${If} $g_bPostInstallStatus == "true"
1062	${LogToVBoxTray} "0" "${PRODUCT_NAME} successfully updated!"
1063	${EndIf}
1064
1065	SetErrorLevel 0
1066
1067	FunctionEnd
1068
1069	; This function is called at the very beginning of installer execution
1070	Function .onInit
1071
1072	Push $0
1073
1074	; Init values
1075	StrCpy $g_iSystemMode "0"
1076	StrCpy $g_strCurUser "<None>"
1077	StrCpy $g_strAddVerMaj "0"
1078	StrCpy $g_strAddVerMin "0"
1079	StrCpy $g_strAddVerBuild "0"
1080	StrCpy $g_strAddVerRev "0"
1081
1082	StrCpy $g_bIgnoreUnknownOpts "false"
1083	StrCpy $g_bLogEnable "false"
1084	StrCpy $g_bFakeWHQL "false"
1085	StrCpy $g_bForceInstall "false"
1086	StrCpy $g_bUninstall "false"
1087	StrCpy $g_bRebootOnExit "false"
1088	StrCpy $g_iScreenX "0"
1089	StrCpy $g_iScreenY "0"
1090	StrCpy $g_iScreenBpp "0"
1091	StrCpy $g_iSfOrder "0"
1092	StrCpy $g_bNoVBoxServiceExit "false"
1093	StrCpy $g_bNoVBoxTrayExit "false"
1094	StrCpy $g_bNoVideoDrv "false"
1095	StrCpy $g_bNoGuestDrv "false"
1096	StrCpy $g_bNoMouseDrv "false"
1097	StrCpy $g_bNoStartMenuEntries "false"
1098	StrCpy $g_bWithAutoLogon "false"
1099	StrCpy $g_bWithD3D "false"
1100	StrCpy $g_bOnlyExtract "false"
1101	StrCpy $g_bWithWDDM "false"
1102	StrCpy $g_bCapDllCache "false"
1103	StrCpy $g_bCapWDDM "false"
1104	StrCpy $g_bPostInstallStatus "false"
1105
1106	; We need a special directory set to SysWOW64 because some
1107	; shell operations don't support file redirection (yet)
1108	StrCpy $g_strSysWow64 "$WINDIR\SysWOW64"
1109
1110	SetErrorLevel 0
1111	ClearErrors
1112
1113	!ifdef UNINSTALLER_ONLY
1114
1115	;
1116	; If UNINSTALLER_ONLY is defined, we're only interested in uninst.exe
1117	; so we can sign it
1118	;
1119	; Note that the Quit causes the exit status to be 2 instead of 0
1120	;
1121	WriteUninstaller "$%PATH_TARGET%\uninst.exe"
1122	Quit
1123
1124	!else
1125
1126	; Handle command line
1127	Call HandleCommandLine
1128
1129	; Check if there's already another instance of the installer is running -
1130	; important for preventing NT4 to spawn the installer twice
1131	System::Call 'kernel32::CreateMutexA(i 0, i 0, t "VBoxGuestInstaller") ?e'
1132	Pop $0
1133	${If} $0 != 0
1134	Quit
1135	${EndIf}
1136
1137	; Retrieve Windows version and store result in $g_strWinVersion
1138	Call GetWindowsVersionEx
1139	Pop $g_strWinVersion
1140
1141	; Retrieve capabilities
1142	Call CheckForCapabilities
1143
1144	; Get user Name
1145	AccessControl::GetCurrentUserName
1146	Pop $g_strCurUser
1147	${LogVerbose} "Current user: $g_strCurUser"
1148
1149	; Only extract files? This action can be called even from non-Admin users
1150	; and non-compatible architectures
1151	${If} $g_bOnlyExtract == "true"
1152	Call ExtractFiles
1153	MessageBox MB_OK\|MB_ICONINFORMATION $(VBOX_EXTRACTION_COMPLETE) /SD IDOK
1154	Quit
1155	${EndIf}
1156
1157	; Check for correct architecture
1158	Call CheckArchitecture
1159	Pop $0
1160	${If} $0 <> 0 ; Wrong architecture? Tell the world
1161	!if $%BUILD_TARGET_ARCH% == "amd64"
1162	MessageBox MB_ICONSTOP $(VBOX_NOTICE_ARCH_AMD64) /SD IDOK
1163	!else
1164	MessageBox MB_ICONSTOP $(VBOX_NOTICE_ARCH_X86) /SD IDOK
1165	!endif
1166	Abort "$(VBOX_NOTICE_ARCH_AMD64)"
1167	${EndIf}
1168
1169	; Has the user who calls us admin rights?
1170	UserInfo::GetAccountType
1171	Pop $0
1172	${If} $0 != "Admin"
1173	MessageBox MB_ICONSTOP $(VBOX_NOADMIN) /SD IDOK
1174	Abort
1175	${EndIf}
1176
1177	; Only uninstall?
1178	${If} $g_bUninstall == "true"
1179	Call Uninstall_Innotek
1180	Call Uninstall
1181	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_UNINST_SUCCESS) /SD IDOK
1182	Quit
1183	${EndIf}
1184
1185	Call CheckForInstalledComponents
1186
1187	;
1188	; Section 02
1189	;
1190	${If} $g_bWithAutoLogon == "true" ; Auto-logon support
1191	!insertmacro SelectSection ${SEC02}
1192	${EndIf}
1193
1194	;
1195	; Section 03
1196	;
1197	!if $%VBOX_WITH_CROGL% == "1"
1198	${If} $g_bWithD3D == "true" ; D3D support
1199	!insertmacro SelectSection ${SEC03}
1200	${EndIf}
1201	!endif
1202	${If} $g_bWithWDDM == "true" ; D3D / WDDM support
1203	!insertmacro SelectSection ${SEC03}
1204	${EndIf}
1205	; On Windows 8 / 8.1 / Windows Server 2012 R2 and newer we always select the 3D
1206	; section and disable it so that it cannot be deselected again
1207	${If} $g_strWinVersion == "8"
1208	${OrIf} $g_strWinVersion == "8_1"
1209	${OrIf} $g_strWinVersion == "10"
1210	IntOp $0 ${SF_SELECTED} \| ${SF_RO}
1211	SectionSetFlags ${SEC03} $0
1212	${EndIf}
1213
1214	;
1215	; Section 04
1216	;
1217	${If} $g_bNoStartMenuEntries == "false" ; Start menu entries
1218	!insertmacro SelectSection ${SEC04}
1219	${EndIf}
1220
1221	!ifdef USE_MUI
1222	; Display language selection dialog (will be hidden in silent mode!)
1223	!ifdef VBOX_INSTALLER_ADD_LANGUAGES
1224	!insertmacro MUI_LANGDLL_DISPLAY
1225	!endif
1226	!endif
1227
1228	Call SetAppMode64
1229
1230	; Check for old additions
1231	Call CheckForOldGuestAdditions
1232	Call GetAdditionsVersion
1233
1234	; Due to some bug in NSIS the license page won't be displayed if we're in
1235	; 64-bit registry view, so as a workaround switch back to 32-bit (Wow6432Node)
1236	; mode for now
1237	Call SetAppMode32
1238
1239	!endif ; UNINSTALLER_ONLY
1240
1241	Pop $0
1242
1243	FunctionEnd
1244
1245	;
1246	; The uninstaller is built separately when doing code signing
1247	; For some reason NSIS still finds the Uninstall section even
1248	; when EXTERNAL_UNINSTALLER is defined. This causes a silly warning
1249	;
1250	!ifndef EXTERNAL_UNINSTALLER
1251
1252	Function un.onUninstSuccess
1253
1254	HideWindow
1255	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_UNINST_SUCCESS) /SD IDOK
1256
1257	FunctionEnd
1258
1259	Function un.onInit
1260
1261	; Has the user who calls us admin rights?
1262	UserInfo::GetAccountType
1263	Pop $0
1264	${If} $0 != "Admin"
1265	MessageBox MB_ICONSTOP $(VBOX_NOADMIN) /SD IDOK
1266	Abort
1267	${EndIf}
1268
1269	MessageBox MB_ICONQUESTION\|MB_YESNO\|MB_DEFBUTTON2 $(VBOX_UNINST_CONFIRM) /SD IDYES IDYES proceed
1270	Quit
1271
1272	proceed:
1273
1274	Call un.SetAppMode64
1275
1276	; Set system directory
1277	StrCpy $g_strSystemDir "$SYSDIR"
1278
1279	; We need a special directory set to SysWOW64 because some
1280	; shell operations don't support file redirection (yet)
1281	StrCpy $g_strSysWow64 "$WINDIR\SysWOW64"
1282
1283	; Retrieve Windows version we're running on and store it in $g_strWinVersion
1284	Call un.GetWindowsVersionEx
1285	Pop $g_strWinVersion
1286
1287	; Retrieve capabilities
1288	Call un.CheckForCapabilities
1289
1290	FunctionEnd
1291
1292	Section Uninstall
1293
1294	!ifdef _DEBUG
1295	${LogEnable} "true"
1296	!endif
1297
1298	Call un.SetAppMode64
1299
1300	; Call the uninstall main function
1301	Call un.Uninstall
1302
1303	; ... and remove the local install directory
1304	Call un.UninstallInstDir
1305
1306	!ifndef _DEBUG
1307	SetAutoClose true
1308	MessageBox MB_ICONQUESTION\|MB_YESNO\|MB_DEFBUTTON2 $(VBOX_REBOOT_REQUIRED) /SD IDNO IDYES restart
1309	StrCmp $g_bRebootOnExit "true" restart
1310	!endif
1311
1312	Goto exit
1313
1314	restart:
1315
1316	${LogVerbose} "Rebooting ..."
1317	Reboot
1318
1319	exit:
1320
1321	SectionEnd
1322
1323	; !EXTERNAL_UNINSTALLER
1324	!endif
1325
1326	;Direct the output to our bin dir
1327	!cd "$%PATH_OUT%\bin\additions"

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format