VirtualBox

source: vbox/trunk/configure.vbs@ 96043

Last change on this file since 96043 was 93463, checked in by vboxsync, 3 years ago

configure.vbs: Adapt to using the Windows 11 SDK+WDK, eliminating the legacy Platform SDK prerequisite completely.
  • Property svn:eol-style set to CRLF
  • Property svn:keywords set to Id
File size: 85.4 KB
Line 
1' $Id: configure.vbs 93463 2022-01-27 18:40:49Z vboxsync $
2'' @file
3' The purpose of this script is to check for all external tools, headers, and
4' libraries VBox OSE depends on.
5'
6' The script generates the build configuration file 'AutoConfig.kmk' and the
7' environment setup script 'env.bat'. A log of what has been done is
8' written to 'configure.log'.
9'
10
11'
12' Copyright (C) 2006-2022 Oracle Corporation
13'
14' This file is part of VirtualBox Open Source Edition (OSE), as
15' available from http://www.virtualbox.org. This file is free software;
16' you can redistribute it and/or modify it under the terms of the GNU
17' General Public License (GPL) as published by the Free Software
18' Foundation, in version 2 as it comes in the "COPYING" file of the
19' VirtualBox OSE distribution. VirtualBox OSE is distributed in the
20' hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
21'
22
23
24''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
25' Header Files
26''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
27
28''
29' Includes a vbscript file relative to the script.
30sub IncludeFile(strFilename)
31 dim objFile, objFileSys
32 set objFileSys = WScript.CreateObject("Scripting.FileSystemObject")
33 dim strPath : strPath = objFileSys.BuildPath(objFileSys.GetParentFolderName(Wscript.ScriptFullName), strFilename)
34 set objFile = objFileSys.openTextFile(strPath)
35 executeglobal objFile.readAll()
36 objFile.close
37 set objFileSys = nothing
38end sub
39
40IncludeFile "tools\win\vbscript\helpers.vbs"
41
42
43''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
44' Global Variables '
45''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
46dim g_strPath, g_strEnvFile, g_strLogFile, g_strCfgFile
47g_strPath = Left(Wscript.ScriptFullName, Len(Wscript.ScriptFullName) - Len("\configure.vbs"))
48g_strEnvFile = g_strPath & "\env.bat"
49g_strCfgFile = g_strPath & "\AutoConfig.kmk"
50g_strLogFile = g_strPath & "\configure.log"
51'g_strTmpFile = g_strPath & "\configure.tmp"
52
53
54' kBuild stuff.
55dim g_strPathkBuild, g_strPathkBuildBin, g_strPathDev, g_arrPathDev
56g_strPathkBuild = ""
57g_strPathkBuildBin = ""
58g_strPathDev = ""
59g_arrPathDev = Array(":placeholder:")
60
61dim g_strTargetArch, g_StrTargetArchWin
62g_strTargetArch = ""
63g_StrTargetArchWin = ""
64
65dim g_strHostArch, g_strHostArchWin
66g_strHostArch = ""
67g_strHostArchWin = ""
68
69' Visual C++ info.
70dim g_strPathVCC, g_strVCCVersion
71g_strPathVCC = ""
72g_strVCCVersion = ""
73
74' SDK and DDK.
75dim g_strPathSDK10, g_strPathPSDK, g_strVerPSDK, g_strPathDDK
76g_strPathSDK10 = ""
77g_strPathPSDK = ""
78g_strVerPSDK = ""
79g_strPathDDK = ""
80
81' COM disabling.
82dim g_blnDisableCOM, g_strDisableCOM
83g_blnDisableCOM = False
84g_strDisableCOM = ""
85
86' Whether to try the internal stuff first or last.
87dim g_blnInternalFirst
88g_blnInternalFirst = True
89
90' List of program files locations.
91dim g_arrProgramFiles
92if EnvGet("ProgramFiles(x86)") <> "" then
93 g_arrProgramFiles = Array(EnvGet("ProgramFiles"), EnvGet("ProgramFiles(x86)"))
94else
95 g_arrProgramFiles = Array(EnvGet("ProgramFiles"))
96end if
97
98
99
100''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
101' Helpers: Logging and Logged operations '
102''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
103
104''
105' Write a log header with some basic info.
106sub LogInit
107 FileDelete g_strLogFile
108 LogPrint "# Log file generated by " & Wscript.ScriptFullName
109 for i = 1 to WScript.Arguments.Count
110 LogPrint "# Arg #" & i & ": " & WScript.Arguments.Item(i - 1)
111 next
112 if Wscript.Arguments.Count = 0 then
113 LogPrint "# No arguments given"
114 end if
115 LogPrint "# Reconstructed command line: " & GetCommandline()
116
117 ' some Wscript stuff
118 LogPrint "# Wscript properties:"
119 LogPrint "# ScriptName: " & Wscript.ScriptName
120 LogPrint "# Version: " & Wscript.Version
121 LogPrint "# Build: " & Wscript.BuildVersion
122 LogPrint "# Name: " & Wscript.Name
123 LogPrint "# Full Name: " & Wscript.FullName
124 LogPrint "# Path: " & Wscript.Path
125 LogPrint "#"
126
127
128 ' the environment
129 LogPrint "# Environment:"
130 dim objEnv
131 for each strVar in g_objShell.Environment("PROCESS")
132 LogPrint "# " & strVar
133 next
134 LogPrint "#"
135end sub
136
137
138''
139' Append text to the log file.
140sub LogPrint(str)
141 FileAppendLine g_strLogFile, str
142 'Wscript.Echo "dbg: " & str
143end sub
144
145''
146' Debug output.
147sub DbgPrint(str)
148 'FileAppendLine g_strLogFile, str
149 'Wscript.Echo "dbg: " & str
150end sub
151
152
153''
154' Checks if the file exists and logs failures.
155function LogFileExists(strPath, strFilename)
156 LogFileExists = FileExists(strPath & "/" & strFilename)
157 if LogFileExists = False then
158 LogPrint "Testing '" & strPath & "': " & strFilename & " not found"
159 end if
160end function
161
162
163''
164' Checks if the file exists and logs failures.
165function LogFileExists1(strPath)
166 LogFileExists1 = FileExists(strPath)
167 if LogFileExists1 = False then
168 LogPrint "Testing '" & strPath & "': file not found"
169 end if
170end function
171
172
173''
174' Checks if the directory exists and logs failures.
175function LogDirExists(strPath)
176 LogDirExists = DirExists(strPath)
177 if LogDirExists = False then
178 LogPrint "Testing '" & strPath & "': not found (or not dir)"
179 end if
180end function
181
182
183''
184' Finds the first file matching the pattern.
185' If no file is found, log the failure.
186function LogFindFile(strPath, strPattern)
187 dim str, strOutput
188
189 '
190 ' Yes, there are some facy database kinda interface to the filesystem
191 ' however, breaking down the path and constructing a usable query is
192 ' too much hassle. So, we'll do it the unix way...
193 '
194 if Shell("dir /B """ & DosSlashes(strPath) & "\" & DosSlashes(strPattern) & """", True, strOutput) = 0 _
195 And InStr(1, strOutput, Chr(13)) > 1 _
196 then
197 ' return the first word.
198 LogFindFile = Left(strOutput, InStr(1, strOutput, Chr(13)) - 1)
199 else
200 LogPrint "Testing '" & strPath & "': " & strPattern & " not found"
201 LogFindFile = ""
202 end if
203end function
204
205
206''
207' Finds the first directory matching the pattern.
208' If no directory is found, log the failure,
209' else return the complete path to the found directory.
210function LogFindDir(strPath, strPattern)
211 dim str, strOutput
212
213 '
214 ' Yes, there are some facy database kinda interface to the filesystem
215 ' however, breaking down the path and constructing a usable query is
216 ' too much hassle. So, we'll do it the unix way...
217 '
218
219 ' List the alphabetically last names as first entries (with /O-N).
220 if Shell("dir /B /AD /O-N """ & DosSlashes(strPath) & "\" & DosSlashes(strPattern) & """", True, strOutput) = 0 _
221 And InStr(1, strOutput, Chr(13)) > 1 _
222 then
223 ' return the first word.
224 LogFindDir = strPath & "/" & Left(strOutput, InStr(1, strOutput, Chr(13)) - 1)
225 else
226 LogPrint "Testing '" & strPath & "': " & strPattern & " not found"
227 LogFindDir = ""
228 end if
229end function
230
231
232''
233' Wrapper around RegGetString that logs successes.
234function LogRegGetString(strName)
235 LogRegGetString = RegGetString(strName)
236 if LogRegGetString <> "" then LogPrint "RegGetString(" & strName & ") -> " & LogRegGetString
237end function
238
239
240''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
241' Helpers: Configuration and Batch Script Writers '
242''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
243
244''
245' Initializes the config file.
246sub CfgInit
247 FileDelete g_strCfgFile
248 CfgPrint "# -*- Makefile -*-"
249 CfgPrint "#"
250 CfgPrint "# Build configuration generated by " & GetCommandline()
251 CfgPrint "#"
252 CfgPrintAssign "VBOX_OSE", "1"
253 CfgPrintAssignRecursive "VBOX_VCC_WERR", "$(NO_SUCH_VARIABLE)"
254end sub
255
256
257''
258' Prints a string to the config file.
259sub CfgPrint(str)
260 FileAppendLine g_strCfgFile, str
261end sub
262
263''
264' Prints a simple assignment to the config file.
265sub CfgPrintAssign(strVar, strValue)
266 if strValue = "" then
267 FileAppendLine g_strCfgFile, RightPad(strVar, 23) & " :="
268 else
269 FileAppendLine g_strCfgFile, RightPad(strVar, 23) & " := " & strValue
270 end if
271end sub
272
273''
274' Prints a recursive assignment to the config file.
275sub CfgPrintAssignRecursive(strVar, strValue)
276 FileAppendLine g_strCfgFile, RightPad(strVar, 23) & " = " & strValue
277end sub
278
279
280''
281' Initializes the environment batch script.
282sub EnvInit
283 FileDelete g_strEnvFile
284 EnvPrint "@echo off"
285 EnvPrint "rem"
286 EnvPrint "rem Environment setup script generated by " & GetCommandline()
287 EnvPrint "rem"
288end sub
289
290
291''
292' Prints a string to the environment batch script.
293sub EnvPrint(str)
294 FileAppendLine g_strEnvFile, str
295end sub
296
297
298''
299' Helper for EnvPrintPrepend and EnvPrintAppend.
300sub EnvPrintCleanup(strEnv, strValue, strSep)
301 dim cchValueAndSep
302 FileAppendLine g_strEnvFile, "set " & strEnv & "=%" & strEnv & ":" & strSep & strValue & strSep & "=" & strSep & "%"
303 cchValueAndSep = Len(strValue) + Len(strSep)
304 FileAppendLine g_strEnvFile, "if ""%" & strEnv & "%""==""" & strValue & """ set " & strEnv & "="
305 FileAppendLine g_strEnvFile, "if ""%" & strEnv & ":~0," & cchValueAndSep & "%""==""" & strValue & strSep & """ set " & strEnv & "=%" & strEnv & ":~" & cchValueAndSep & "%"
306 FileAppendLine g_strEnvFile, "if ""%" & strEnv & ":~-" & cchValueAndSep & "%""==""" & strSep & strValue & """ set " & strEnv & "=%" & strEnv & ":~0,-" & cchValueAndSep & "%"
307end sub
308
309
310'' Use by EnvPrintPrepend to skip ';' stripping.
311dim g_strPrependCleanEnvVars
312
313''
314' Print a statement prepending strValue to strEnv, removing duplicate values.
315sub EnvPrintPrepend(strEnv, strValue, strSep)
316 ' Remove old values and any leading separators.
317 EnvPrintCleanup strEnv, strValue, strSep
318 if InStr(1, g_strPrependCleanEnvVars, "|" & strEnv & "|") = 0 then
319 FileAppendLine g_strEnvFile, "if ""%" & strEnv & ":~0,1%""==""" & strSep & """ set " & strEnv & "=%" & strEnv & ":~1%"
320 FileAppendLine g_strEnvFile, "if ""%" & strEnv & ":~0,1%""==""" & strSep & """ set " & strEnv & "=%" & strEnv & ":~1%"
321 g_strPrependCleanEnvVars = g_strPrependCleanEnvVars & "|" & strEnv & "|"
322 end if
323 ' Do the setting
324 FileAppendLine g_strEnvFile, "set " & strEnv & "=" & strValue & strSep & "%" & strEnv & "%"
325end sub
326
327
328'' Use by EnvPrintPrepend to skip ';' stripping.
329dim g_strAppendCleanEnvVars
330
331''
332' Print a statement appending strValue to strEnv, removing duplicate values.
333sub EnvPrintAppend(strEnv, strValue, strSep)
334 ' Remove old values and any trailing separators.
335 EnvPrintCleanup strEnv, strValue, strSep
336 if InStr(1, g_strAppendCleanEnvVars, "|" & strEnv & "|") = 0 then
337 FileAppendLine g_strEnvFile, "if ""%" & strEnv & ":~-1%""==""" & strSep & """ set " & strEnv & "=%" & strEnv & ":~0,-1%"
338 FileAppendLine g_strEnvFile, "if ""%" & strEnv & ":~-1%""==""" & strSep & """ set " & strEnv & "=%" & strEnv & ":~0,-1%"
339 g_strAppendCleanEnvVars = g_strAppendCleanEnvVars & "|" & strEnv & "|"
340 end if
341 ' Do the setting.
342 FileAppendLine g_strEnvFile, "set " & strEnv & "=%" & strEnv & "%" & strSep & strValue
343end sub
344
345
346''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
347' Feature disabling '
348''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
349
350''
351' No COM
352sub DisableCOM(strReason)
353 if g_blnDisableCOM = False then
354 LogPrint "Disabled COM components: " & strReason
355 g_blnDisableCOM = True
356 g_strDisableCOM = strReason
357 CfgPrintAssign "VBOX_WITH_MAIN", ""
358 CfgPrintAssign "VBOX_WITH_QTGUI", ""
359 CfgPrintAssign "VBOX_WITH_VBOXSDL", ""
360 CfgPrintAssign "VBOX_WITH_DEBUGGER_GUI", ""
361 end if
362end sub
363
364
365''
366' No UDPTunnel
367sub DisableUDPTunnel(strReason)
368 if g_blnDisableUDPTunnel = False then
369 LogPrint "Disabled UDPTunnel network transport: " & strReason
370 g_blnDisableUDPTunnel = True
371 g_strDisableUDPTunnel = strReason
372 CfgPrintAssign "VBOX_WITH_UDPTUNNEL", ""
373 end if
374end sub
375
376
377''
378' No SDL
379sub DisableSDL(strReason)
380 if g_blnDisableSDL = False then
381 LogPrint "Disabled SDL frontend: " & strReason
382 g_blnDisableSDL = True
383 g_strDisableSDL = strReason
384 CfgPrintAssign "VBOX_WITH_VBOXSDL", ""
385 end if
386end sub
387
388
389''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
390' Tool/Library Locating and Checking '
391''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
392
393''
394' Generic helper for looking for a tools under g_strPathDev.
395'
396' The callback function takes the '.../tools/win.arch/tool/version' dir and
397' varUser as arguments, returning an non-empty string if it was found suitable.
398'
399function SearchToolsEx(strTool, strVerPrefix, ByRef fnCallback, ByRef varUser, ByRef arrToolsDirs)
400 dim strToolsDir, arrDirs, strDir
401 SearchToolsEx = ""
402 for each strToolsDir in arrToolsDirs
403 arrDirs = GetSubdirsStartingWithRVerSorted(strToolsDir, strVerPrefix)
404 for each strDir in arrDirs
405 SearchToolsEx = fnCallback(strToolsDir & "/" & strDir, varUser)
406 if SearchToolsEx <> "" then
407 exit function
408 end if
409 next
410 next
411end function
412
413'' Search under g_strPathDev for a tool, target arch only.
414function SearchTargetTools(strTool, strVerPrefix, ByRef fnCallback, ByRef varUser)
415 dim i
416 redim arrToolsDirs(ArraySize(g_arrPathDev) - 1)
417 for i = 0 to UBound(g_arrPathDev)
418 arrToolsDirs(i) = g_arrPathDev(i) & "/win." & g_strTargetArch & "/" & strTool
419 next
420 SearchTargetTools = SearchToolsEx(strTool, strVerPrefix, fnCallback, varUser, arrToolsDirs)
421end function
422
423'' Search under g_strPathDev for a tool, target arch and alternative arches.
424function SearchTargetPlusTools(strTool, strVerPrefix, ByRef fnCallback, ByRef varUser)
425 dim i
426 redim arrToolsDirs(ArraySize(g_arrPathDev)*3 - 1)
427 for i = 0 to UBound(g_arrPathDev)
428 arrToolsDirs(i*3 + 0) = g_arrPathDev(i) & "/win." & g_strTargetArch & "/" & strTool
429 arrToolsDirs(i*3 + 1) = g_arrPathDev(i) & "/win.x86/" & strTool
430 arrToolsDirs(i*3 + 2) = g_arrPathDev(i) & "/win.amd64/" & strTool
431 next
432 SearchTargetPlusTools = SearchToolsEx(strTool, strVerPrefix, fnCallback, varUser, arrToolsDirs)
433end function
434
435'' Search under g_strPathDev for a tool, host arch first.
436function SearchHostTools(strTool, strVerPrefix, ByRef fnCallback, ByRef varUser)
437 dim i
438 redim arrToolsDirs(ArraySize(g_arrPathDev) * 3 - 1)
439 for i = 0 to UBound(g_arrPathDev)
440 arrToolsDirs(i*3 + 0) = g_arrPathDev(i) & "/win." & g_strHostArch & "/" & strTool
441 arrToolsDirs(i*3 + 1) = g_arrPathDev(i) & "/win.x86/" & strTool
442 arrToolsDirs(i*3 + 2) = g_arrPathDev(i) & "/win.amd64/" & strTool
443 next
444 SearchHostTools = SearchToolsEx(strTool, strVerPrefix, fnCallback, varUser, arrToolsDirs)
445end function
446
447'' Search under g_strPathDev for a tool, common dir first.
448function SearchCommonTools(strTool, strVerPrefix, ByRef fnCallback, ByRef varUser)
449 dim i
450 redim arrToolsDirs(ArraySize(g_arrPathDev) * 4 - 1)
451 for i = 0 to UBound(g_arrPathDev)
452 arrToolsDirs(i*4 + 0) = g_arrPathDev(i) & "/win.common/" & strTool
453 arrToolsDirs(i*4 + 1) = g_arrPathDev(i) & "/win." & g_strTargetArch & "/" & strTool
454 arrToolsDirs(i*4 + 2) = g_arrPathDev(i) & "/win.x86/" & strTool
455 arrToolsDirs(i*4 + 3) = g_arrPathDev(i) & "/win.amd64/" & strTool
456 next
457 SearchCommonTools = SearchToolsEx(strTool, strVerPrefix, fnCallback, varUser, arrToolsDirs)
458end function
459
460''
461' Checks the the path doesn't contain characters the tools cannot deal with.
462'
463sub CheckSourcePath
464 dim sPwd
465
466 sPwd = PathAbsLong(g_strPath) ' Must check the long version.
467 if InStr(1, sPwd, " ") > 0 then
468 MsgError "Source path contains spaces! Please move it. (" & sPwd & ")"
469 end if
470 if InStr(1, sPwd, "$") > 0 then
471 MsgError "Source path contains the '$' char! Please move it. (" & sPwd & ")"
472 end if
473 if InStr(1, sPwd, "%") > 0 then
474 MsgError "Source path contains the '%' char! Please move it. (" & sPwd & ")"
475 end if
476 if InStr(1, sPwd, Chr(10)) > 0 _
477 or InStr(1, sPwd, Chr(13)) > 0 _
478 or InStr(1, sPwd, Chr(9)) > 0 _
479 then
480 MsgError "Source path contains control characters! Please move it. (" & sPwd & ")"
481 end if
482 Print "Source path: OK"
483end sub
484
485
486''
487' Checks for kBuild - very simple :)
488'
489sub CheckForkBuild(strOptkBuild)
490 dim blnNeedEnvVars, strOutput
491 PrintHdr "kBuild"
492
493 '
494 ' Check if there is a 'kmk' in the path somewhere without
495 ' any KBUILD_*PATH stuff around.
496 '
497 blnNeedEnvVars = True
498 g_strPathkBuild = strOptkBuild
499 g_strPathkBuildBin = ""
500 if (g_strPathkBuild = "") _
501 And (EnvGetFirst("KBUILD_PATH", "PATH_KBUILD") = "") _
502 And (EnvGetFirst("KBUILD_BIN_PATH", "PATH_KBUILD_BIN") = "") _
503 And (Shell("kmk.exe --version", True, strOutput) = 0) _
504 And (InStr(1,strOutput, "kBuild Make 0.1") > 0) _
505 And (InStr(1,strOutput, "KBUILD_PATH") > 0) _
506 And (InStr(1,strOutput, "KBUILD_BIN_PATH") > 0) then
507 '' @todo Need to parse out the KBUILD_PATH and KBUILD_BIN_PATH values to complete the other tests.
508 'blnNeedEnvVars = False
509 MsgWarning "You've installed kBuild it seems. configure.vbs hasn't been updated to " _
510 & "deal with that yet and will use the one it ships with. Sorry."
511 end if
512
513 '
514 ' Check for the KBUILD_PATH env.var. and fall back on root/kBuild otherwise.
515 '
516 if g_strPathkBuild = "" then
517 g_strPathkBuild = EnvGetFirst("KBUILD_PATH", "PATH_KBUILD")
518 if (g_strPathkBuild <> "") and (FileExists(g_strPathkBuild & "/footer.kmk") = False) then
519 MsgWarning "Ignoring incorrect kBuild path (KBUILD_PATH=" & g_strPathkBuild & ")"
520 g_strPathkBuild = ""
521 end if
522
523 if g_strPathkBuild = "" then
524 g_strPathkBuild = g_strPath & "/kBuild"
525 end if
526 end if
527
528 g_strPathkBuild = UnixSlashes(PathAbs(g_strPathkBuild))
529
530 '
531 ' Check for env.vars that kBuild uses (do this early to set g_strTargetArch).
532 '
533 str = EnvGetFirst("KBUILD_TYPE", "BUILD_TYPE")
534 if (str <> "") _
535 And (InStr(1, "|release|debug|profile|kprofile", str) <= 0) then
536 EnvPrint "set KBUILD_TYPE=release"
537 EnvSet "KBUILD_TYPE", "release"
538 MsgWarning "Found unknown KBUILD_TYPE value '" & str &"' in your environment. Setting it to 'release'."
539 end if
540
541 str = EnvGetFirst("KBUILD_TARGET", "BUILD_TARGET")
542 if (str <> "") _
543 And (InStr(1, "win|win32|win64", str) <= 0) then '' @todo later only 'win' will be valid. remember to fix this check!
544 EnvPrint "set KBUILD_TARGET=win"
545 EnvSet "KBUILD_TARGET", "win"
546 MsgWarning "Found unknown KBUILD_TARGET value '" & str &"' in your environment. Setting it to 'win32'."
547 end if
548
549 str = EnvGetFirst("KBUILD_TARGET_ARCH", "BUILD_TARGET_ARCH")
550 if (str <> "") _
551 And (InStr(1, "x86|amd64", str) <= 0) then
552 EnvPrint "set KBUILD_TARGET_ARCH=x86"
553 EnvSet "KBUILD_TARGET_ARCH", "x86"
554 MsgWarning "Found unknown KBUILD_TARGET_ARCH value '" & str &"' in your environment. Setting it to 'x86'."
555 str = "x86"
556 end if
557 if g_strTargetArch = "" then '' command line parameter --target-arch=x86|amd64 has priority
558 if str <> "" then
559 g_strTargetArch = str
560 elseif (EnvGet("PROCESSOR_ARCHITEW6432") = "AMD64" ) _
561 Or (EnvGet("PROCESSOR_ARCHITECTURE") = "AMD64" ) then
562 g_strTargetArch = "amd64"
563 else
564 g_strTargetArch = "x86"
565 end if
566 else
567 if InStr(1, "x86|amd64", g_strTargetArch) <= 0 then
568 EnvPrint "set KBUILD_TARGET_ARCH=x86"
569 EnvSet "KBUILD_TARGET_ARCH", "x86"
570 MsgWarning "Unknown --target-arch=" & str &". Setting it to 'x86'."
571 end if
572 end if
573 LogPrint " Target architecture: " & g_strTargetArch & "."
574 Wscript.Echo " Target architecture: " & g_strTargetArch & "."
575 EnvPrint "set KBUILD_TARGET_ARCH=" & g_strTargetArch
576
577 ' Windows variant of the arch name.
578 g_strTargetArchWin = g_strTargetArch
579 if g_strTargetArchWin = "amd64" then g_strTargetArchWin = "x64"
580
581 str = EnvGetFirst("KBUILD_TARGET_CPU", "BUILD_TARGET_CPU")
582 ' perhaps a bit pedantic this since this isn't clearly define nor used much...
583 if (str <> "") _
584 And (InStr(1, "i386|i486|i686|i786|i868|k5|k6|k7|k8", str) <= 0) then
585 EnvPrint "set BUILD_TARGET_CPU=i386"
586 EnvSet "KBUILD_TARGET_CPU", "i386"
587 MsgWarning "Found unknown KBUILD_TARGET_CPU value '" & str &"' in your environment. Setting it to 'i386'."
588 end if
589
590 str = EnvGetFirst("KBUILD_HOST", "BUILD_PLATFORM")
591 if (str <> "") _
592 And (InStr(1, "win|win32|win64", str) <= 0) then '' @todo later only 'win' will be valid. remember to fix this check!
593 EnvPrint "set KBUILD_HOST=win"
594 EnvSet "KBUILD_HOST", "win"
595 MsgWarning "Found unknown KBUILD_HOST value '" & str &"' in your environment. Setting it to 'win32'."
596 end if
597
598 str = EnvGetFirst("KBUILD_HOST_ARCH", "BUILD_PLATFORM_ARCH")
599 if str <> "" then
600 if InStr(1, "x86|amd64", str) <= 0 then
601 str = "x86"
602 MsgWarning "Found unknown KBUILD_HOST_ARCH value '" & str &"' in your environment. Setting it to 'x86'."
603 end if
604 elseif (EnvGet("PROCESSOR_ARCHITEW6432") = "AMD64" ) _
605 Or (EnvGet("PROCESSOR_ARCHITECTURE") = "AMD64" ) then
606 str = "amd64"
607 else
608 str = "x86"
609 end if
610 LogPrint " Host architecture: " & str & "."
611 Wscript.Echo " Host architecture: " & str & "."
612 EnvPrint "set KBUILD_HOST_ARCH=" & str
613 g_strHostArch = str
614
615 ' Windows variant of the arch name.
616 g_strHostArchWin = g_strHostArch
617 if g_strHostArchWin = "amd64" then g_strHostArchWin = "x64"
618
619
620 str = EnvGetFirst("KBUILD_HOST_CPU", "BUILD_PLATFORM_CPU")
621 ' perhaps a bit pedantic this since this isn't clearly define nor used much...
622 if (str <> "") _
623 And (InStr(1, "i386|i486|i686|i786|i868|k5|k6|k7|k8", str) <= 0) then
624 EnvPrint "set KBUILD_HOST_CPU=i386"
625 EnvSet "KBUILD_HOST_CPU", "i386"
626 MsgWarning "Found unknown KBUILD_HOST_CPU value '" & str &"' in your environment. Setting it to 'i386'."
627 end if
628
629 '
630 ' Determin the location of the kBuild binaries.
631 '
632 if g_strPathkBuildBin = "" then
633 g_strPathkBuildBin = g_strPathkBuild & "/bin/win." & g_strHostArch
634 if FileExists(g_strPathkBuildBin & "/kmk.exe") = False then
635 g_strPathkBuildBin = g_strPathkBuild & "/bin/win.x86"
636 end if
637 end if
638 g_strPathkBuildBin = UnixSlashes(PathAbs(g_strPathkBuildBin))
639
640 '
641 ' Perform basic validations of the kBuild installation.
642 '
643 if (FileExists(g_strPathkBuild & "/footer.kmk") = False) _
644 Or (FileExists(g_strPathkBuild & "/header.kmk") = False) _
645 Or (FileExists(g_strPathkBuild & "/rules.kmk") = False) then
646 MsgFatal "Can't find valid kBuild at '" & g_strPathkBuild & "'. Either there is an " _
647 & "incorrect KBUILD_PATH in the environment or the checkout didn't succeed."
648 exit sub
649 end if
650 if (FileExists(g_strPathkBuildBin & "/kmk.exe") = False) _
651 Or (FileExists(g_strPathkBuildBin & "/kmk_ash.exe") = False) then
652 MsgFatal "Can't find valid kBuild binaries at '" & g_strPathkBuildBin & "'. Either there is an " _
653 & "incorrect KBUILD_PATH in the environment or the checkout didn't succeed."
654 exit sub
655 end if
656
657 if (Shell(DosSlashes(g_strPathkBuildBin & "/kmk.exe") & " --version", True, strOutput) <> 0) then
658 MsgFatal "Can't execute '" & g_strPathkBuildBin & "/kmk.exe --version'. check configure.log for the out."
659 exit sub
660 end if
661
662 '
663 ' If KBUILD_DEVTOOLS is set, check that it's pointing to something useful.
664 '
665 str = UnixSlashes(EnvGet("KBUILD_DEVTOOLS"))
666 g_strPathDev = str
667 if str <> "" _
668 and LogDirExists(str & "/bin") _
669 and LogDirExists(str & "/win.amd64/bin") _
670 and LogDirExists(str & "/win.x86/bin") _
671 then
672 LogPrint "Found KBUILD_DEVTOOLS='" & str & "'."
673 elseif str <> "" then
674 MsgWarning "Ignoring bogus KBUILD_DEVTOOLS='" & str &"' in your environment!"
675 g_strPathDev = strNew
676 end if
677 if g_strPathDev = "" then
678 g_strPathDev = UnixSlashes(g_strPath & "/tools")
679 LogPrint "Using KBUILD_DEVTOOLS='" & g_strPathDev & "'."
680 if str <> "" then
681 EnvPrint "set KBUILD_DEVTOOLS=" & g_strPathDev
682 EnvSet "KBUILD_DEVTOOLS", g_strPathDev
683 end if
684 end if
685 g_arrPathDev(ArrayFindString(g_arrPathDev, ":placeholder:")) = g_strPathDev
686
687 '
688 ' Write KBUILD_PATH and updated PATH to the environment script if necessary.
689 '
690 if blnNeedEnvVars = True then
691 EnvPrint "set KBUILD_PATH=" & g_strPathkBuild
692 EnvSet "KBUILD_PATH", g_strPathkBuild
693
694 if Right(g_strPathkBuildBin, 7) = "win.x86" then
695 EnvPrintCleanup "PATH", DosSlashes(Left(g_strPathkBuildBin, Len(g_strPathkBuildBin) - 7) & "win.amd64"), ";"
696 end if
697 if Right(g_strPathkBuildBin, 9) = "win.amd64" then
698 EnvPrintCleanup "PATH", DosSlashes(Left(g_strPathkBuildBin, Len(g_strPathkBuildBin) - 9) & "win.x86"), ";"
699 end if
700 EnvPrintPrepend "PATH", DosSlashes(g_strPathkBuildBin), ";"
701 EnvPrependPathItem "PATH", g_strPathkBuildBin, ";"
702 end if
703
704 PrintResult "kBuild", g_strPathkBuild
705 PrintResult "kBuild binaries", g_strPathkBuildBin
706end sub
707
708
709''
710' Checks for Visual C++ version 16 (2019), 15 (2017), 14 (2015), 12 (2013), 11 (2012) or 10 (2010).
711'
712sub CheckForVisualCPP(strOptVC, strOptVCCommon)
713 PrintHdr "Visual C++"
714
715 '
716 ' Try find it...
717 '
718 dim objState, strProgFiles
719 set objState = new VisualCPPState
720 objState.check strOptVC, strOptVCCommon
721 if g_blnInternalFirst = True then objState.checkInternal
722 objState.checkProgItems "2019"
723 objState.checkProgFiles "Microsoft Visual Studio\2019\BuildTools\VC"
724 objState.checkProgFiles "Microsoft Visual Studio\2019\Professional\VC"
725 objState.checkProgFiles "Microsoft Visual Studio\2019\Community\VC"
726 objState.checkRegistry "Microsoft\VisualStudio\SxS\VS7\16.0", "VC", "" ' doesn't work.
727 objState.checkProgItems "2017"
728 objState.checkProgFiles "Microsoft Visual Studio\2017\BuildTools\VC"
729 objState.checkProgFiles "Microsoft Visual Studio\2017\Professional\VC"
730 objState.checkProgFiles "Microsoft Visual Studio\2017\Community\VC"
731 objState.checkProgFiles "Microsoft Visual Studio\2017\Express\VC"
732 objState.checkRegistry "Microsoft\VisualStudio\SxS\VS7\15.0", "VC", ""
733 objState.checkRegistry "Microsoft\VisualStudio\SxS\VS7\14.0", "VC", "Common7"
734 objState.checkRegistry "Microsoft\VisualStudio\SxS\VS7\12.0", "VC", "Common7" '?
735 objState.checkRegistry "Microsoft\VisualStudio\SxS\VS7\11.0", "VC", "Common7" '?
736 objState.checkProg "cl.exe"
737 objState.checkRegistry "Microsoft\VisualStudio\10.0\Setup\VS\ProductDir", "VC", "Common7"
738 if g_blnInternalFirst = False then objState.checkInternal
739
740 if objState.m_blnFound = False then
741 MsgError "Cannot find cl.exe (Visual C++) anywhere on your system. Check the build requirements."
742 exit sub
743 end if
744 g_strPathVCC = objState.m_strPathVC
745 g_strVCCVersion = objState.m_strVersion
746
747 '
748 ' Ok, emit build config variables.
749 '
750 CfgPrintAssign "VBOX_VCC_TOOL_STEM", objState.m_strVersion
751 CfgPrintAssign "PATH_TOOL_" & objState.m_strVersion, g_strPathVCC
752 CfgPrintAssign "PATH_TOOL_" & objState.m_strVersion & "X86", "$(PATH_TOOL_" & objState.m_strVersion & ")"
753 CfgPrintAssign "PATH_TOOL_" & objState.m_strVersion & "AMD64", "$(PATH_TOOL_" & objState.m_strVersion & ")"
754
755 if objState.m_strVersion = "VCC100" _
756 or objState.m_strVersion = "VCC110" _
757 or objState.m_strVersion = "VCC120" _
758 or objState.m_strVersion = "VCC140" _
759 then
760 CfgPrintAssign "VBOX_WITH_NEW_VCC", "" '?? for VCC110+
761 else
762 CfgPrintAssign "VBOX_WITH_NEW_VCC", "1"
763 end if
764 PrintResult "Visual C++ " & objState.m_strVersion, g_strPathVCC
765
766 ' And the env.bat path fix.
767 if objState.m_strPathVCCommon <> "" then
768 EnvPrintAppend "PATH", DosSlashes(objState.m_strPathVCCommon) & "\IDE", ";"
769 end if
770end sub
771
772'' Class we use for detecting Visual C++
773class VisualCPPState
774 public m_blnFound
775 public m_strPathVC
776 public m_strPathVCCommon
777 public m_strVersion
778 public m_strClVersion
779 public m_blnNewLayout
780
781 private sub Class_Initialize
782 m_blnFound = False
783 m_strPathVC = ""
784 m_strPathVCCommon = ""
785 m_strVersion = ""
786 m_strClVersion = ""
787 m_blnNewLayout = false
788 end sub
789
790 public function checkClExe(strClExe)
791 ' We'll have to make sure mspdbXX.dll is somewhere in the PATH.
792 dim strSavedPath, rcExit, strOutput
793
794 strSavedPath = EnvGet("PATH")
795 if (m_strPathVCCommon <> "") then
796 EnvAppendPathItem "PATH", m_strPathVCCommon & "/IDE", ";"
797 end if
798 rcExit = Shell(DosSlashes(strClExe), True, strOutput)
799 EnvSet "PATH", strSavedPath
800
801 checkClExe = False
802 if rcExit = 0 then
803 ' Extract the ' Version xx.yy.build.zz for arch' bit.
804 dim offVer, offEol, strVer
805 strVer = ""
806 offVer = InStr(1, strOutput, " Version ")
807 if offVer > 0 then
808 offVer = offVer + Len(" Version ")
809 offEol = InStr(offVer, strOutput, Chr(13))
810 if offEol > 0 then
811 strVer = Trim(Mid(strOutput, offVer, offEol - offVer))
812 end if
813 end if
814
815 ' Check that it's a supported version
816 checkClExe = True
817 if InStr(1, strVer, "16.") = 1 then
818 m_strVersion = "VCC100"
819 elseif InStr(1, strVer, "17.") = 1 then
820 m_strVersion = "VCC110"
821 LogPrint "The Visual C++ compiler ('" & strClExe & "') version isn't really supported, but may work: " & strVer
822 elseif InStr(1, strVer, "18.") = 1 then
823 m_strVersion = "VCC120"
824 LogPrint "The Visual C++ compiler ('" & strClExe & "') version isn't really supported, but may work: " & strVer
825 elseif InStr(1, strVer, "19.0") = 1 then
826 m_strVersion = "VCC140"
827 LogPrint "The Visual C++ compiler ('" & strClExe & "') version isn't really supported, but may work: " & strVer
828 elseif InStr(1, strVer, "19.1") = 1 then
829 m_strVersion = "VCC141"
830 LogPrint "The Visual C++ compiler ('" & strClExe & "') version isn't really supported, but may work: " & strVer
831 elseif InStr(1, strVer, "19.2") = 1 then
832 m_strVersion = "VCC142"
833 else
834 LogPrint "The Visual C++ compiler we found ('" & strClExe & "') isn't in the 10.0-19.2x range (" & strVer & ")."
835 LogPrint "Check the build requirements and select the appropriate compiler version."
836 checkClExe = False
837 exit function
838 end if
839 LogPrint "'" & strClExe & "' = " & m_strVersion & " (" & strVer & ")"
840 else
841 LogPrint "Executing '" & strClExe & "' (which we believe to be the Visual C++ compiler driver) failed (rcExit=" & rcExit & ")."
842 end if
843 end function
844
845 public function checkInner(strPathVC) ' For the new layout only
846 if m_blnFound = False then
847 if LogDirExists(strPathVC & "/bin") _
848 and LogDirExists(strPathVC & "/lib") _
849 and LogDirExists(strPathVC & "/include") _
850 and LogFileExists(strPathVC, "include/stdarg.h") _
851 and LogFileExists(strPathVC, "lib/x64/libcpmt.lib") _
852 and LogFileExists(strPathVC, "lib/x86/libcpmt.lib") _
853 and LogFileExists(strPathVC, "bin/Host" & g_strHostArchWin & "/" & g_strTargetArchWin & "/cl.exe") _
854 and LogFileExists(strPathVC, "bin/Host" & g_strHostArchWin & "/" & g_strHostArchWin & "/cl.exe") _
855 then
856 LogPrint " => seems okay. new layout."
857 m_blnFound = checkClExe(strPathVC & "/bin/Host" & g_strHostArchWin & "/" & g_strTargetArchWin & "/cl.exe")
858 if m_blnFound then
859 m_strPathVC = strPathVC
860 end if
861 end if
862 end if
863 checkInner = m_blnFound
864 end function
865
866 public function check(strPathVC, strPathVCommon)
867 if (m_blnFound = False) and (strPathVC <> "") then
868 m_strPathVC = UnixSlashes(PathAbs(strPathVC))
869 m_strPathVCCommon = strPathVCCommon
870 m_strVersion = ""
871
872 LogPrint "Trying: strPathVC=" & m_strPathVC & " strPathVCCommon=" & m_strPathVCCommon
873 if LogDirExists(m_strPathVC) then
874 ' 15.0+ layout? This is fun because of the multiple CL versions (/tools/msvc/xx.yy.bbbbb/).
875 ' OTOH, the user may have pointed us directly to one of them.
876 if LogDirExists(m_strPathVC & "/Tools/MSVC") then
877 m_blnNewLayout = True
878 LogPrint " => seems okay. new layout."
879 dim arrFolders, i
880 arrFolders = GetSubdirsStartingWithVerSorted(m_strPathVC & "/Tools/MSVC", "14.2")
881 if UBound(arrFolders) < 0 then arrFolders = GetSubdirsStartingWithVerSorted(m_strPathVC & "/Tools/MSVC", "14.1")
882 if UBound(arrFolders) < 0 then arrFolders = GetSubdirsStartingWithVerSorted(m_strPathVC & "/Tools/MSVC", "1")
883 for i = UBound(arrFolders) to LBound(arrFolders) step -1
884 if checkInner(m_strPathVC & "/Tools/MSVC/" & arrFolders(i)) then exit for ' modifies m_strPathVC on success
885 next
886 elseif LogDirExists(m_strPathVC & "/bin/HostX64") _
887 or LogDirExists(m_strPathVC & "/bin/HostX86") then
888 checkInner(m_strPathVC)
889 ' 14.0 and older layout?
890 elseif LogFileExists(m_strPathVC, "/bin/cl.exe") then
891 m_blnNewLayout = False
892 if LogFileExists(m_strPathVC, "bin/link.exe") _
893 and LogFileExists(m_strPathVC, "include/string.h") _
894 and LogFileExists(m_strPathVC, "lib/libcmt.lib") _
895 and LogFileExists(m_strPathVC, "lib/msvcrt.lib") _
896 then
897 LogPrint " => seems okay. old layout."
898 m_blnFound = checkClExe(m_strPathVC & "/bin/cl.exe")
899 end if
900 end if
901 end if
902 end if
903 check = m_bldFound
904 end function
905
906 public function checkProg(strProg)
907 if m_blnFound = False then
908 dim str, i, offNewLayout
909 str = Which(strProg)
910 if str <> "" then
911 LogPrint "checkProg: '" & strProg & "' -> '" & str & "'"
912 if FileExists(PathStripFilename(str) & "/build.exe") then
913 Warning "Ignoring DDK cl.exe (" & str & ")." ' don't know how to deal with this cl.
914 else
915 ' Assume we've got cl.exe from somewhere under the 'bin' directory..
916 m_strPathVC = PathParent(PathStripFilename(str))
917 for i = 1 To 5
918 if LogDirExists(m_strPathVC & "/include") then
919 m_strPathVCCommon = PathParent(m_strPathVC) & "/Common7"
920 if DirExists(m_strPathVCCommon) = False then
921 m_strPathVCCommon = ""
922 ' New layout?
923 offNewLayout = InStr(1, LCase(DosSlashes(m_strPathVC)), "\tools\msvc\")
924 if offNewLayout > 0 then m_strPathVC = Left(m_strPathVC, offNewLayout)
925 end if
926 check m_strPathVC, m_strPathVCCommon
927 exit for
928 end if
929 m_strPathVC = PathParent(m_strPathVC)
930 next
931 end if
932 end if
933 end if
934 checkProg = m_bldFound
935 end function
936
937 public function checkProgFiles(strSubdir)
938 if m_blnFound = False then
939 dim strProgFiles
940 for each strProgFiles in g_arrProgramFiles
941 check strProgFiles & "/" & strSubdir, ""
942 next
943 end if
944 checkProgFiles = m_blnFound
945 end function
946
947 public function checkRegistry(strValueNm, strVCSubdir, strVCommonSubdir)
948 if m_blnFound = False then
949 dim str, strPrefix, arrPrefixes
950 arrPrefixes = Array("HKLM\SOFTWARE\Wow6432Node\", "HKLM\SOFTWARE\", "HKCU\SOFTWARE\Wow6432Node\", "HKCU\SOFTWARE\")
951 for each strPrefix in arrPrefixes
952 str = LogRegGetString(strPrefix & strValueNm)
953 if str <> "" then
954 LogPrint "checkRegistry: '" & strPrefix & strValueNm & "' -> '" & str & "'"
955 if check(str & strVCSubdir, str & strVCommonSubdir) = True then
956 exit for
957 end if
958 end if
959 next
960 end if
961 checkRegistry = m_bldFound
962 end function
963
964 public function checkProgItems(strVersionYear)
965 if m_blnFound = False then
966 dim strCandidate
967 for each strCandidate in CollectFromProgramItemLinks(GetRef("VisualCPPCallback"), strVersionYear)
968 check strCandidate, ""
969 next
970 end if
971 checkProgItems = m_blnFound
972 end function
973
974 public function checkInternal
975 dim strPathDev
976 for each strPathDev in g_arrPathDev : check strPathDev & "/win.amd64/vcc/v14.2", "" : next
977 for each strPathDev in g_arrPathDev : check strPathDev & "/win.amd64/vcc/v14.2", "" : next
978 for each strPathDev in g_arrPathDev : check strPathDev & "/win.amd64/vcc/v14.1", "" : next
979 for each strPathDev in g_arrPathDev : check strPathDev & "/win.amd64/vcc/v14.0", "" : next
980 for each strPathDev in g_arrPathDev : check strPathDev & "/win.amd64/vcc/v10sp1", "" : next
981 for each strPathDev in g_arrPathDev : check strPathDev & "/win.x86/vcc/v10sp1", "" : next
982 checkInternal = m_blnFound
983 end function
984end class
985
986' See checkProgItems()
987function VisualCPPCallback(ByRef arrStrings, cStrings, ByRef strVersionYear)
988 VisualCPPCallback = ""
989 ' We're looking for items with three strings like this:
990 ' C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Visual Studio 2019\Visual Studio Tools\VC\x64 Native Tools Command Prompt for VS 2019.lnk
991 ' C:\Windows\system32\cmd.exe
992 ' /k "C:\Program Files (x86)\Microsoft Visual Studio\2019\Professional\VC\Auxiliary\Build\vcvars64.bat"
993 if cStrings >= 3 then
994 if InStr(1, arrStrings(0), strVersionYear) > 0 then
995 dim strTail : strTail = "\Auxiliary\Build\vcvars64.bat"""
996 dim str : str = arrStrings(UBound(arrStrings))
997 if StrComp(Right(str, Len(strTail)), strTail, vbTextCompare) = 0 then
998 dim offColon : offColon = InStr(1, str, ":")
999 if offColon > 1 then
1000 VisualCPPCallback = Mid(str, offColon - 1, Len(str) - (offColon - 2) - Len(strTail))
1001 end if
1002 end if
1003 end if
1004 end if
1005end function
1006
1007
1008''
1009' Checks for a windows 10 SDK (later also WDK).
1010'
1011sub CheckForSDK10(strOptSDK10, strOptSDK10Version)
1012 dim strPathSDK10, strSDK10Version, str
1013 PrintHdr "Windows 10 SDK/WDK"
1014 '' @todo implement strOptSDK10Version
1015
1016 '
1017 ' Try find the Windows 10 kit.
1018 '
1019 strSDK10Version = ""
1020 strPathSDK10 = CheckForSDK10Sub(strOptSDK10, strSDK10Version)
1021 if strPathSDK10 = "" and g_blnInternalFirst = true then
1022 strPathSDK10 = SearchTargetPlusTools("sdk", "v10.", GetRef("CheckForSDK10Sub"), strSDK10Version)
1023 end if
1024
1025 if strPathSDK10 = "" then
1026 str = LogRegGetString("HKLM\SOFTWARE\Microsoft\Windows Kits\Installed Roots\KitsRoot10")
1027 strPathSDK10 = CheckForSDK10Sub(str, strSDK10Version)
1028 end if
1029 if strPathSDK10 = "" then
1030 for each str in g_arrProgramFiles
1031 strPathSDK10 = CheckForSDK10Sub(str & "/Windows Kits/10", strSDK10Version)
1032 if strPathSDK10 <> "" then exit for
1033 next
1034 end if
1035 if strPathSDK10 = "" and g_blnInternalFirst = true then
1036 strPathSDK10 = SearchTargetPlusTools("sdk", "v10.", GetRef("CheckForSDK10Sub"), strSDK10Version)
1037 end if
1038
1039 if strPathSDK10 = "" then
1040 MsgError "Cannot find a suitable Windows 10 SDK. Check configure.log and the build requirements."
1041 exit sub
1042 end if
1043
1044 '
1045 ' Emit the config.
1046 '
1047 strPathSDK10 = UnixSlashes(PathAbs(strPathSDK10))
1048 CfgPrintAssign "PATH_SDK_WINSDK10", strPathSDK10
1049 CfgPrintAssign "SDK_WINSDK10_VERSION", strSDK10Version
1050
1051 PrintResult "Windows 10 SDK", strPathSDK10
1052 PrintResultMsg "Windows 10 SDK version", strSDK10Version
1053 g_strPathSDK10 = strPathSDK10
1054end sub
1055
1056'' Checks if the specified path points to a usable Windows 10 SDK/WDK.
1057function CheckForSDK10Sub(strPathSDK10, ByRef strSDK10Version)
1058 CheckForSDK10Sub = ""
1059 if strPathSDK10 <> "" then
1060 LogPrint "Trying: strPathSDK10=" & strPathSDK10
1061 if LogDirExists(strPathSDK10) then
1062 if LogDirExists(strPathSDK10 & "/Bin") _
1063 and LogDirExists(strPathSDK10 & "/Include") _
1064 and LogDirExists(strPathSDK10 & "/Lib") _
1065 and LogDirExists(strPathSDK10 & "/Redist") _
1066 then
1067 ' Only testing the highest one, for now. '' @todo incorporate strOptSDK10Version
1068 dim arrVersions
1069 arrVersions = GetSubdirsStartingWithVerSorted(strPathSDK10 & "/Include", "10.0.")
1070 if UBound(arrVersions) >= 0 then
1071 dim strVersion
1072 strVersion = arrVersions(UBound(arrVersions))
1073 LogPrint "Trying version: " & strVersion
1074 if LogFileExists(strPathSDK10, "include/" & strVersion & "/um/Windows.h") _
1075 and LogFileExists(strPathSDK10, "include/" & strVersion & "/ucrt/malloc.h") _
1076 and LogFileExists(strPathSDK10, "include/" & strVersion & "/ucrt/stdio.h") _
1077 and LogFileExists(strPathSDK10, "lib/" & strVersion & "/um/" & g_strTargetArchWin & "/kernel32.lib") _
1078 and LogFileExists(strPathSDK10, "lib/" & strVersion & "/um/" & g_strTargetArchWin & "/user32.lib") _
1079 and LogFileExists(strPathSDK10, "lib/" & strVersion & "/ucrt/" & g_strTargetArchWin & "/libucrt.lib") _
1080 and LogFileExists(strPathSDK10, "lib/" & strVersion & "/ucrt/" & g_strTargetArchWin & "/ucrt.lib") _
1081 and LogFileExists(strPathSDK10, "bin/" & strVersion & "/" & g_strHostArchWin & "/rc.exe") _
1082 and LogFileExists(strPathSDK10, "bin/" & strVersion & "/" & g_strHostArchWin & "/midl.exe") _
1083 then
1084 if StrComp(strVersion, "10.0.17134.0") >= 0 then
1085 strSDK10Version = strVersion
1086 CheckForSDK10Sub = strPathSDK10
1087 else
1088 LogPrint "Version " & strVersion & " is too low, minimum: 10.0.17134.0"
1089 end if
1090 end if
1091 else
1092 LogPrint "Found no 10.0.* subdirectories under '" & strPathSDK10 & "/Include'!"
1093 end if
1094 end if
1095 end if
1096 end if
1097end function
1098
1099
1100''
1101' Locating a Windows 7 Driver Kit.
1102'
1103sub CheckForWinDDK(strOptDDK)
1104 dim strPathDDK, str, strSubKeys
1105 PrintHdr "Windows DDK v7.1"
1106
1107 '
1108 ' Find the DDK.
1109 '
1110 strPathDDK = CheckForWinDDKSub(strOptDDK, True)
1111
1112 ' The tools location (first).
1113 if strPathDDK = "" and g_blnInternalFirst = true then
1114 for each str in g_arrPathDev
1115 strPathDDK = CheckForWinDDKSub(str & "/win.x86/ddk/7600.16385.1", False)
1116 if strPathDDK <> "" then exit for
1117 next
1118 end if
1119
1120 ' Check the environment
1121 if strPathDDK = "" then strPathDDK = CheckForWinDDKSub(PathParent(PathParent(EnvGet("DDK_INC_PATH"))), True)
1122 if strPathDDK = "" then strPathDDK = CheckForWinDDKSub(EnvGet("BASEDIR"), True)
1123
1124 ' Some array constants to ease the work.
1125 arrSoftwareKeys = array("SOFTWARE", "SOFTWARE\Wow6432Node")
1126 arrRoots = array("HKLM", "HKCU")
1127
1128 ' Windows 7 WDK.
1129 if strPathDDK = "" then
1130 arrLocations = array()
1131 for each strSoftwareKey in arrSoftwareKeys
1132 for each strSubKey in RegEnumSubKeysFull("HKLM", strSoftwareKey & "\Microsoft\KitSetup\configured-kits")
1133 for each strSubKey2 in RegEnumSubKeysFull("HKLM", strSubKey)
1134 str = LogRegGetString("HKLM\" & strSubKey2 & "\setup-install-location")
1135 if str <> "" then
1136 arrLocations = ArrayAppend(arrLocations, PathAbsLong(str))
1137 end if
1138 next
1139 next
1140 next
1141 arrLocations = ArrayRVerSortStrings(arrLocations)
1142
1143 ' Check the locations we've gathered.
1144 for each str in arrLocations
1145 strPathDDK = CheckForWinDDKSub(str, True)
1146 if strPathDDK <> "" then exit for
1147 next
1148 end if
1149
1150 ' The tools location (post).
1151 if strPathDDK = "" and g_blnInternalFirst = false then
1152 for each str in g_arrPathDev
1153 strPathDDK = CheckForWinDDKSub(str & "/win.x86/ddk/7600.16385.1", False)
1154 if strPathDDK <> "" then exit for
1155 next
1156 end if
1157
1158 ' Give up.
1159 if strPathDDK = "" then
1160 MsgError "Cannot find the Windows DDK v7.1. Check configure.log and the build requirements."
1161 exit sub
1162 end if
1163
1164 '
1165 ' Emit the config.
1166 '
1167 strPathDDK = UnixSlashes(PathAbs(strPathDDK))
1168 CfgPrintAssign "PATH_SDK_WINDDK71", strPathDDK
1169
1170 PrintResult "Windows DDK v7.1", strPathDDK
1171 g_strPathDDK = strPathDDK
1172end sub
1173
1174'' Quick check if the DDK is in the specified directory or not.
1175function CheckForWinDDKSub(strPathDDK, blnCheckBuild)
1176 CheckForWinDDKSub = ""
1177 if strPathDDK <> "" then
1178 dim strOutput
1179 LogPrint "Trying: strPathDDK=" & strPathDDK & " blnCheckBuild=" & blnCheckBuild
1180 if LogFileExists(strPathDDK, "inc/api/ntdef.h") _
1181 And LogFileExists(strPathDDK, "lib/win7/i386/int64.lib") _
1182 And LogFileExists(strPathDDK, "lib/wlh/i386/int64.lib") _
1183 And LogFileExists(strPathDDK, "lib/wnet/i386/int64.lib") _
1184 And LogFileExists(strPathDDK, "lib/wxp/i386/int64.lib") _
1185 And Not LogFileExists(strPathDDK, "lib/win8/i386/int64.lib") _
1186 And LogFileExists(strPathDDK, "bin/x86/rc.exe") _
1187 then
1188 if Not blnCheckBuild then
1189 CheckForWinDDKSub = strPathDDK
1190 '' @todo Find better build check.
1191 elseif Shell("""" & DosSlashes(strPathDDK & "/bin/x86/rc.exe") & """" , True, strOutput) <> 0 _
1192 and InStr(1, strOutput, "Resource Compiler Version 6.1.") > 0 _
1193 then
1194 CheckForWinDDKSub = strPathDDK
1195 end if
1196 end if
1197 end if
1198end function
1199
1200
1201''
1202' Locating midl.exe
1203'
1204sub CheckForMidl(strOptMidl)
1205 dim strMidl, str
1206 PrintHdr "Midl.exe"
1207
1208 ' Skip if no COM/ATL.
1209 if g_blnDisableCOM then
1210 PrintResultMsg "Midl.exe", "Skipped (" & g_strDisableCOM & ")"
1211 exit sub
1212 end if
1213
1214 strMidl = CheckForMidlSub(strOptMidl)
1215 if strMidl = "" then strMidl = CheckForMidlSub(g_strPathSDK10 & "/bin/" & g_strHostArchWin & "/Midl.exe")
1216 if strMidl = "" then strMidl = CheckForMidlSub(g_strPathSDK10 & "/bin/x86/Midl.exe")
1217 if strMidl = "" then strMidl = CheckForMidlSub(g_strPathPSDK & "/bin/Midl.exe")
1218 if strMidl = "" then strMidl = CheckForMidlSub(g_strPathVCC & "/Common7/Tools/Bin/Midl.exe")
1219 if strMidl = "" then strMidl = CheckForMidlSub(g_strPathDDK & "/bin/" & g_strHostArchWin & "/Midl.exe")
1220 if strMidl = "" then strMidl = CheckForMidlSub(g_strPathDDK & "/bin/x86/Midl.exe")
1221 if strMidl = "" then strMidl = CheckForMidlSub(g_strPathDDK & "/bin/Midl.exe")
1222 if strMidl = "" then
1223 for each str in g_arrPathDev
1224 strMidl = CheckForMidlSub(str & "/win." & g_strHostArchWin & "/bin/Midl.exe")
1225 if strMidl <> "" then exit for
1226 strMidl = CheckForMidlSub(str & "/win.x86/bin/Midl.exe")
1227 if strMidl <> "" then exit for
1228 next
1229 end if
1230
1231 if strMidl = "" then
1232 PrintResultMsg "Midl.exe", "not found"
1233 else
1234 CfgPrintAssign "VBOX_MAIN_IDL", strMidl
1235 PrintResult "Midl.exe", strMidl
1236 end if
1237end sub
1238
1239function CheckForMidlSub(strMidl)
1240 CheckForMidlSub = ""
1241 if strMidl <> "" then
1242 if LogFileExists1(strMidl) then
1243 CheckForMidlSub = UnixSlashes(PathAbs(strMidl))
1244 end if
1245 end if
1246end function
1247
1248
1249''
1250' Locating yasm.exe
1251'
1252sub CheckForYasm(strOptYasm)
1253 dim strPathYasm, strVersion
1254 PrintHdr "yasm"
1255
1256 strVersion = ""
1257 strPathYasm = CheckForYasmSub(strOptYasm, strVersion)
1258 if strPathYasm = "" then strPathYasm = CheckForYasmSub(PathStripFilename(strOptYasm), strVersion)
1259 if strPathYasm = "" and g_blnInternalFirst = true then
1260 strPathYasm = SearchHostTools("yasm", "v", GetRef("CheckForYasmSub"), strVersion)
1261 end if
1262 if strPathYasm = "" then strPathYasm = CheckForYasmSub(PathStripFilename(Which("yasm.exe")), strVersion)
1263 if strPathYasm = "" and g_blnInternalFirst = false then
1264 strPathYasm = SearchHostTools("yasm", "v", GetRef("CheckForYasmSub"), strVersion)
1265 end if
1266
1267 if strPathYasm = "" then
1268 PrintResultMsg "yasm", "not found"
1269 MsgError "Unable to locate yasm!"
1270 else
1271 CfgPrintAssign "PATH_TOOL_YASM", strPathYasm
1272 PrintResult "yasm v" & strVersion, strPathYasm
1273 end if
1274end sub
1275
1276function CheckForYasmSub(strPathYasm, ByRef strVersion)
1277 CheckForYasmSub = ""
1278 if strPathYasm <> "" then
1279 if LogFileExists(strPathYasm, "yasm.exe") then
1280 dim strOutput
1281 if Shell("""" & DosSlashes(strPathYasm & "\yasm.exe") & """ --version", True, strOutput) = 0 then
1282 dim strPreamble : strPreamble = "yasm"
1283 dim strVer : strVer = Trim(StrGetFirstLine(strOutput))
1284 if StrComp(Left(strVer, Len(strPreamble)), strPreamble, vbTextCompare) = 0 then
1285 strVersion = StrGetFirstWord(Trim(Mid(strVer, Len(strPreamble) + 1)))
1286 if StrVersionCompare(strVersion, "1.3.0") >= 0 and strVersion <> "" then
1287 LogPrint "Found yasm version: " & strVer
1288 CheckForYasmSub = UnixSlashes(PathAbs(strPathYasm))
1289 else
1290 LogPrint "yasm version is older than 1.3.0: " & strVersion
1291 end if
1292 else
1293 LogPrint "Not yasm: " & strVer
1294 end if
1295 end if
1296 end if
1297 end if
1298end function
1299
1300
1301''
1302' Locating nasm.exe
1303'
1304sub CheckForNasm(strOptNasm)
1305 dim strPathNasm, strVersion
1306 PrintHdr "nasm"
1307
1308 strPathNasm = CheckForNasmSub(strOptNasm, strVersion)
1309 if strPathNasm = "" then strPathNasm = CheckForNasmSub(PathStripFilename(strOptNasm), strVersion)
1310 if strPathNasm = "" and g_blnInternalFirst = true then
1311 strPathNasm = SearchHostTools("nasm", "v", GetRef("CheckForNasmSub"), strVersion)
1312 end if
1313 if strPathNasm = "" then strPathNasm = CheckForNasmSub(LogRegGetString("HKLM\SOFTWARE\nasm\"), strVersion)
1314 if strPathNasm = "" then strPathNasm = CheckForNasmSub(LogRegGetString("HKCU\SOFTWARE\nasm\"), strVersion)
1315 if strPathNasm = "" then
1316 for each strCandidate in CollectFromProgramItemLinks(GetRef("NasmProgramItemCallback"), strPathNasm)
1317 strPathNasm = CheckForNasmSub(strCandidate, strVersion)
1318 next
1319 end if
1320 if strPathNasm = "" then strPathNasm = CheckForNasmSub(PathStripFilename(Which("nasm.exe")), strVersion)
1321 if strPathNasm = "" and g_blnInternalFirst = false then
1322 strPathNasm = SearchHostTools("nasm", "v", GetRef("CheckForNasmSub"), strVersion)
1323 end if
1324
1325 if strPathNasm = "" then
1326 PrintResultMsg "nasm", "not found"
1327 else
1328 CfgPrintAssign "PATH_TOOL_NASM", strPathNasm
1329 PrintResult "nasm v" & strVersion, strPathNasm
1330 end if
1331end sub
1332
1333function NasmProgramItemCallback(ByRef arrStrings, cStrings, ByRef strUnused)
1334 dim str, off
1335 NasmProgramItemCallback = ""
1336 if cStrings > 1 then
1337 str = arrStrings(1)
1338 off = InStr(1, str, "\nasm.exe", vbTextCompare)
1339 if off > 0 then
1340 NasmProgramItemCallback = Left(str, off - 1)
1341 end if
1342 end if
1343end function
1344
1345function CheckForNasmSub(strPathNasm, ByRef strVersion)
1346 CheckForNasmSub = ""
1347 if strPathNasm <> "" then
1348 if LogFileExists(strPathNasm, "nasm.exe") then
1349 dim strOutput
1350 if Shell("""" & DosSlashes(strPathNasm & "\nasm.exe") & """ -version", True, strOutput) = 0 then
1351 dim strPreamble : strPreamble = "NASM version"
1352 dim strVer : strVer = Trim(StrGetFirstLine(strOutput))
1353 if StrComp(Left(strVer, Len(strPreamble)), strPreamble, vbTextCompare) = 0 then
1354 strVersion = StrGetFirstWord(Trim(Mid(strVer, Len(strPreamble) + 1)))
1355 if StrVersionCompare(strVersion, "2.12.0") >= 0 and strVersion <> "" then
1356 LogPrint "Found nasm version: " & strVersion
1357 CheckForNasmSub = UnixSlashes(PathAbs(strPathNasm))
1358 else
1359 LogPrint "nasm version is older than 2.12.0: " & strVersion
1360 end if
1361 else
1362 LogPrint "Not nasm: " & strVer
1363 end if
1364 end if
1365 end if
1366 end if
1367end function
1368
1369
1370''
1371' Locating OpenWatcom 1.9
1372'
1373sub CheckForOpenWatcom(strOptOpenWatcom)
1374 dim strPathOW, strCandidate, strVersion
1375 PrintHdr "OpenWatcom"
1376
1377 strPathOW = CheckForOpenWatcomSub(strOptOpenWatcom, strVersion)
1378 if strPathOW = "" and g_blnInternalFirst = true then
1379 strPathOW = SearchCommonTools("openwatcom", "v", GetRef("CheckForOpenWatcomSub"), strVersion)
1380 end if
1381 if strPathOW = "" then
1382 for each strCandidate in CollectFromProgramItemLinks(GetRef("OpenWatcomProgramItemCallback"), strPathOW)
1383 if strPathOW = "" then strPathOW = CheckForOpenWatcomSub(strCandidate, strVersion)
1384 next
1385 end if
1386 if strPathOW = "" then strPathOW = CheckForOpenWatcomSub(EnvGet("WATCOM"), strVersion)
1387 if strPathOW = "" then strPathOW = CheckForOpenWatcomSub(PathParent(PathStripFilename(Which("wcc386.exe"))), strVersion)
1388 if strPathOW = "" and g_blnInternalFirst = false then
1389 strPathOW = SearchCommonTools("openwatcom", "v", GetRef("CheckForOpenWatcomSub"), strVersion)
1390 end if
1391
1392 if strPathOW = "" then
1393 PrintResultMsg "OpenWatcom", "not found"
1394 CfgPrintAssign "VBOX_WITH_OPEN_WATCOM", ""
1395 exit sub
1396 end if
1397
1398 CfgPrintAssign "VBOX_WITH_OPEN_WATCOM", "1"
1399 CfgPrintAssign "PATH_TOOL_OPENWATCOM", strPathOW
1400 PrintResult "OpenWatcom v" & strVersion, strPathOW
1401 if StrVersionCompare(strVersion, "2.0") >= 0 then
1402 MsgWarning "We only test building with OpenWatcom 1.9."
1403 end if
1404end sub
1405
1406function OpenWatcomProgramItemCallback(ByRef arrStrings, cStrings, ByRef strUnused)
1407 dim str, off
1408 OpenWatcomProgramItemCallback = ""
1409 if cStrings > 1 then
1410 str = arrStrings(1)
1411 off = InStr(1, str, "\binnt\", vbTextCompare)
1412 if off > 0 then
1413 OpenWatcomProgramItemCallback = Left(str, off - 1)
1414 end if
1415 end if
1416end function
1417
1418function CheckForOpenWatcomSub(strPathOW, ByRef strVersion)
1419 CheckForOpenWatcomSub = ""
1420 if strPathOW <> "" then
1421 LogPrint "Trying: " & strPathOW
1422 if LogDirExists(strPathOW) then
1423 if LogDirExists(strPathOW & "/binnt") _
1424 and LogDirExists(strPathOW & "/h") _
1425 and LogDirExists(strPathOW & "/eddat") _
1426 and LogFileExists(strPathOW, "binnt/wcc386.exe") _
1427 and LogFileExists(strPathOW, "binnt/wcc.exe") _
1428 and LogFileExists(strPathOW, "binnt/wlink.exe") _
1429 and LogFileExists(strPathOW, "binnt/wcl386.exe") _
1430 and LogFileExists(strPathOW, "binnt/wcl.exe") _
1431 and LogFileExists(strPathOW, "binnt/wlib.exe") _
1432 and LogFileExists(strPathOW, "binnt/wasm.exe") _
1433 and LogFileExists(strPathOW, "h/stdarg.h") _
1434 then
1435 ' Some wcl/wcl386 option parsing quirk allows us to specify /whatever
1436 ' and just get the logo text and exit code 0. We use /y as it's a valid option.
1437 dim strOutput
1438 if Shell("""" & DosSlashes(strPathOW & "\binnt\wcl.exe") & """ /y", True, strOutput) = 0 then
1439 dim strPreamble : strPreamble = "Open Watcom C/C++16 Compile and Link Utility Version"
1440 strOutput = StrGetFirstLine(strOutput)
1441 if StrStartsWithI(strOutput, strPreamble) then
1442 strVersion = StrGetFirstWord(Trim(Mid(strOutput, Len(strPreamble) + 1)))
1443 if StrVersionCompare(strVersion, "1.9") >= 0 then
1444 CheckForOpenWatcomSub = UnixSlashes(PathAbs(strPathOW))
1445 else
1446 LogPrint "OpenWatcom version id older than 1.9: " & strVersion
1447 end if
1448 else
1449 LogPrint "Not OpenWatcom: " & strOutput
1450 end if
1451 end if
1452 end if
1453 end if
1454 end if
1455end function
1456
1457
1458''
1459' Checks for any libSDL binaries.
1460'
1461sub CheckForlibSDL(strOptlibSDL)
1462 dim strPathLibSDL, strVersion
1463 PrintHdr "libSDL"
1464
1465 '
1466 ' Try find some SDL library.
1467 '
1468 strPathLibSDL = CheckForLibSDLSub(strOptlibSDL, strVersion)
1469 if strPathlibSDL = "" and g_blnInternalFirst = true then
1470 strPathLibSDL = SearchTargetTools("libsdl", "v", GetRef("CheckForLibSDLSub"), strVersion)
1471 end if
1472
1473 ' Poke about in the LIB and PATH env.vars.
1474 if strPathlibSDL = "" then strPathLibSDL = CheckForlibSDLSub(PathParent(PathStripFilename(WhichEx("LIB", "SDLmain.lib"))), strVersion)
1475 if strPathlibSDL = "" then strPathLibSDL = CheckForlibSDLSub(PathParent(PathStripFilename(Which("..\lib\SDLmain.lib"))), strVersion)
1476 if strPathlibSDL = "" then strPathLibSDL = CheckForlibSDLSub(PathParent(PathStripFilename(Which("SDLmain.lib"))), strVersion)
1477 if strPathlibSDL = "" then strPathLibSDL = CheckForlibSDLSub(PathParent(PathStripFilename(Which("SDL.dll"))), strVersion)
1478
1479 ' The tools again.
1480 if strPathlibSDL = "" and g_blnInternalFirst = false then
1481 strPathLibSDL = SearchTargetTools("libsdl", "v", GetRef("CheckForLibSDLSub"), strVersion)
1482 end if
1483
1484 ' Success?
1485 if strPathlibSDL = "" then
1486 if strOptlibSDL = "" then
1487 MsgError "Can't locate libSDL. Try specify the path with the --with-libSDL=<path> argument. " _
1488 & "If still no luck, consult the configure.log and the build requirements."
1489 else
1490 MsgError "Can't locate libSDL. Please consult the configure.log and the build requirements."
1491 end if
1492 exit sub
1493 end if
1494
1495 strPathLibSDL = UnixSlashes(PathAbs(strPathLibSDL))
1496 CfgPrintAssign "PATH_SDK_LIBSDL", strPathlibSDL
1497
1498 PrintResult "libSDL", strPathlibSDL
1499end sub
1500
1501'' Checks if the specified path points to an usable libSDL or not.
1502function CheckForLibSDLSub(strPathlibSDL, strVersion)
1503 CheckForlibSDLSub = ""
1504 if strPathLibSDL <> "" then
1505 LogPrint "Trying: strPathLibSDL=" & strPathLibSDL
1506 if LogFileExists(strPathLibSDL, "lib/SDL.lib") _
1507 and LogFileExists(strPathLibSDL, "lib/SDLmain.lib") _
1508 and LogFileExists(strPathLibSDL, "lib/SDL.dll") _
1509 then
1510 dim strIncSub : strIncSub = "include"
1511 if DirExists(strPathlibSDL & "/include/SDL") then strIncSub = "include/SDL"
1512 if LogFileExists(strPathLibSDL, strIncSub & "/SDL.h") _
1513 and LogFileExists(strPathLibSDL, strIncSub & "/SDL_syswm.h") _
1514 and LogFileExists(strPathLibSDL, strIncSub & "/SDL_version.h") _
1515 then
1516 strVersion = ""
1517 CheckForLibSDLSub = strPathLibSDL
1518 end if
1519 end if
1520 end if
1521end function
1522
1523
1524''
1525' Checks for libxml2.
1526'
1527sub CheckForXml2(strOptXml2)
1528 dim strPathXml2, str
1529 PrintHdr "libxml2"
1530
1531 '
1532 ' Part of tarball / svn, so we can exit immediately if no path was specified.
1533 '
1534 if (strOptXml2 = "") then
1535 PrintResultMsg "libxml2", "src/lib/libxml2-*"
1536 exit sub
1537 end if
1538
1539 ' Skip if no COM/ATL.
1540 if g_blnDisableCOM then
1541 PrintResultMsg "libxml2", "Skipped (" & g_strDisableCOM & ")"
1542 exit sub
1543 end if
1544
1545 '
1546 ' Try find some xml2 dll/lib.
1547 '
1548 strPathXml2 = ""
1549 if (strPathXml2 = "") And (strOptXml2 <> "") then
1550 if CheckForXml2Sub(strOptXml2) then strPathXml2 = strOptXml2
1551 end if
1552
1553 if strPathXml2 = "" then
1554 str = Which("libxml2.lib")
1555 if str <> "" then
1556 str = PathParent(PathStripFilename(str))
1557 if CheckForXml2Sub(str) then strPathXml2 = str
1558 end if
1559 end if
1560
1561 ' Success?
1562 if strPathXml2 = "" then
1563 if strOptXml2 = "" then
1564 MsgError "Can't locate libxml2. Try specify the path with the --with-libxml2=<path> argument. " _
1565 & "If still no luck, consult the configure.log and the build requirements."
1566 else
1567 MsgError "Can't locate libxml2. Please consult the configure.log and the build requirements."
1568 end if
1569 exit sub
1570 end if
1571
1572 strPathXml2 = UnixSlashes(PathAbs(strPathXml2))
1573 CfgPrintAssign "SDK_VBOX_LIBXML2_DEFS", "_REENTRANT"
1574 CfgPrintAssign "SDK_VBOX_LIBXML2_INCS", strPathXml2 & "/include"
1575 CfgPrintAssign "SDK_VBOX_LIBXML2_LIBS", strPathXml2 & "/lib/libxml2.lib"
1576
1577 PrintResult "libxml2", strPathXml2
1578end sub
1579
1580'' Checks if the specified path points to an usable libxml2 or not.
1581function CheckForXml2Sub(strPathXml2)
1582 dim str
1583
1584 CheckForXml2Sub = False
1585 LogPrint "trying: strPathXml2=" & strPathXml2
1586 if LogFileExists(strPathXml2, "include/libxml/xmlexports.h") _
1587 And LogFileExists(strPathXml2, "include/libxml/xmlreader.h") _
1588 then
1589 str = LogFindFile(strPathXml2, "bin/libxml2.dll")
1590 if str <> "" then
1591 if LogFindFile(strPathXml2, "lib/libxml2.lib") <> "" then
1592 CheckForXml2Sub = True
1593 end if
1594 end if
1595 end if
1596end function
1597
1598
1599'' Checks for openssl
1600sub CheckForSsl(strOptSsl, bln32Bit)
1601 dim strPathSsl, str
1602 PrintHdr "openssl"
1603
1604 strOpenssl = "openssl"
1605 if bln32Bit = True then
1606 strOpenssl = "openssl32"
1607 end if
1608
1609 '
1610 ' Part of tarball / svn, so we can exit immediately if no path was specified.
1611 '
1612 if (strOptSsl = "") then
1613 PrintResult strOpenssl, "src/libs/openssl-*"
1614 exit sub
1615 end if
1616
1617 '
1618 ' Try find some openssl dll/lib.
1619 '
1620 strPathSsl = ""
1621 if (strPathSsl = "") And (strOptSsl <> "") then
1622 if CheckForSslSub(strOptSsl) then strPathSsl = strOptSsl
1623 end if
1624
1625 if strPathSsl = "" then
1626 str = Which("libssl.lib")
1627 if str <> "" then
1628 str = PathParent(PathStripFilename(str))
1629 if CheckForSslSub(str) then strPathSsl = str
1630 end if
1631 end if
1632
1633 ' Success?
1634 if strPathSsl = "" then
1635 if strOptSsl = "" then
1636 MsgError "Can't locate " & strOpenssl & ". " _
1637 & "Try specify the path with the --with-" & strOpenssl & "=<path> argument. " _
1638 & "If still no luck, consult the configure.log and the build requirements."
1639 else
1640 MsgError "Can't locate " & strOpenssl & ". " _
1641 & "Please consult the configure.log and the build requirements."
1642 end if
1643 exit sub
1644 end if
1645
1646 strPathSsl = UnixSlashes(PathAbs(strPathSsl))
1647 if bln32Bit = True then
1648 CfgPrintAssign "SDK_VBOX_OPENSSL-x86_INCS", strPathSsl & "/include"
1649 CfgPrintAssign "SDK_VBOX_OPENSSL-x86_LIBS", strPathSsl & "/lib/libcrypto.lib" & " " & strPathSsl & "/lib/libssl.lib"
1650 CfgPrintAssign "SDK_VBOX_BLD_OPENSSL-x86_LIBS", strPathSsl & "/lib/libcrypto.lib" & " " & strPathSsl & "/lib/libssl.lib"
1651 else
1652 CfgPrintAssign "SDK_VBOX_OPENSSL_INCS", strPathSsl & "/include"
1653 CfgPrintAssign "SDK_VBOX_OPENSSL_LIBS", strPathSsl & "/lib/libcrypto.lib" & " " & strPathSsl & "/lib/libssl.lib"
1654 CfgPrintAssign "SDK_VBOX_BLD_OPENSSL_LIBS", strPathSsl & "/lib/libcrypto.lib" & " " & strPathSsl & "/lib/libssl.lib"
1655 end if
1656
1657 PrintResult strOpenssl, strPathSsl
1658end sub
1659
1660'' Checks if the specified path points to an usable openssl or not.
1661function CheckForSslSub(strPathSsl)
1662
1663 CheckForSslSub = False
1664 LogPrint "trying: strPathSsl=" & strPathSsl
1665 if LogFileExists(strPathSsl, "include/openssl/md5.h") _
1666 And LogFindFile(strPathSsl, "lib/libssl.lib") <> "" _
1667 then
1668 CheckForSslSub = True
1669 end if
1670end function
1671
1672
1673''
1674' Checks for libcurl
1675'
1676sub CheckForCurl(strOptCurl, bln32Bit)
1677 dim strPathCurl, str
1678 PrintHdr "libcurl"
1679
1680 strCurl = "libcurl"
1681 if bln32Bit = True then
1682 strCurl = "libcurl32"
1683 end if
1684
1685 '
1686 ' Part of tarball / svn, so we can exit immediately if no path was specified.
1687 '
1688 if (strOptCurl = "") then
1689 PrintResult strCurl, "src/libs/curl-*"
1690 exit sub
1691 end if
1692
1693 '
1694 ' Try find some cURL dll/lib.
1695 '
1696 strPathCurl = ""
1697 if (strPathCurl = "") And (strOptCurl <> "") then
1698 if CheckForCurlSub(strOptCurl) then strPathCurl = strOptCurl
1699 end if
1700
1701 if strPathCurl = "" then
1702 str = Which("libcurl.lib")
1703 if str <> "" then
1704 str = PathParent(PathStripFilename(str))
1705 if CheckForCurlSub(str) then strPathCurl = str
1706 end if
1707 end if
1708
1709 ' Success?
1710 if strPathCurl = "" then
1711 if strOptCurl = "" then
1712 MsgError "Can't locate " & strCurl & ". " _
1713 & "Try specify the path with the --with-" & strCurl & "=<path> argument. " _
1714 & "If still no luck, consult the configure.log and the build requirements."
1715 else
1716 MsgError "Can't locate " & strCurl & ". " _
1717 & "Please consult the configure.log and the build requirements."
1718 end if
1719 exit sub
1720 end if
1721
1722 strPathCurl = UnixSlashes(PathAbs(strPathCurl))
1723 if bln32Bit = True then
1724 CfgPrintAssign "SDK_VBOX_LIBCURL-x86_INCS", strPathCurl & "/include"
1725 CfgPrintAssign "SDK_VBOX_LIBCURL-x86_LIBS.x86", strPathCurl & "/libcurl.lib"
1726 else
1727 CfgPrintAssign "SDK_VBOX_LIBCURL_INCS", strPathCurl & "/include"
1728 CfgPrintAssign "SDK_VBOX_LIBCURL_LIBS", strPathCurl & "/libcurl.lib"
1729 end if
1730
1731 PrintResult strCurl, strPathCurl
1732end sub
1733
1734'' Checks if the specified path points to an usable libcurl or not.
1735function CheckForCurlSub(strPathCurl)
1736
1737 CheckForCurlSub = False
1738 LogPrint "trying: strPathCurl=" & strPathCurl
1739 if LogFileExists(strPathCurl, "include/curl/curl.h") _
1740 And LogFindFile(strPathCurl, "libcurl.dll") <> "" _
1741 And LogFindFile(strPathCurl, "libcurl.lib") <> "" _
1742 then
1743 CheckForCurlSub = True
1744 end if
1745end function
1746
1747
1748''
1749' Checks for any Qt5 binaries.
1750'
1751sub CheckForQt(strOptQt5, strOptInfix)
1752 dim strPathQt5, strInfixQt5, arrFolders, arrVccInfixes, strVccInfix, strPathDev
1753 PrintHdr "Qt5"
1754
1755 '
1756 ' Try to find the Qt5 installation (user specified path with --with-qt5)
1757 '
1758 LogPrint "Checking for user specified path of Qt5 ... "
1759 strPathQt5 = CheckForQt5Sub(UnixSlashes(strOptQt5), strOptInfix, strInfixQt5)
1760 if strPathQt5 = "" and g_blnInternalFirst = true then strPathQt5 = CheckForQt5Internal(strOptInfix, strInfixQt5)
1761 if strPathQt5 = "" then
1762 '
1763 ' Collect links from "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\UFH\SHC"
1764 '
1765 ' Typical string list:
1766 ' C:\Users\someuser\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Qt\5.x.y\MSVC 20zz (64-bit)\Qt 5.x.y (MSVC 20zz 64-bit).lnk
1767 ' C:\Windows\System32\cmd.exe
1768 ' /A /Q /K E:\qt\installed\5.x.y\msvc20zz_64\bin\qtenv2.bat
1769 '
1770 dim arrCandidates, strCandidate
1771 arrCandidates = CollectFromProgramItemLinks(GetRef("Qt5ProgramItemCallback"), strPathQt5)
1772 LogPrint "Testing qtenv2.bat links (" & ArraySize(arrCandidates) & ") ..."
1773
1774 ' VC infixes/subdir names to consider (ASSUMES 64bit)
1775 if g_strVCCVersion = "VCC142" or g_strVCCVersion = "" then
1776 arrVccInfixes = Array("msvc2019_64", "msvc2017_64", "msvc2015_64")
1777 elseif g_strVCCVersion = "VCC141" then
1778 arrVccInfixes = Array("msvc2017_64", "msvc2015_64", "msvc2019_64")
1779 elseif g_strVCCVersion = "VCC140" then
1780 arrVccInfixes = Array("msvc2015_64", "msvc2017_64", "msvc2019_64")
1781 elseif g_strVCCVersion = "VCC120" then
1782 arrVccInfixes = Array("msvc2013_64")
1783 elseif g_strVCCVersion = "VCC110" then
1784 arrVccInfixes = Array("msvc2012_64")
1785 elseif g_strVCCVersion = "VCC100" then
1786 arrVccInfixes = Array("msvc2010_64")
1787 else
1788 MsgFatal "Unexpected VC version: " & g_strVCCVersion
1789 arrVccInfixes = Array()
1790 end if
1791 for each strVccInfix in arrVccInfixes
1792 for each strCandidate in arrCandidates
1793 if InStr(1, LCase(strCandidate), strVccInfix) > 0 then
1794 strPathQt5 = CheckForQt5Sub(strCandidate, strOptInfix, strInfixQt5)
1795 if strPathQt5 <> "" then exit for
1796 end if
1797 next
1798 if strPathQt5 <> "" then exit for
1799 next
1800 end if
1801
1802 ' Check the dev tools - prefer ones matching the compiler.
1803 if strPathQt5 = "" and g_blnInternalFirst = false then strPathQt5 = CheckForQt5Internal(strOptInfix, strInfixQt5)
1804
1805 '
1806 ' Display the result and output the config.
1807 '
1808 if strPathQt5 <> "" then
1809 PrintResult "Qt5", strPathQt5
1810 PrintResultMsg "Qt5 infix", strInfixQt5
1811 CfgPrintAssign "PATH_SDK_QT5", strPathQt5
1812 CfgPrintAssign "PATH_TOOL_QT5", "$(PATH_SDK_QT5)"
1813 CfgPrintAssign "VBOX_PATH_QT", "$(PATH_SDK_QT5)"
1814 CfgPrintAssign "VBOX_QT_INFIX", strInfixQt5
1815 CfgPrintAssign "VBOX_WITH_QT_PAYLOAD", "1"
1816 else
1817 PrintResultMsg "Qt5", "not found"
1818 CfgPrintAssign "VBOX_WITH_QTGUI", ""
1819 end if
1820end sub
1821
1822function CheckForQt5Internal(strOptInfix, ByRef strInfixQt5)
1823 dim strPathDev, arrFolders, arrVccInfixes, strVccInfix, i
1824 CheckForQt5Internal = ""
1825 for each strPathDev in g_arrPathDev
1826 LogPrint "Testing tools dir (" & strPathDev & "/win." & g_strTargetArch & "/qt/v5*) ..."
1827 arrFolders = GetSubdirsStartingWithVerSorted(strPathDev & "/win." & g_strTargetArch & "/qt", "v5")
1828 arrVccInfixes = Array(LCase(g_strVCCVersion), Left(LCase(g_strVCCVersion), Len(g_strVCCVersion) - 1), "")
1829 for each strVccInfix in arrVccInfixes
1830 for i = UBound(arrFolders) to LBound(arrFolders) step -1
1831 if strVccInfix = "" or InStr(1, LCase(arrFolders(i)), strVccInfix) > 0 then
1832LogPrint "i="&i&" strVccInfix="&strVccInfix
1833 strPathQt5 = CheckForQt5Sub(strPathDev & "/win." & g_strTargetArch & "/qt/" & arrFolders(i), strOptInfix, strInfixQt5)
1834 if strPathQt5 <> "" then
1835 CheckForQt5Internal = strPathQt5
1836 exit function
1837 end if
1838 end if
1839 next
1840 next
1841 next
1842end function
1843
1844function Qt5ProgramItemCallback(ByRef arrStrings, cStrings, ByRef strUnused)
1845 dim str, off
1846 Qt5ProgramItemCallback = ""
1847 if cStrings >= 3 then
1848 str = Trim(arrStrings(UBound(arrStrings)))
1849 if LCase(Right(str, Len("\bin\qtenv2.bat"))) = "\bin\qtenv2.bat" _
1850 and InStr(1, LCase(str), "\msvc20") > 0 _
1851 and InStr(1, str, ":") > 0 _
1852 then
1853 off = InStr(1, str, ":") - 1
1854 Qt5ProgramItemCallback = Mid(str, off, Len(str) - off - Len("\bin\qtenv2.bat") + 1)
1855 end if
1856 end if
1857end function
1858
1859function CheckForQt5Sub(strPathQt5, strOptInfix, ByRef strInfixQt5)
1860 CheckForQt5Sub = ""
1861 if strPathQt5 <> "" then
1862 LogPrint "Trying: strPathQt5=" & strPathQt5
1863
1864 if LogFileExists(strPathQt5, "bin/moc.exe") _
1865 and LogFileExists(strPathQt5, "bin/uic.exe") _
1866 and LogFileExists(strPathQt5, "include/QtWidgets/qwidget.h") _
1867 and LogFileExists(strPathQt5, "include/QtWidgets/QApplication") _
1868 and LogFileExists(strPathQt5, "include/QtGui/QImage") _
1869 and LogFileExists(strPathQt5, "include/QtNetwork/QHostAddress") _
1870 then
1871 ' Infix testing.
1872 if LogFileExists(strPathQt5, "lib/Qt5Core.lib") _
1873 and LogFileExists(strPathQt5, "lib/Qt5Network.lib") then
1874 LogPrint "found it w/o infix"
1875 strInfixQt5 = ""
1876 CheckForQt5Sub = UnixSlashes(PathAbs(strPathQt5))
1877 elseif LogFileExists(strPathQt5, "lib/Qt5Core" & strOptInfix & ".lib") _
1878 and LogFileExists(strPathQt5, "lib/Qt5Network" & strOptInfix & ".lib") then
1879 LogPrint "found it w/ infix: " & strOptInfix & " (option)"
1880 strInfixQt5 = strOptInfix
1881 CheckForQt5Sub = UnixSlashes(PathAbs(strPathQt5))
1882 elseif LogFileExists(strPathQt5, "lib/Qt5CoreVBox.lib") _
1883 and LogFileExists(strPathQt5, "lib/Qt5NetworkVBox.lib") then
1884 LogPrint "found it w/ infix: VBox"
1885 strInfixQt5 = "VBox"
1886 CheckForQt5Sub = UnixSlashes(PathAbs(strPathQt5))
1887 end if
1888 end if
1889 end if
1890end function
1891
1892
1893''
1894' Checks for python.
1895'
1896function CheckForPython(strOptPython)
1897 dim strPathPython, arrVersions, strVer, str
1898 PrintHdr "Python"
1899 CheckForPython = False
1900
1901 '
1902 ' Locate it.
1903 '
1904 strPathPython = CheckForPythonSub(strOptPython)
1905 if strPathPython = "" then
1906 arrVersions = Array("3.12", "3.11", "3.10", "3.9", "3.8", "3.7", "3.6", "3.5", "2.7")
1907 for each strVer in arrVersions
1908 strPathPython = CheckForPythonSub(LogRegGetString("HKLM\SOFTWARE\Python\PythonCore\" & strVer & "\InstallPath\"))
1909 if strPathPython <> "" then exit for
1910 next
1911 end if
1912 if strPathPython = "" then strPathPython = CheckForPythonSub(PathStripFilename(Which("python.exe")))
1913
1914 '
1915 ' Output config & result.
1916 '
1917 CheckForPython = strPathPython <> ""
1918 if CheckForPython then
1919 CfgPrintAssign "VBOX_BLD_PYTHON", strPathPython
1920 PrintResult "Python", strPathPython
1921 else
1922 PrintResultMsg "Python", "not found"
1923 end if
1924end function
1925
1926function CheckForPythonSub(strPathPython)
1927 CheckForPythonSub = ""
1928 if strPathPython <> "" then
1929 if LogFileExists(strPathPython, "python.exe") _
1930 and LogDirExists(strPathPython & "/DLLs") _
1931 then
1932 CheckForPythonSub = UnixSlashes(PathAbs(strPathPython & "/python.exe"))
1933 end if
1934 end if
1935end function
1936
1937
1938''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
1939' Main function and usage '
1940''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
1941
1942''
1943' Show usage.
1944'
1945sub usage
1946 Print "Usage: cscript configure.vbs [options]"
1947 Print ""
1948 Print "Configuration:"
1949 Print " -h, --help Display this."
1950 Print " --target-arch=x86|amd64 The target architecture."
1951 Print " --continue-on-error Do not stop on errors."
1952 Print " --internal-last Check internal tools (tools/win.*) last."
1953 Print " --internal-first Check internal tools (tools/win.*) first (default)."
1954 Print ""
1955 Print "Components:"
1956 Print " --disable-COM Disables all frontends and API."
1957 Print " --disable-SDL Disables the SDL frontend."
1958 Print " --disable-UDPTunnel"
1959 Print " --disable-pylint Disable use of pylint."
1960 Print ""
1961 Print "Locations:"
1962 Print " --with-kBuild=PATH Where kBuild is to be found."
1963 Print " --with-libSDL=PATH Where libSDL is to be found."
1964 Print " --with-Qt5=PATH Where Qt5 is to be found (optional)."
1965 Print " --with-DDK=PATH Where the WDK is to be found."
1966 Print " --with-SDK=PATH Where the Windows SDK is to be found."
1967 Print " --with-SDK10=PATH Where the Windows 10 SDK/WDK is to be found."
1968 Print " --with-VC=PATH Where the Visual C++ compiler is to be found."
1969 Print " (Expecting bin, include and lib subdirs.)"
1970 Print " --with-VC-Common=PATH Maybe needed for 2015 and older to"
1971 Print " locate the Common7 directory."
1972 Print " --with-python=PATH The python to use."
1973 Print " --with-midl=PATH Where midl.exe is to be found."
1974 Print " --with-yasm=PATH Where YASM is to be found."
1975 Print " --with-nasm=PATH Where NASM is to be found (optional)"
1976 Print " --with-openwatcom=PATH Where OpenWatcom 1.9 is to be found (optional)."
1977 Print " --with-libxml2=PATH To use a libxml2 other than the VBox one (opt)."
1978 Print " --with-openssl=PATH To use an openssl other than the VBox one (opt)."
1979 Print " --with-openssl32=PATH The 32-bit variant of openssl (optional)."
1980 Print " --with-libcurl=PATH To use a cURL other than the VBox one (optional)."
1981 Print " --with-libcurl32=PATH The 32-bit variant of cURL (optional)."
1982 Print ""
1983 Print " --append-tools-dir=PATH, --prepend-tools-dir=PATH"
1984 Print " Adds an alternative tools directory to search."
1985 Print " --append-tools-dir=PATH, --prepend-prog-files=PATH"
1986 Print " Adds an alternative Program Files dir to search."
1987 Print " --append-ewdk-drive=DRIVE, --prepend-ewdk-drive=DRIVE"
1988 Print " Adds an EWDK drive the search list."
1989end sub
1990
1991
1992''
1993' The main() like function.
1994'
1995function Main
1996 dim strOutput
1997
1998 '
1999 ' Write the log header and check that we're not using wscript.
2000 '
2001 LogInit
2002 if UCase(Right(Wscript.FullName, 11)) = "WSCRIPT.EXE" then
2003 Wscript.Echo "This script must be run under CScript."
2004 Main = 1
2005 exit function
2006 end if
2007 SelfTest
2008
2009 '
2010 ' Parse arguments.
2011 '
2012 strOptDDK = ""
2013 strOptkBuild = ""
2014 strOptlibSDL = ""
2015 strOptQt5 = ""
2016 strOptQt5Infix = ""
2017 strOptSDK10 = ""
2018 strOptSDK10Version = ""
2019 strOptVC = ""
2020 strOptVCCommon = ""
2021 strOptMidl = ""
2022 strOptYasm = ""
2023 strOptNasm = ""
2024 strOptOpenWatcom = ""
2025 strOptXml2 = ""
2026 strOptSsl = ""
2027 strOptSsl32 = ""
2028 strOptCurl = ""
2029 strOptCurl32 = ""
2030 strOptPython = ""
2031 blnOptDisableCOM = False
2032 blnOptDisableUDPTunnel = False
2033 blnOptDisableSDL = False
2034 for i = 1 to Wscript.Arguments.Count
2035 dim str, strArg, strPath
2036
2037 ' Separate argument and path value
2038 str = Wscript.Arguments.item(i - 1)
2039 if InStr(1, str, "=") > 0 then
2040 strArg = Mid(str, 1, InStr(1, str, "=") - 1)
2041 strPath = Mid(str, InStr(1, str, "=") + 1)
2042 if strPath = "" then MsgFatal "Syntax error! Argument #" & i & " is missing the path."
2043 else
2044 strArg = str
2045 strPath = ""
2046 end if
2047
2048 ' Process the argument
2049 select case LCase(strArg)
2050 ' --with-something:
2051 case "--with-ddk"
2052 strOptDDK = strPath
2053 case "--with-dxsdk"
2054 MsgWarning "Ignoring --with-dxsdk (the DirectX SDK is no longer required)."
2055 case "--with-kbuild"
2056 strOptkBuild = strPath
2057 case "--with-libsdl"
2058 strOptlibSDL = strPath
2059 case "--with-mingw32"
2060 ' ignore
2061 case "--with-mingw-w64"
2062 ' ignore
2063 case "--with-qt5"
2064 strOptQt5 = strPath
2065 case "--with-qt5-infix"
2066 strOptQt5Infix = strPath
2067 case "--with-sdk"
2068 MsgWarning "Ignoring --with-sdk (the legacy Platform SDK is no longer required)."
2069 case "--with-sdk10"
2070 strOptSDK10 = strPath
2071 case "--with-sdk10-version"
2072 strOptSDK10Version = strPath
2073 case "--with-vc"
2074 strOptVC = strPath
2075 case "--with-vc-common"
2076 strOptVCCommon = strPath
2077 case "--with-vc-express-edition"
2078 ' ignore
2079 case "--with-w32api"
2080 ' ignore
2081 case "--with-midl"
2082 strOptMidl = strPath
2083 case "--with-yasm"
2084 strOptYasm = strPath
2085 case "--with-nasm"
2086 strOptNasm = strPath
2087 case "--with-openwatcom"
2088 strOptOpenWatcom = strPath
2089 case "--with-libxml2"
2090 strOptXml2 = strPath
2091 case "--with-openssl"
2092 strOptSsl = strPath
2093 case "--with-openssl32"
2094 strOptSsl32 = strPath
2095 case "--with-libcurl"
2096 strOptCurl = strPath
2097 case "--with-libcurl32"
2098 strOptCurl32 = strPath
2099 case "--with-python"
2100 strOptPython = strPath
2101
2102 ' Search lists.
2103 case "--append-tools-dir"
2104 g_arrToolsDirs = ArrayAppend(g_arrPathDev, strPath)
2105 case "--prepend-tools-dir"
2106 g_arrToolsDirs = ArrayPrepend(g_arrPathDev, strPath)
2107 case "--append-prog-files"
2108 g_arrProgramFiles = ArrayAppend(g_arrProgramFiles, strPath)
2109 case "--prepend-prog-files"
2110 g_arrProgramFiles = ArrayPrepend(g_arrProgramFiles, strPath)
2111 case "--append-ewdk-drive"
2112 g_arrProgramFiles = ArrayAppend(g_arrProgramFiles, strPath & "\Program Files")
2113 case "--prepend-ewdk-drive"
2114 g_arrProgramFiles = ArrayPrepend(g_arrProgramFiles, strPath & "\Program Files")
2115
2116 ' --disable-something/--enable-something
2117 case "--disable-com"
2118 blnOptDisableCOM = True
2119 case "--enable-com"
2120 blnOptDisableCOM = False
2121 case "--disable-udptunnel"
2122 blnOptDisableUDPTunnel = True
2123 case "--enable-udptunnel"
2124 blnOptDisableUDPTunnel = False
2125 case "--disable-sdl"
2126 blnOptDisableSDL = True
2127 case "--endable-sdl"
2128 blnOptDisableSDL = False
2129 case "--disable-pylint"
2130 blnOptDisablePylint = True
2131 case "--enable-pylint"
2132 blnOptDisablePylint = False
2133
2134 ' Other stuff.
2135 case "--continue-on-error"
2136 g_blnContinueOnError = True
2137 case "--internal-first"
2138 g_blnInternalFirst = True
2139 case "--internal-last"
2140 g_blnInternalFirst = False
2141 case "--target-arch"
2142 g_strTargetArch = strPath
2143 case "-h", "--help", "-?"
2144 usage
2145 Main = 0
2146 exit function
2147 case else
2148 Wscript.echo "syntax error: Unknown option '" & str &"'."
2149 usage
2150 Main = 2
2151 exit function
2152 end select
2153 next
2154
2155 '
2156 ' Initialize output files.
2157 '
2158 CfgInit
2159 EnvInit
2160
2161 '
2162 ' Check that the Shell function is sane.
2163 '
2164 g_objShell.Environment("PROCESS")("TESTING_ENVIRONMENT_INHERITANCE") = "This works"
2165 if Shell("set TESTING_ENVIRONMENT_INHERITANC", False, strOutput) <> 0 then ' The 'E' is missing on purpose (4nt).
2166 MsgFatal "shell execution test failed!"
2167 end if
2168 if strOutput <> "TESTING_ENVIRONMENT_INHERITANCE=This works" & CHR(13) & CHR(10) then
2169 Print "Shell test Test -> '" & strOutput & "'"
2170 MsgFatal "shell inheritance or shell execution isn't working right. Make sure you use cmd.exe."
2171 end if
2172 g_objShell.Environment("PROCESS")("TESTING_ENVIRONMENT_INHERITANCE") = ""
2173 Print "Shell inheritance test: OK"
2174
2175 '
2176 ' Do the checks.
2177 '
2178 if blnOptDisableCOM = True then
2179 DisableCOM "--disable-com"
2180 end if
2181 if blnOptDisableUDPTunnel = True then
2182 DisableUDPTunnel "--disable-udptunnel"
2183 end if
2184 if blnOptDisablePylint = True then
2185 CfgPrintAssign "override VBOX_WITH_PYLINT", ""
2186 end if
2187 CheckSourcePath
2188 CheckForkBuild strOptkBuild
2189 CheckForWinDDK strOptDDK
2190 CheckForVisualCPP strOptVC, strOptVCCommon
2191 CheckForSDK10 strOptSDK10, strOptSDK10Version
2192 CheckForMidl strOptMidl
2193 CheckForYasm strOptYasm
2194 CheckForNasm strOptNasm
2195 CheckForOpenWatcom strOptOpenWatcom
2196 if blnOptDisableSDL = True then
2197 DisableSDL "--disable-sdl"
2198 else
2199 CheckForlibSDL strOptlibSDL
2200 end if
2201 CheckForXml2 strOptXml2
2202 CheckForSsl strOptSsl, False
2203 if g_strTargetArch = "amd64" then
2204 ' 32-bit openssl required as well
2205 CheckForSsl strOptSsl32, True
2206 end if
2207 CheckForCurl strOptCurl, False
2208 if g_strTargetArch = "amd64" then
2209 ' 32-bit Curl required as well
2210 CheckForCurl strOptCurl32, True
2211 end if
2212 CheckForQt strOptQt5, strOptQt5Infix
2213 CheckForPython strOptPython
2214 CfgPrintAssign "VBOX_WITH_LIBVPX", "" '' @todo look for libvpx 1.1.0+
2215 CfgPrintAssign "VBOX_WITH_LIBOPUS", "" '' @todo look for libopus 1.2.1+
2216
2217 EnvPrintAppend "PATH", DosSlashes(g_strPath & "\tools\win." & g_strHostArch & "\bin"), ";"
2218 if g_strHostArch = "amd64" then
2219 EnvPrintAppend "PATH", DosSlashes(g_strPath & "\tools\win.x86\bin"), ";"
2220 else
2221 EnvPrintCleanup "PATH", DosSlashes(g_strPath & "\tools\win.amd64\bin"), ";"
2222 end if
2223
2224 Print ""
2225 Print "Execute env.bat once before you start to build VBox:"
2226 Print ""
2227 Print " env.bat"
2228 Print " kmk"
2229 Print ""
2230 if g_rcScript <> 0 then
2231 Print "Warning: ignored errors. See above or in configure.log."
2232 end if
2233
2234 Main = g_rcScript
2235end function
2236
2237'
2238' What crt0.o typically does:
2239'
2240WScript.Quit(Main())
2241
Note: See TracBrowser for help on using the repository browser.

© 2024 Oracle Support Privacy / Do Not Sell My Info Terms of Use Trademark Policy Automated Access Etiquette