VBoxGuestAdditions.nsi@ 46478

Last change on this file since 46478 was 45952, checked in by vboxsync, 12 years ago
Windows Guest Additions installer: Select 3D section to reflect /with_wddm switch, help typo.
Property svn:eol-style set to `native` Property svn:keywords set to `Author Date Id Revision`
File size: 42.8 KB

Line
1	; $Id: VBoxGuestAdditions.nsi 45952 2013-05-08 15:01:59Z vboxsync $
2	; @file
3	; VBoxGuestAdditions.nsi - Main file for Windows Guest Additions installation.
4	;
5
6	;
7	; Copyright (C) 2012-2013 Oracle Corporation
8	;
9	; This file is part of VirtualBox Open Source Edition (OSE), as
10	; available from http://www.virtualbox.org. This file is free software;
11	; you can redistribute it and/or modify it under the terms of the GNU
12	; General Public License (GPL) as published by the Free Software
13	; Foundation, in version 2 as it comes in the "COPYING" file of the
14	; VirtualBox OSE distribution. VirtualBox OSE is distributed in the
15	; hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
16	;
17
18	!if $%BUILD_TYPE% == "debug"
19	!define _DEBUG ; Turn this on to get extra output
20	!endif
21
22	!ifdef _DEBUG
23	; Scratch directory for plugin tests
24	!addincludedir .\PluginTest
25	!addplugindir .\PluginTest
26	!endif
27
28	; Defines for special functions
29	!define WHQL_FAKE ; Enables faking of non WHQL signed / approved drivers
30	; Needs the VBoxWHQLFake.exe in the additions output directory!
31	!define WFP_FILE_EXCEPTION ; Enables setting a temporary file exception for WFP proctected files
32
33	!define VENDOR_ROOT_KEY "SOFTWARE\$%VBOX_VENDOR_SHORT%"
34
35	; Product defines
36	!define PRODUCT_NAME "$%VBOX_PRODUCT% Guest Additions"
37	!define PRODUCT_DESC "$%VBOX_PRODUCT% Guest Additions"
38	!define PRODUCT_VERSION "$%VBOX_VERSION_MAJOR%.$%VBOX_VERSION_MINOR%.$%VBOX_VERSION_BUILD%.0"
39	!define PRODUCT_PUBLISHER "$%VBOX_VENDOR%"
40	!define PRODUCT_COPYRIGHT "(C) $%VBOX_C_YEAR% $%VBOX_VENDOR%"
41	!define PRODUCT_OUTPUT "VBoxWindowsAdditions-$%BUILD_TARGET_ARCH%.exe"
42	!define PRODUCT_WEB_SITE "http://www.virtualbox.org"
43	!define PRODUCT_INSTALL_KEY "${VENDOR_ROOT_KEY}\VirtualBox Guest Additions"
44	!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
45	!define PRODUCT_UNINST_ROOT_KEY "HKLM"
46
47	!define LICENSE_FILE_RTF "license.rtf"
48
49	; Needed for InstallLib macro: Install libraries in every case
50	!define LIBRARY_IGNORE_VERSION
51
52	VIProductVersion "${PRODUCT_VERSION}"
53	VIAddVersionKey "FileVersion" "$%VBOX_VERSION_STRING%"
54	VIAddVersionKey "ProductName" "${PRODUCT_NAME}"
55	VIAddVersionKey "ProductVersion" "${PRODUCT_VERSION}"
56	VIAddVersionKey "CompanyName" "${PRODUCT_PUBLISHER}"
57	VIAddVersionKey "FileDescription" "${PRODUCT_DESC}"
58	VIAddVersionKey "LegalCopyright" "${PRODUCT_COPYRIGHT}"
59	VIAddVersionKey "InternalName" "${PRODUCT_OUTPUT}"
60
61	; This registry key will hold the mouse driver path before install (NT4 only)
62	!define ORG_MOUSE_PATH "MousePath"
63
64	; If we have our guest install helper DLL, add the
65	; plugin path so that NSIS can find it when compiling the installer
66	; Note: NSIS plugins always have to be compiled in 32-bit!
67	!if $%VBOX_WITH_GUEST_INSTALL_HELPER% == "1"
68	!addplugindir "$%PATH_TARGET_X86%\VBoxGuestInstallHelper"
69	!endif
70
71	!include "LogicLib.nsh"
72	!include "FileFunc.nsh"
73	!insertmacro GetParameters
74	!insertmacro GetOptions
75	!include "WordFunc.nsh"
76	!insertmacro WordFind
77	!insertmacro StrFilter
78
79	!include "nsProcess.nsh"
80	!include "Library.nsh"
81	!include "Sections.nsh"
82	!include "strstr.nsh" ; Function "strstr"
83	!include "servicepack.nsh" ; Function "GetServicePack"
84	!include "winver.nsh" ; Function for determining Windows version
85	!define REPLACEDLL_NOREGISTER ; Replace in use DLL function
86	!include "ReplaceDLL.nsh"
87	!include "dumplog.nsh" ; Dump log to file function
88
89	!if $%BUILD_TARGET_ARCH% == "amd64"
90	!include "x64.nsh"
91	!endif
92
93	; Set Modern UI (MUI) as default
94	!define USE_MUI
95
96	!ifdef USE_MUI
97	; Use modern UI, version 2
98	!include "MUI2.nsh"
99
100	; MUI Settings
101	!define MUI_WELCOMEFINISHPAGE_BITMAP "$%VBOX_BRAND_WIN_ADD_INST_DLGBMP%"
102	!define MUI_ABORTWARNING
103	!define MUI_WELCOMEPAGE_TITLE_3LINES "Welcome to the ${PRODUCT_NAME} Additions Setup"
104
105	; API defines
106	!define SM_CLEANBOOT 67
107
108	; Icons
109	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit
110	!define MUI_ICON "$%VBOX_NSIS_ICON_FILE%"
111	!define MUI_UNICON "$%VBOX_NSIS_ICON_FILE%"
112	!else ; 64-bit
113	!define MUI_ICON "$%VBOX_WINDOWS_ADDITIONS_ICON_FILE%"
114	!define MUI_UNICON "$%VBOX_WINDOWS_ADDITIONS_ICON_FILE%"
115	!endif
116
117	; Welcome page
118	!insertmacro MUI_PAGE_WELCOME
119	!ifdef VBOX_WITH_LICENSE_DISPLAY
120	; License page
121	!insertmacro MUI_PAGE_LICENSE "$(VBOX_LICENSE)"
122	!define MUI_LICENSEPAGE_RADIOBUTTONS
123	!endif
124	; Directory page
125	!insertmacro MUI_PAGE_DIRECTORY
126	; Components Page
127	!insertmacro MUI_PAGE_COMPONENTS
128	; Instfiles page
129	!insertmacro MUI_PAGE_INSTFILES
130
131	!ifndef _DEBUG
132	!define MUI_FINISHPAGE_TITLE_3LINES ; Have a bit more vertical space for text
133	!insertmacro MUI_PAGE_FINISH ; Only show in release mode - useful information for debugging!
134	!endif
135
136	; Uninstaller pages
137	!insertmacro MUI_UNPAGE_INSTFILES
138
139	; Define languages we will use
140	!insertmacro MUI_LANGUAGE "English"
141	!insertmacro MUI_LANGUAGE "French"
142	!insertmacro MUI_LANGUAGE "German"
143
144	; Set branding text which appears on the horizontal line at the bottom
145	!ifdef _DEBUG
146	BrandingText "VirtualBox Windows Additions $%VBOX_VERSION_STRING% (r$%VBOX_SVN_REV%) - Debug Build"
147	!else
148	BrandingText "VirtualBox Windows Additions $%VBOX_VERSION_STRING%"
149	!endif
150
151	!ifdef VBOX_WITH_LICENSE_DISPLAY
152	; Set license language
153	LicenseLangString VBOX_LICENSE ${LANG_ENGLISH} "$%VBOX_BRAND_LICENSE_RTF%"
154
155	; If license files not available (OSE / PUEL) build, then use the English one as default
156	!ifdef VBOX_BRAND_fr_FR_LICENSE_RTF
157	LicenseLangString VBOX_LICENSE ${LANG_FRENCH} "$%VBOX_BRAND_fr_FR_LICENSE_RTF%"
158	!else
159	LicenseLangString VBOX_LICENSE ${LANG_FRENCH} "$%VBOX_BRAND_LICENSE_RTF%"
160	!endif
161	!ifdef VBOX_BRAND_de_DE_LICENSE_RTF
162	LicenseLangString VBOX_LICENSE ${LANG_GERMAN} "$%VBOX_BRAND_de_DE_LICENSE_RTF%"
163	!else
164	LicenseLangString VBOX_LICENSE ${LANG_GERMAN} "$%VBOX_BRAND_LICENSE_RTF%"
165	!endif
166	!endif
167
168	!insertmacro MUI_RESERVEFILE_LANGDLL
169	!else ; !USE_MUI
170	XPStyle on
171	!ifdef VBOX_WITH_LICENSE_DISPLAY
172	Page license
173	!endif
174	Page components
175	Page directory
176	Page instfiles
177	!endif
178
179	; Language files
180	!include "Languages\English.nsh"
181	!include "Languages\French.nsh"
182	!include "Languages\German.nsh"
183
184	; Variables and output files
185	Name "${PRODUCT_NAME} $%VBOX_VERSION_STRING%"
186	!ifdef UNINSTALLER_ONLY
187	!echo "Uninstaller only!"
188	OutFile "$%PATH_TARGET%\VBoxWindowsAdditions-$%BUILD_TARGET_ARCH%-uninst.exe"
189	!else
190	OutFile "VBoxWindowsAdditions-$%BUILD_TARGET_ARCH%.exe"
191	!endif ; UNINSTALLER_ONLY
192
193	; Define default installation directory
194	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit
195	InstallDir "$PROGRAMFILES32\$%VBOX_VENDOR_SHORT%\VirtualBox Guest Additions"
196	!else ; 64-bit
197	InstallDir "$PROGRAMFILES64\$%VBOX_VENDOR_SHORT%\VirtualBox Guest Additions"
198	!endif
199
200	InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" ""
201	ShowInstDetails show
202	ShowUnInstDetails show
203	RequestExecutionLevel highest
204
205	; Internal parameters
206	Var g_iSystemMode ; Current system mode (0 = Normal boot, 1 = Fail-safe boot, 2 = Fail-safe with network boot)
207	Var g_strSystemDir ; Windows system directory
208	Var g_strSysWow64 ; The SysWow64 directory on 64-bit systems
209	Var g_strCurUser ; Current user using the system
210	Var g_strAddVerMaj ; Installed Guest Additions: Major version
211	Var g_strAddVerMin ; Installed Guest Additions: Minor version
212	Var g_strAddVerBuild ; Installed Guest Additions: Build number
213	Var g_strAddVerRev ; Installed Guest Additions: SVN revision
214	Var g_strWinVersion ; Current Windows version we're running on
215	Var g_bLogEnable ; Do logging when installing? "true" or "false"
216	Var g_bWithWDDM ; Install the WDDM graphics driver instead of the XPDM one
217	Var g_bCapDllCache ; Capability: Does the (Windows) guest have have a DLL cache which needs to be taken care of?
218	Var g_bCapWDDM ; Capability: Is the guest able to handle/use our WDDM driver?
219
220	; Command line parameters - these can be set/modified
221	; on the command line
222	Var g_bFakeWHQL ; Cmd line: Fake Windows to install non WHQL certificated drivers (only for W2K and XP currently!!) ("/unsig_drv")
223	Var g_bForceInstall ; Cmd line: Force installation on unknown Windows OS version
224	Var g_bUninstall ; Cmd line: Just uninstall any previous Guest Additions and exit
225	Var g_bRebootOnExit ; Cmd line: Auto-Reboot on successful installation. Good for unattended installations ("/reboot")
226	Var g_iScreenBpp ; Cmd line: Screen depth ("/depth=X")
227	Var g_iScreenX ; Cmd line: Screen resolution X ("/resx=X")
228	Var g_iScreenY ; Cmd line: Screen resolution Y ("/resy=Y")
229	Var g_iSfOrder ; Cmd line: Order of Shared Folders network provider (0=first, 1=second, ...)
230	Var g_bIgnoreUnknownOpts ; Cmd line: Ignore unknown options (don't display the help)
231	Var g_bNoVBoxServiceExit ; Cmd line: Do not quit VBoxService before updating - install on next reboot
232	Var g_bNoVBoxTrayExit ; Cmd line: Do not quit VBoxTray before updating - install on next reboot
233	Var g_bNoVideoDrv ; Cmd line: Do not install the VBoxVideo driver
234	Var g_bNoGuestDrv ; Cmd line: Do not install the VBoxGuest driver
235	Var g_bNoMouseDrv ; Cmd line: Do not install the VBoxMouse driver
236	Var g_bWithAutoLogon ; Cmd line: Install VBoxGINA / VBoxCredProv for auto logon support
237	Var g_bWithVBoxMMR ; Cmd line: Install VBoxMMR for media redirection support
238	Var g_bWithD3D ; Cmd line: Install Direct3D support
239	Var g_bOnlyExtract ; Cmd line: Only extract all files, do not install them. Only valid with param "/D" (target directory)
240	Var g_bPostInstallStatus ; Cmd line: Post the overall installation status to some external program (VBoxTray)
241
242	; Platform parts of this installer
243	!include "VBoxGuestAdditionsLog.nsh"
244	!include "VBoxGuestAdditionsExternal.nsh"
245	!include "VBoxGuestAdditionsCommon.nsh"
246	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit only
247	!include "VBoxGuestAdditionsNT4.nsh"
248	!endif
249	!include "VBoxGuestAdditionsW2KXP.nsh"
250	!include "VBoxGuestAdditionsVista.nsh"
251	!include "VBoxGuestAdditionsUninstall.nsh" ; Product uninstallation
252	!include "VBoxGuestAdditionsUninstallOld.nsh" ; Uninstallation of deprecated versions which must be removed first
253
254	Function HandleCommandLine
255
256	Push $0 ; Command line (without process name)
257	Push $1 ; Number of parameters
258	Push $2 ; Current parameter index
259	Push $3 ; Current parameter pair (name=value)
260	Push $4 ; Current parameter name
261	Push $5 ; Current parameter value (if present)
262
263	StrCpy $1 "0" ; Init param counter
264	StrCpy $2 "1" ; Init current param counter
265
266	${GetParameters} $0 ; Extract command line
267	${If} $0 == "" ; If no parameters at all exit
268	Goto exit
269	${EndIf}
270
271	; Enable for debugging
272	;MessageBox MB_OK "CmdLine: $0"
273
274	${WordFind} $0 " " "#" $1 ; Get number of parameters in cmd line
275	${If} $0 == $1 ; If result matches the input then
276	StrCpy $1 "1" ; no delimiter was found. Correct to 1 word total
277	${EndIf}
278
279	${While} $2 <= $1 ; Loop through all params
280
281	${WordFind} $0 " " "+$2" $3 ; Get current name=value pair
282	${WordFind} $3 "=" "+1" $4 ; Get current param name
283	${WordFind} $3 "=" "+2" $5 ; Get current param value
284
285	${StrFilter} $4 "-" "" "" $4 ; Transfer param name to lowercase
286
287	; Enable for debugging
288	;MessageBox MB_OK "#$2 of #$1, param='$3', name=$4, val=$5"
289
290	${Switch} $4
291
292	${Case} '/d' ; NSIS: /D=<instdir> switch, skip
293	${Break}
294
295	${Case} '/depth'
296	${Case} 'depth'
297	StrCpy $g_iScreenBpp $5
298	${Break}
299
300	${Case} '/extract'
301	StrCpy $g_bOnlyExtract "true"
302	${Break}
303
304	${Case} '/force'
305	StrCpy $g_bForceInstall "true"
306	${Break}
307
308	${Case} '/help'
309	${Case} '/H'
310	${Case} '/h'
311	${Case} '/?'
312	Goto usage
313	${Break}
314
315	${Case} '/ignore_unknownopts' ; Not officially documented
316	StrCpy $g_bIgnoreUnknownOpts "true"
317	${Break}
318
319	${Case} '/l'
320	${Case} '/log'
321	${Case} '/logging'
322	StrCpy $g_bLogEnable "true"
323	${Break}
324
325	${Case} '/ncrc' ; NSIS: /NCRC switch, skip
326	${Break}
327
328	${Case} '/no_vboxservice_exit' ; Not officially documented
329	StrCpy $g_bNoVBoxServiceExit "true"
330	${Break}
331
332	${Case} '/no_vboxtray_exit' ; Not officially documented
333	StrCpy $g_bNoVBoxTrayExit "true"
334	${Break}
335
336	${Case} '/no_videodrv' ; Not officially documented
337	StrCpy $g_bNoVideoDrv "true"
338	${Break}
339
340	${Case} '/no_guestdrv' ; Not officially documented
341	StrCpy $g_bNoGuestDrv "true"
342	${Break}
343
344	${Case} '/no_mousedrv' ; Not officially documented
345	StrCpy $g_bNoMouseDrv "true"
346	${Break}
347
348	!if $%VBOX_WITH_GUEST_INSTALL_HELPER% == "1"
349	; This switch tells our installer that it
350	; - should not quit VBoxTray during the update, because ...
351	; - ... it should show the overall installation status
352	; using VBoxTray's balloon message feature (since VBox 4.0)
353	${Case} '/post_installstatus' ; Not officially documented
354	StrCpy $g_bNoVBoxTrayExit "true"
355	StrCpy $g_bPostInstallStatus "true"
356	${Break}
357	!endif
358
359	${Case} '/reboot'
360	StrCpy $g_bRebootOnExit "true"
361	${Break}
362
363	${Case} '/s' ; NSIS: /S switch, skip
364	${Break}
365
366	${Case} '/sforder'
367	${Case} 'sforder'
368	StrCpy $g_iSfOrder $5
369	${Break}
370
371	!ifdef WHQL_FAKE
372	${Case} '/unsig_drv'
373	StrCpy $g_bFakeWHQL "true"
374	${Break}
375	!endif
376
377	${Case} '/uninstall'
378	StrCpy $g_bUninstall "true"
379	${Break}
380
381	${Case} '/with_autologon'
382	StrCpy $g_bWithAutoLogon "true"
383	${Break}
384
385	!if $%VBOX_WITH_MMR% == "1"
386	${Case} '/with_vboxmmr'
387	StrCpy $g_bWithVBoxMMR "true"
388	${Break}
389	!endif
390
391	!if $%VBOX_WITH_CROGL% == "1"
392	${Case} '/with_d3d'
393	${Case} '/with_direct3d'
394	StrCpy $g_bWithD3D "true"
395	${Break}
396	!endif
397
398	!if $%VBOX_WITH_WDDM% == "1"
399	${Case} '/with_wddm'
400	StrCpy $g_bWithWDDM "true"
401	${Break}
402	!endif
403
404	${Case} '/xres'
405	${Case} 'xres'
406	StrCpy $g_iScreenX $5
407	${Break}
408
409	${Case} '/yres'
410	${Case} 'yres'
411	StrCpy $g_iScreenY $5
412	${Break}
413
414	${Default} ; Unknown parameter, print usage message
415	; Prevent popping up usage message on (yet) unknown parameters
416	; in silent mode, just skip
417	IfSilent +1 +2
418	${Break}
419	goto usage
420	${Break}
421
422	${EndSwitch}
423
424	next_param:
425
426	IntOp $2 $2 + 1
427
428	${EndWhile}
429	Goto exit
430
431	usage:
432
433	; If we were told to ignore unknown (invalid) options, just return to
434	; the parsing loop ...
435	${If} $g_bIgnoreUnknownOpts == "true"
436	Goto next_param
437	${EndIf}
438	MessageBox MB_OK "${PRODUCT_NAME} Installer$\r$\n$\r$\n \
439	Usage: VBoxWindowsAdditions-$%BUILD_TARGET_ARCH% [OPTIONS] [/l] [/S] [/D=<PATH>]$\r$\n$\r$\n \
440	Options:$\r$\n \
441	/depth=BPP$\tSets the guest's display color depth (bits per pixel)$\r$\n \
442	/extract$\t$\tOnly extract installation files$\r$\n \
443	/force$\t$\tForce installation on unknown/undetected Windows versions$\r$\n \
444	/uninstall$\t$\tJust uninstalls the Guest Additions and exits$\r$\n \
445	/with_autologon$\tInstalls auto-logon support$\r$\n \
446	/with_d3d$\tInstalls D3D support$\r$\n \
447	/with_vboxmmr$\tInstalls multimedia redirection (MMR) support$\r$\n \
448	/with_wddm$\tInstalls the WDDM instead of the XPDM graphics driver$\r$\n \
449	/xres=X$\t$\tSets the guest's display resolution (width in pixels)$\r$\n \
450	/yres=Y$\t$\tSets the guest's display resolution (height in pixels)$\r$\n \
451	$\r$\n \
452	Installer parameters:$\r$\n \
453	/l$\t$\tEnables logging$\r$\n \
454	/S$\t$\tSilent install$\r$\n \
455	/D=<PATH>$\tSets the default install path$\r$\n \
456	$\r$\n \
457	Note: Order of options and installer parameters are mandatory." /SD IDOK
458
459	; No stack restore needed, we're about to quit
460	Quit
461
462	done:
463
464	!ifdef _DEBUG
465	${LogVerbose} "Property: XRes: $g_iScreenX"
466	${LogVerbose} "Property: YRes: $g_iScreenY"
467	${LogVerbose} "Property: BPP: $g_iScreenBpp"
468	${LogVerbose} "Property: Logging enabled: $g_bLogEnable"
469	!endif
470
471	exit:
472
473	Pop $5
474	Pop $4
475	Pop $3
476	Pop $2
477	Pop $1
478	Pop $0
479
480	FunctionEnd
481
482	Function CheckForOldGuestAdditions
483
484	Push $0
485	Push $1
486	Push $2
487
488	begin:
489
490	${LogVerbose} "Checking for old Guest Additions ..."
491
492	sun_check:
493
494	; Check for old "Sun VirtualBox Guest Additions"
495	; - before rebranding to Oracle
496	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Sun VirtualBox Guest Additions" "UninstallString"
497	StrCmp $0 "" sun_xvm_check ; If string is empty, Sun additions are probably not installed (anymore)
498
499	MessageBox MB_YESNO $(VBOX_SUN_FOUND) /SD IDYES IDYES sun_uninstall
500	Pop $2
501	Pop $1
502	Pop $0
503	MessageBox MB_ICONSTOP $(VBOX_SUN_ABORTED) /SD IDOK
504	Quit
505
506	sun_uninstall:
507
508	Call Uninstall_Sun
509	Goto success
510
511	sun_xvm_check:
512
513	; Check for old "Sun xVM VirtualBox Guest Additions"
514	; - before getting rid of the "xVM" namespace
515	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Sun xVM VirtualBox Guest Additions" "UninstallString"
516	StrCmp $0 "" innotek_check ; If string is empty, Sun xVM additions are probably not installed (anymore)
517
518	MessageBox MB_YESNO $(VBOX_SUN_FOUND) /SD IDYES IDYES sun_xvm_uninstall
519	Pop $2
520	Pop $1
521	Pop $0
522	MessageBox MB_ICONSTOP $(VBOX_SUN_ABORTED) /SD IDOK
523	Quit
524
525	sun_xvm_uninstall:
526
527	Call Uninstall_SunXVM
528	Goto success
529
530	innotek_check:
531
532	; Check for old "innotek" Guest Additions" before rebranding to "Sun"
533	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\innotek VirtualBox Guest Additions" "UninstallString"
534	StrCmp $0 "" exit ; If string is empty, innotek Guest Additions are probably not installed (anymore)
535
536	MessageBox MB_YESNO $(VBOX_INNOTEK_FOUND) /SD IDYES IDYES innotek_uninstall
537	Pop $2
538	Pop $1
539	Pop $0
540	MessageBox MB_ICONSTOP $(VBOX_INNOTEK_ABORTED) /SD IDOK
541	Quit
542
543	innotek_uninstall:
544
545	Call Uninstall_Innotek
546	Goto success
547
548	success:
549
550	; Nothing to do here yet
551
552	exit:
553
554	Pop $2
555	Pop $1
556	Pop $0
557
558	FunctionEnd
559
560	Function CheckForInstalledComponents
561
562	Push $0
563	Push $1
564
565	${LogVerbose} "Checking for installed components ..."
566	StrCpy $1 ""
567
568	Call SetAppMode64
569
570	; VBoxGINA already installed? So we need to update the installed version as well,
571	; regardless whether the user used "/with_autologon" or not
572	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
573	${If} $0 == "VBoxGINA.dll"
574	StrCpy $1 "GINA"
575	${Else}
576	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\Credential Providers\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}" ""
577	${If} $0 == "VBoxCredProv"
578	StrCpy $1 "Credential Provider"
579	${EndIf}
580	${EndIf}
581
582	!ifdef _DEBUG
583	${LogVerbose} "Auto-logon module: $0"
584	!endif
585
586	${IfNot} $1 == ""
587	${LogVerbose} "Auto-logon support ($1) was installed previously"
588	StrCpy $g_bWithAutoLogon "true" ; Force update
589	${Else}
590	${LogVerbose} "Auto-logon support was not installed previously"
591	${EndIf}
592
593	; Check for installed MMR support and enable updating
594	; those modules if needed
595	${If} ${FileExists} "$g_strSystemDir\VBoxMMR.exe"
596	!if $%BUILD_TARGET_ARCH% == "amd64"
597	${AndIf} ${FileExists} "$g_strSysWow64\VBoxMMRHook.dll"
598	!else
599	${AndIf} ${FileExists} "$g_strSystemDir\VBoxMMRHook.dll"
600	!endif
601	${LogVerbose} "MultiMedia Redirection support (MMR) was installed previously"
602	StrCpy $g_bWithVBoxMMR "true" ; Force update
603	${Else}
604	${LogVerbose} "MultiMedia Redirection support (MMR) support was not installed previously"
605	${EndIf}
606
607	Pop $1
608	Pop $0
609
610	FunctionEnd
611
612	; Main Files
613	Section $(VBOX_COMPONENT_MAIN) SEC01
614
615	SectionIn RO ; Section cannot be unselected (read-only)
616	${If} $g_bPostInstallStatus == "true"
617	${LogToVBoxTray} "0" "${PRODUCT_NAME} update started, please wait ..."
618	${EndIf}
619
620	IfSilent +1 +2
621	StrCpy $g_bLogEnable "true" ; Force logging in silent mode
622
623	${LogEnable} "$g_bLogEnable"
624	IfSilent +1 +2 ; NSIS will expand ${LogVerbose} before doing relative jumps!
625	LogText "Installer runs in silent mode"
626
627	SetOutPath "$INSTDIR"
628	SetOverwrite on
629
630	Call SetAppMode64
631
632	StrCpy $g_strSystemDir "$SYSDIR"
633
634	${LogVerbose} "Version: $%VBOX_VERSION_STRING% (Rev $%VBOX_SVN_REV%)"
635	${If} $g_strAddVerMaj != ""
636	${LogVerbose} "Previous version: $g_strAddVerMaj.$g_strAddVerMin.$g_strAddVerBuild (Rev $g_strAddVerRev)"
637	${Else}
638	${LogVerbose} "No previous version of ${PRODUCT_NAME} detected"
639	${EndIf}
640	!if $%BUILD_TARGET_ARCH% == "amd64"
641	${LogVerbose} "Detected OS: Windows $g_strWinVersion (64-bit)"
642	!else
643	${LogVerbose} "Detected OS: Windows $g_strWinVersion (32-bit)"
644	!endif
645	${LogVerbose} "System Directory: $g_strSystemDir"
646
647	!ifdef _DEBUG
648	${LogVerbose} "Installer runs in debug mode"
649	!endif
650
651	;
652	; Here starts the main dispatcher (based on guest OS)
653	;
654
655	; Which OS are we using?
656	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit
657	StrCmp $g_strWinVersion "NT4" nt4 ; Windows NT 4.0
658	!endif
659	StrCmp $g_strWinVersion "2000" w2k ; Windows 2000
660	StrCmp $g_strWinVersion "XP" w2k ; Windows XP
661	StrCmp $g_strWinVersion "2003" w2k ; Windows 2003 Server
662	StrCmp $g_strWinVersion "Vista" vista ; Windows Vista
663	StrCmp $g_strWinVersion "7" vista ; Windows 7
664	StrCmp $g_strWinVersion "8" vista ; Windows 8
665
666	${If} $g_bForceInstall == "true"
667	Goto vista ; Assume newer OS than we know of ...
668	${EndIf}
669
670	Goto notsupported
671
672	!if $%BUILD_TARGET_ARCH% == "x86" ; 32-bit
673	nt4: ; Windows NT4
674
675	Call GetServicePack
676	Pop $R0 ; Major version
677	Pop $R1 ; Minor version
678
679	; At least Service Pack 6 installed?
680	${If} $R0 <> "6"
681	MessageBox MB_YESNO $(VBOX_NT4_NO_SP6) /SD IDYES IDYES +2
682	Quit
683	${EndIf}
684
685	; Copy some common files ...
686	Call Common_CopyFiles
687
688	Call NT4_Main
689	goto success
690	!endif
691
692	w2k: ; Windows 2000 and XP ...
693
694	; Copy some common files ...
695	Call Common_CopyFiles
696
697	Call W2K_Main
698	goto success
699
700	vista: ; Windows Vista / Windows 7 / Windows 8
701
702	; Check requirments; this function can abort the installation if necessary!
703	Call Vista_CheckForRequirements
704
705	; Copy some common files ...
706	Call Common_CopyFiles
707
708	Call W2K_Main ; First install stuff from Windows 2000 / XP
709	Call Vista_Main ; ... and some specific stuff for Vista / Windows 7
710	goto success
711
712	notsupported:
713
714	MessageBox MB_ICONSTOP $(VBOX_PLATFORM_UNSUPPORTED) /SD IDOK
715	goto exit
716
717	success:
718
719	; Write a registry key with version and installation path for later lookup
720	WriteRegStr HKLM "${PRODUCT_INSTALL_KEY}" "Version" "$%VBOX_VERSION_STRING_RAW%"
721	WriteRegStr HKLM "${PRODUCT_INSTALL_KEY}" "VersionExt" "$%VBOX_VERSION_STRING%"
722	WriteRegStr HKLM "${PRODUCT_INSTALL_KEY}" "Revision" "$%VBOX_SVN_REV%"
723	WriteRegStr HKLM "${PRODUCT_INSTALL_KEY}" "InstallDir" "$INSTDIR"
724
725	; Set the reboot flag to tell the finish page that is should
726	; default to the "reboot now" entry
727	SetRebootFlag true
728
729	exit:
730
731	SectionEnd
732
733	; Auto-logon support (section is hidden at the moment -- only can be enabled via command line switch)
734	Section /o -$(VBOX_COMPONENT_AUTOLOGON) SEC02
735
736	Call SetAppMode64
737
738	Call GetWindowsVersion
739	Pop $R0 ; Windows Version
740
741	${LogVerbose} "Installing auto-logon support ..."
742
743	; Another GINA already is installed? Check if this is ours, otherwise let the user decide (unless it's a silent setup)
744	; whether to replace it with the VirtualBox one or not
745	ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL"
746	${If} $0 != ""
747	${If} $0 != "VBoxGINA.dll"
748	${LogVerbose} "Found another already installed GINA module: $0"
749	MessageBox MB_ICONQUESTION\|MB_YESNO\|MB_DEFBUTTON1 $(VBOX_COMPONENT_AUTOLOGON_WARN_3RDPARTY) /SD IDYES IDYES install
750	${LogVerbose} "Skipping GINA installation, keeping: $0"
751	goto skip
752	${EndIf}
753	${EndIf}
754
755	install:
756
757	; Do we need VBoxCredProv or VBoxGINA?
758	${If} $R0 == 'Vista' ; Windows Vista.
759	${OrIf} $R0 == '7' ; Windows 7.
760	${OrIf} $R0 == '8' ; Windows 8.
761	; Use VBoxCredProv on Vista and up.
762	${LogVerbose} "Installing VirtualBox credential provider ..."
763	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxCredProv.dll" "$g_strSystemDir\VBoxCredProv.dll" "$INSTDIR"
764	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\Credential Providers\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}" "" "VBoxCredProv" ; adding to (default) key
765	WriteRegStr HKCR "CLSID\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}" "" "VBoxCredProv" ; adding to (Default) key
766	WriteRegStr HKCR "CLSID\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}\InprocServer32" "" "VBoxCredProv.dll" ; adding to (Default) key
767	WriteRegStr HKCR "CLSID\{275D3BCC-22BB-4948-A7F6-3A3054EBA92B}\InprocServer32" "ThreadingModel" "Apartment"
768	${Else} ; Use VBoxGINA on older Windows OSes (< Vista)
769	${LogVerbose} "Installing VirtualBox GINA ..."
770	!insertmacro ReplaceDLL "$%PATH_OUT%\bin\additions\VBoxGINA.dll" "$g_strSystemDir\VBoxGINA.dll" "$INSTDIR"
771	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon" "GinaDLL" "VBoxGINA.dll"
772	; Add Windows notification package callbacks for VBoxGINA
773	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon\Notify\VBoxGINA" "DLLName" "VBoxGINA.dll"
774	WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon\Notify\VBoxGINA" "Impersonate" 0
775	WriteRegStr HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion\WinLogon\Notify\VBoxGINA" "StopScreenSaver" "WnpScreenSaverStop"
776	${EndIf}
777
778	skip:
779
780	; Nothing to do here right now
781
782	exit:
783
784	SectionEnd
785
786	; Prepares the access rights for replacing
787	; a WRP (Windows Resource Protection) protected file
788	Function PrepareWRPFile
789
790	Pop $0
791
792	${IfNot} ${FileExists} "$0"
793	${LogVerbose} "WRP: File $0 does not exist, skipping"
794	Return
795	${EndIf}
796
797	${If} ${FileExists} "$g_strSystemDir\takeown.exe"
798	${CmdExecute} "$\"$g_strSystemDir\takeown.exe$\" /F $\"$0$\"" "true"
799	${Else}
800	${LogVerbose} "WRP: Warning: takeown.exe not found, skipping"
801	${EndIf}
802
803	AccessControl::SetFileOwner "$0" "(S-1-5-32-545)"
804	Pop $1
805	${LogVerbose} "WRP: Setting file owner for $0 returned: $1"
806
807	AccessControl::GrantOnFile "$0" "(S-1-5-32-545)" "FullAccess"
808	Pop $1
809	${LogVerbose} "WRP: Setting access rights for $0 returned: $1"
810
811	!if $%VBOX_WITH_GUEST_INSTALL_HELPER% == "1"
812	!ifdef WFP_FILE_EXCEPTION
813	VBoxGuestInstallHelper::DisableWFP "$0"
814	Pop $1 ; Get return value (ignored for now)
815	${LogVerbose} "WRP: Setting WFP exception for $0 returned: $1"
816	!endif
817	!endif
818
819	FunctionEnd
820
821	; Direct3D support
822	Section /o $(VBOX_COMPONENT_D3D) SEC03
823
824	!if $%VBOX_WITH_WDDM% == "1"
825	${If} $g_bWithWDDM == "true"
826	; All D3D components are installed with WDDM driver package, nothing to be done here
827	Return
828	${EndIf}
829	!endif
830
831	SetOverwrite on
832
833	${If} $g_strSystemDir == ''
834	StrCpy $g_strSystemDir "$SYSDIR"
835	${EndIf}
836
837	SetOutPath $g_strSystemDir
838	${LogVerbose} "Installing Direct3D support ..."
839	FILE "$%PATH_OUT%\bin\additions\VBoxD3D8.dll"
840	FILE "$%PATH_OUT%\bin\additions\VBoxD3D9.dll"
841	FILE "$%PATH_OUT%\bin\additions\wined3d.dll"
842
843	;
844	; Update DLL cache
845	;
846	${If} $g_bCapDllCache == "true"
847	${If} ${FileExists} "$g_strSystemDir\dllcache"
848	SetOutPath "$g_strSystemDir\dllcache"
849	${CopyFileEx} "" "$g_strSystemDir\dllcache\d3d8.dll" "$g_strSystemDir\dllcache\msd3d8.dll" "Microsoft Corporation" "$%BUILD_TARGET_ARCH%"
850	${CopyFileEx} "" "$g_strSystemDir\dllcache\d3d9.dll" "$g_strSystemDir\dllcache\msd3d9.dll" "Microsoft Corporation" "$%BUILD_TARGET_ARCH%"
851
852	Push "$g_strSystemDir\dllcache\d3d8.dll"
853	Call PrepareWRPFile
854
855	Push "$g_strSystemDir\dllcache\d3d9.dll"
856	Call PrepareWRPFile
857
858	; Exchange DLLs
859	${InstallFileEx} "" "$%PATH_OUT%\bin\additions\d3d8.dll" "$g_strSystemDir\dllcache\d3d8.dll" "$TEMP"
860	${InstallFileEx} "" "$%PATH_OUT%\bin\additions\d3d9.dll" "$g_strSystemDir\dllcache\d3d9.dll" "$TEMP"
861	${Else}
862	${LogVerbose} "DLL cache does not exist, skipping"
863	${EndIf}
864	${EndIf}
865
866	;
867	; Save original DLLs (only if msd3d*.dll does not exist) ...
868	;
869	SetOutPath $g_strSystemDir
870	${CopyFileEx} "" "$g_strSystemDir\d3d8.dll" "$g_strSystemDir\msd3d8.dll" "Microsoft Corporation" "$%BUILD_TARGET_ARCH%"
871	${CopyFileEx} "" "$g_strSystemDir\d3d9.dll" "$g_strSystemDir\msd3d9.dll" "Microsoft Corporation" "$%BUILD_TARGET_ARCH%"
872
873	Push "$g_strSystemDir\d3d8.dll"
874	Call PrepareWRPFile
875
876	Push "$g_strSystemDir\d3d9.dll"
877	Call PrepareWRPFile
878
879	; Exchange DLLs
880	${InstallFileEx} "" "$%PATH_OUT%\bin\additions\d3d8.dll" "$g_strSystemDir\d3d8.dll" "$TEMP"
881	${InstallFileEx} "" "$%PATH_OUT%\bin\additions\d3d9.dll" "$g_strSystemDir\d3d9.dll" "$TEMP"
882
883	!if $%BUILD_TARGET_ARCH% == "amd64"
884	; Only 64-bit installer:
885	; Also copy 32-bit DLLs on 64-bit Windows in SysWOW64 node
886	SetOutPath $g_strSysWow64
887	${LogVerbose} "Installing Direct3D support for 32-bit applications (SysWOW64: $g_strSysWow64) ..."
888	FILE "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxD3D8.dll"
889	FILE "$%VBOX_PATH_ADDITIONS_WIN_X86%\VBoxD3D9.dll"
890	FILE "$%VBOX_PATH_ADDITIONS_WIN_X86%\wined3d.dll"
891
892	;
893	; Update DLL cache
894	;
895	${If} $g_bCapDllCache == "true"
896	${If} ${FileExists} "$g_strSysWow64\dllcache"
897	SetOutPath "$g_strSysWow64\dllcache"
898	${CopyFileEx} "" "$g_strSysWow64\dllcache\d3d8.dll" "$g_strSysWow64\dllcache\msd3d8.dll" "Microsoft Corporation" "x86"
899	${CopyFileEx} "" "$g_strSysWow64\dllcache\d3d9.dll" "$g_strSysWow64\dllcache\msd3d9.dll" "Microsoft Corporation" "x86"
900
901	Push "$g_strSysWow64\dllcache\d3d8.dll"
902	Call PrepareWRPFile
903
904	Push "$g_strSysWow64\dllcache\d3d9.dll"
905	Call PrepareWRPFile
906
907	; Exchange DLLs
908	${InstallFileEx} "" "$%VBOX_PATH_ADDITIONS_WIN_X86%\d3d8.dll" "$g_strSysWow64\dllcache\d3d8.dll" "$TEMP"
909	${InstallFileEx} "" "$%VBOX_PATH_ADDITIONS_WIN_X86%\d3d9.dll" "$g_strSysWow64\dllcache\d3d9.dll" "$TEMP"
910	${Else}
911	${LogVerbose} "DLL cache does not exist, skipping"
912	${EndIf}
913	${EndIf}
914
915	;
916	; Update original DLLs
917	;
918
919	; Save original DLLs (only if msd3d*.dll does not exist) ...
920	${CopyFileEx} "" "$g_strSysWow64\d3d8.dll" "$g_strSysWow64\msd3d8.dll" "Microsoft Corporation" "x86"
921	${CopyFileEx} "" "$g_strSysWow64\d3d9.dll" "$g_strSysWow64\msd3d9.dll" "Microsoft Corporation" "x86"
922
923	Push "$g_strSysWow64\d3d8.dll"
924	Call PrepareWRPFile
925
926	Push "$g_strSysWow64\d3d9.dll"
927	Call PrepareWRPFile
928
929	; Exchange DLLs
930	${InstallFileEx} "" "$%VBOX_PATH_ADDITIONS_WIN_X86%\d3d8.dll" "$g_strSysWow64\d3d8.dll" "$TEMP"
931	${InstallFileEx} "" "$%VBOX_PATH_ADDITIONS_WIN_X86%\d3d9.dll" "$g_strSysWow64\d3d9.dll" "$TEMP"
932
933	!endif ; amd64
934	Goto done
935
936	error:
937	; @todo
938	Goto exit
939
940	done:
941
942	!ifndef WFP_FILE_EXCEPTION
943	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_WFP_WARN_REPLACE) /SD IDOK
944	!endif
945	Goto exit
946
947	exit:
948
949	SectionEnd
950
951	!ifdef USE_MUI
952	;Assign language strings to sections
953	!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
954	!insertmacro MUI_DESCRIPTION_TEXT ${SEC01} $(VBOX_COMPONENT_MAIN_DESC)
955	!insertmacro MUI_DESCRIPTION_TEXT ${SEC02} $(VBOX_COMPONENT_AUTOLOGON_DESC)
956	!if $%VBOX_WITH_CROGL% == "1"
957	!insertmacro MUI_DESCRIPTION_TEXT ${SEC03} $(VBOX_COMPONENT_D3D_DESC)
958	!endif
959	!insertmacro MUI_FUNCTION_DESCRIPTION_END
960	!endif ; USE_MUI
961
962	Section -Content
963
964	WriteIniStr "$INSTDIR\${PRODUCT_NAME}.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
965
966	SectionEnd
967
968	Section -StartMenu
969
970	CreateDirectory "$SMPROGRAMS\${PRODUCT_NAME}"
971	CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Website.lnk" "$INSTDIR\${PRODUCT_NAME}.url" "" "$INSTDIR\iexplore.ico"
972	CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Uninstall.lnk" "$INSTDIR\uninst.exe"
973
974	SectionEnd
975
976	; This section is called after all the files are in place
977	Section -Post
978
979	!ifdef _DEBUG
980	${LogVerbose} "Doing post install ..."
981	!endif
982
983	!ifdef EXTERNAL_UNINSTALLER
984	SetOutPath "$INSTDIR"
985	FILE "$%PATH_TARGET%\uninst.exe"
986	!else
987	WriteUninstaller "$INSTDIR\uninst.exe"
988	!endif
989
990	; Write uninstaller in "Add / Remove programs"
991	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
992	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
993	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
994	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
995	WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
996
997	; Tune TcpWindowSize for a better network throughput
998	WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Services\Tcpip\Parameters" "TcpWindowSize" 64240
999
1000	; Add Sun Ray client info keys
1001	; Note: We only need 32-bit keys (HKLM\Software / HKLM\Software\Wow6432Node)
1002	!if $%BUILD_TARGET_ARCH% == "amd64"
1003	WriteRegStr HKLM "SOFTWARE\Wow6432Node\Oracle\Sun Ray\ClientInfoAgent\ReconnectActions" "" ""
1004	WriteRegStr HKLM "SOFTWARE\Wow6432Node\Oracle\Sun Ray\ClientInfoAgent\DisconnectActions" "" ""
1005	!else
1006	WriteRegStr HKLM "SOFTWARE\Oracle\Sun Ray\ClientInfoAgent\ReconnectActions" "" ""
1007	WriteRegStr HKLM "SOFTWARE\Oracle\Sun Ray\ClientInfoAgent\DisconnectActions" "" ""
1008	!endif
1009
1010	${LogVerbose} "Installation completed."
1011
1012	SectionEnd
1013
1014	; !!! NOTE: This function has to be right under the last section; otherwise it does
1015	; not get called! Don't ask me why ... !!!
1016	Function .onSelChange
1017
1018	Push $0
1019
1020	; Handle selection of D3D component
1021	SectionGetFlags ${SEC03} $0
1022	${If} $0 == ${SF_SELECTED}
1023
1024	StrCpy $g_bWithD3D "true"
1025
1026	!if $%VBOX_WITH_WDDM% == "1"
1027	; If we're able to use the WDDM driver just use it instead of the replaced
1028	; D3D components below
1029	${If} $g_bCapWDDM == "true"
1030	;
1031	; Temporary solution: Since WDDM is marked as experimental yet we notify the user
1032	; that WDDM (Aero) support is available but not recommended for production use. He now
1033	; can opt-in for installing WDDM or still go for the old (XPDM) way -- safe mode still required!
1034	;
1035	MessageBox MB_ICONQUESTION\|MB_YESNO $(VBOX_COMPONENT_D3D_OR_WDDM) /SD IDNO IDYES d3d_install
1036	; Display an unconditional hint about needed VRAM sizes
1037	; Note: We also could use the PCI configuration space (WMI: Win32_SystemSlot Class) for querying
1038	; the current VRAM size, but let's keep it simple for now
1039	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_COMPONENT_D3D_HINT_VRAM) /SD IDOK
1040	StrCpy $g_bWithWDDM "true"
1041	Goto exit
1042	${EndIf}
1043
1044	d3d_install:
1045
1046	!endif ; $%VBOX_WITH_WDDM% == "1"
1047
1048	${If} $g_bForceInstall != "true"
1049	; Do not install on < XP
1050	${If} $g_strWinVersion == "NT4"
1051	${OrIf} $g_strWinVersion == "2000"
1052	${OrIf} $g_strWinVersion == ""
1053	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_COMPONENT_D3D_NOT_SUPPORTED) /SD IDOK
1054	Goto d3d_disable
1055	${EndIf}
1056	${EndIf}
1057
1058	; If force flag is set skip the safe mode check
1059	${If} $g_bForceInstall != "true"
1060	; If we're not in safe mode, print a warning and don't install D3D support
1061	${If} $g_iSystemMode == '0'
1062	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_COMPONENT_D3D_NO_SM) /SD IDOK
1063	Goto d3d_disable
1064	${EndIf}
1065	${EndIf}
1066
1067	${Else} ; D3D unselected again
1068
1069	${If} $g_strWinVersion != "8" ; On Windows 8 WDDM is mandatory
1070	StrCpy $g_bWithWDDM "false"
1071	${EndIf}
1072
1073	${EndIf}
1074	Goto exit
1075
1076	d3d_disable:
1077
1078	StrCpy $g_bWithD3D "false"
1079	IntOp $0 $0 & ${SECTION_OFF} ; Unselect section again
1080	SectionSetFlags ${SEC03} $0
1081	Goto exit
1082
1083	exit:
1084
1085	Pop $0
1086
1087	FunctionEnd
1088
1089	; This function is called when a critical error occurred, caused by
1090	; the Abort command
1091	Function .onInstFailed
1092
1093	${LogVerbose} "$(VBOX_ERROR_INST_FAILED)"
1094	MessageBox MB_ICONSTOP $(VBOX_ERROR_INST_FAILED) /SD IDOK
1095
1096	${If} $g_bPostInstallStatus == "true"
1097	${LogToVBoxTray} "2" "Error while installing ${PRODUCT_NAME}!"
1098	${EndIf}
1099
1100	; Set overall exit code
1101	SetErrorLevel 1
1102
1103	FunctionEnd
1104
1105	; This function is called when installation was successful!
1106	Function .onInstSuccess
1107
1108	${LogVerbose} "${PRODUCT_NAME} successfully installed"
1109
1110	${If} $g_bPostInstallStatus == "true"
1111	${LogToVBoxTray} "0" "${PRODUCT_NAME} successfully updated!"
1112	${EndIf}
1113
1114	SetErrorLevel 0
1115
1116	FunctionEnd
1117
1118	; This function is called at the very beginning of installer execution
1119	Function .onInit
1120
1121	Push $0
1122
1123	; Init values
1124	StrCpy $g_iSystemMode "0"
1125	StrCpy $g_strCurUser "<None>"
1126	StrCpy $g_strAddVerMaj "0"
1127	StrCpy $g_strAddVerMin "0"
1128	StrCpy $g_strAddVerBuild "0"
1129	StrCpy $g_strAddVerRev "0"
1130
1131	StrCpy $g_bIgnoreUnknownOpts "false"
1132	StrCpy $g_bLogEnable "false"
1133	StrCpy $g_bFakeWHQL "false"
1134	StrCpy $g_bForceInstall "false"
1135	StrCpy $g_bUninstall "false"
1136	StrCpy $g_bRebootOnExit "false"
1137	StrCpy $g_iScreenX "0"
1138	StrCpy $g_iScreenY "0"
1139	StrCpy $g_iScreenBpp "0"
1140	StrCpy $g_iSfOrder "0"
1141	StrCpy $g_bNoVBoxServiceExit "false"
1142	StrCpy $g_bNoVBoxTrayExit "false"
1143	StrCpy $g_bNoVideoDrv "false"
1144	StrCpy $g_bNoGuestDrv "false"
1145	StrCpy $g_bNoMouseDrv "false"
1146	StrCpy $g_bWithAutoLogon "false"
1147	StrCpy $g_bWithVBoxMMR "false"
1148	StrCpy $g_bWithD3D "false"
1149	StrCpy $g_bOnlyExtract "false"
1150	StrCpy $g_bWithWDDM "false"
1151	StrCpy $g_bCapDllCache "false"
1152	StrCpy $g_bCapWDDM "false"
1153	StrCpy $g_bPostInstallStatus "false"
1154
1155	; We need a special directory set to SysWOW64 because some
1156	; shell operations don't support file redirection (yet)
1157	StrCpy $g_strSysWow64 "$WINDIR\SysWOW64"
1158
1159	SetErrorLevel 0
1160	ClearErrors
1161
1162	!ifdef UNINSTALLER_ONLY
1163
1164	;
1165	; If UNINSTALLER_ONLY is defined, we're only interested in uninst.exe
1166	; so we can sign it
1167	;
1168	; Note that the Quit causes the exit status to be 2 instead of 0
1169	;
1170	WriteUninstaller "$%PATH_TARGET%\uninst.exe"
1171	Quit
1172
1173	!else
1174
1175	; Handle command line
1176	Call HandleCommandLine
1177
1178	; Check if there's already another instance of the installer is running -
1179	; important for preventing NT4 to spawn the installer twice
1180	System::Call 'kernel32::CreateMutexA(i 0, i 0, t "VBoxGuestInstaller") ?e'
1181	Pop $0
1182	${If} $0 != 0
1183	Quit
1184	${EndIf}
1185
1186	; Retrieve Windows version and store result in $g_strWinVersion
1187	Call GetWindowsVersionEx
1188	Pop $g_strWinVersion
1189
1190	; Retrieve capabilities
1191	Call CheckForCapabilities
1192
1193	; Get user Name
1194	AccessControl::GetCurrentUserName
1195	Pop $g_strCurUser
1196	${LogVerbose} "Current user: $g_strCurUser"
1197
1198	; Only extract files? This action can be called even from non-Admin users
1199	; and non-compatible architectures
1200	${If} $g_bOnlyExtract == "true"
1201	Call ExtractFiles
1202	MessageBox MB_OK\|MB_ICONINFORMATION $(VBOX_EXTRACTION_COMPLETE) /SD IDOK
1203	Quit
1204	${EndIf}
1205
1206	; Check for correct architecture
1207	Call CheckArchitecture
1208	Pop $0
1209	${If} $0 <> 0 ; Wrong architecture? Tell the world
1210	!if $%BUILD_TARGET_ARCH% == "amd64"
1211	MessageBox MB_ICONSTOP $(VBOX_NOTICE_ARCH_AMD64) /SD IDOK
1212	!else
1213	MessageBox MB_ICONSTOP $(VBOX_NOTICE_ARCH_X86) /SD IDOK
1214	!endif
1215	Abort "$(VBOX_NOTICE_ARCH_AMD64)"
1216	${EndIf}
1217
1218	; Has the user who calls us admin rights?
1219	UserInfo::GetAccountType
1220	Pop $0
1221	${If} $0 != "Admin"
1222	MessageBox MB_ICONSTOP $(VBOX_NOADMIN) /SD IDOK
1223	Abort
1224	${EndIf}
1225
1226	; Only uninstall?
1227	${If} $g_bUninstall == "true"
1228	Call Uninstall_Innotek
1229	Call Uninstall
1230	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_UNINST_SUCCESS) /SD IDOK
1231	Quit
1232	${EndIf}
1233
1234	Call CheckForInstalledComponents
1235
1236	; Set section bits
1237	${If} $g_bWithAutoLogon == "true" ; Auto-logon support
1238	!insertmacro SelectSection ${SEC02}
1239	${EndIf}
1240	!if $%VBOX_WITH_CROGL% == "1"
1241	${If} $g_bWithD3D == "true" ; D3D support
1242	!insertmacro SelectSection ${SEC03}
1243	${EndIf}
1244	!endif
1245	${If} $g_bWithWDDM == "true" ; D3D / WDDM support
1246	!insertmacro SelectSection ${SEC03}
1247	${EndIf}
1248	; On Windows 8 we always select the 3D section and
1249	; disable it so that it cannot be deselected again
1250	${If} $g_strWinVersion == "8"
1251	IntOp $0 ${SF_SELECTED} \| ${SF_RO}
1252	SectionSetFlags ${SEC03} $0
1253	${EndIf}
1254
1255	!ifdef USE_MUI
1256	; Display language selection dialog (will be hidden in silent mode!)
1257	!ifdef VBOX_INSTALLER_ADD_LANGUAGES
1258	!insertmacro MUI_LANGDLL_DISPLAY
1259	!endif
1260	!endif
1261
1262	Call SetAppMode64
1263
1264	; Check for old additions
1265	Call CheckForOldGuestAdditions
1266	Call GetAdditionsVersion
1267
1268	; Due to some bug in NSIS the license page won't be displayed if we're in
1269	; 64-bit registry view, so as a workaround switch back to 32-bit (Wow6432Node)
1270	; mode for now
1271	Call SetAppMode32
1272
1273	!endif ; UNINSTALLER_ONLY
1274
1275	Pop $0
1276
1277	FunctionEnd
1278
1279	;
1280	; The uninstaller is built separately when doing code signing
1281	; For some reason NSIS still finds the Uninstall section even
1282	; when EXTERNAL_UNINSTALLER is defined. This causes a silly warning
1283	;
1284	!ifndef EXTERNAL_UNINSTALLER
1285
1286	Function un.onUninstSuccess
1287
1288	HideWindow
1289	MessageBox MB_ICONINFORMATION\|MB_OK $(VBOX_UNINST_SUCCESS) /SD IDOK
1290
1291	FunctionEnd
1292
1293	Function un.onInit
1294
1295	; Has the user who calls us admin rights?
1296	UserInfo::GetAccountType
1297	Pop $0
1298	${If} $0 != "Admin"
1299	MessageBox MB_ICONSTOP $(VBOX_NOADMIN) /SD IDOK
1300	Abort
1301	${EndIf}
1302
1303	MessageBox MB_ICONQUESTION\|MB_YESNO\|MB_DEFBUTTON2 $(VBOX_UNINST_CONFIRM) /SD IDYES IDYES proceed
1304	Quit
1305
1306	proceed:
1307
1308	Call un.SetAppMode64
1309
1310	; Set system directory
1311	StrCpy $g_strSystemDir "$SYSDIR"
1312
1313	; We need a special directory set to SysWOW64 because some
1314	; shell operations don't support file redirection (yet)
1315	StrCpy $g_strSysWow64 "$WINDIR\SysWOW64"
1316
1317	; Retrieve Windows version we're running on and store it in $g_strWinVersion
1318	Call un.GetWindowsVersionEx
1319	Pop $g_strWinVersion
1320
1321	; Retrieve capabilities
1322	Call un.CheckForCapabilities
1323
1324	FunctionEnd
1325
1326	Section Uninstall
1327
1328	!ifdef _DEBUG
1329	${LogEnable} "true"
1330	!endif
1331
1332	Call un.SetAppMode64
1333
1334	; Call the uninstall main function
1335	Call un.Uninstall
1336
1337	; ... and remove the local install directory
1338	Call un.UninstallInstDir
1339
1340	!ifndef _DEBUG
1341	SetAutoClose true
1342	MessageBox MB_ICONQUESTION\|MB_YESNO\|MB_DEFBUTTON2 $(VBOX_REBOOT_REQUIRED) /SD IDNO IDYES restart
1343	StrCmp $g_bRebootOnExit "true" restart
1344	!endif
1345
1346	Goto exit
1347
1348	restart:
1349
1350	${LogVerbose} "Rebooting ..."
1351	Reboot
1352
1353	exit:
1354
1355	SectionEnd
1356
1357	; !EXTERNAL_UNINSTALLER
1358	!endif
1359
1360	;Direct the output to our bin dir
1361	!cd "$%PATH_OUT%\bin\additions"

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format