configure.vbs@ 5999

Last change on this file since 5999 was 5999, checked in by vboxsync, 17 years ago
The Giant CDDL Dual-License Header Change.
Property svn:eol-style set to `CRLF` Property svn:keywords set to `Id`
File size: 57.0 KB

Line
1	' $Id: configure.vbs 5999 2007-12-07 15:05:06Z vboxsync $
2	'' @file
3	' The purpose of this script is to check for all external tools, headers, and
4	' libraries VBox OSE depends on.
5	'
6	' The script generates the build configuration file 'AutoConfig.kmk' and the
7	' environment setup script 'env.bat'. A log of what has been done is
8	' written to 'configure.log'.
9	'
10
11	'
12	' Copyright (C) 2006-2007 innotek GmbH
13	'
14	' This file is part of VirtualBox Open Source Edition (OSE), as
15	' available from http://www.virtualbox.org. This file is free software;
16	' you can redistribute it and/or modify it under the terms of the GNU
17	' General Public License (GPL) as published by the Free Software
18	' Foundation, in version 2 as it comes in the "COPYING" file of the
19	' VirtualBox OSE distribution. VirtualBox OSE is distributed in the
20	' hope that it will be useful, but WITHOUT ANY WARRANTY of any kind.
21	'
22
23
24	'*****************************************************************************
25	'* Global Variables *
26	'*****************************************************************************
27	dim g_strPath, g_strEnvFile, g_strLogFile, g_strCfgFile, g_strShellOutput
28	g_strPath = Left(Wscript.ScriptFullName, Len(Wscript.ScriptFullName) - Len("\configure.vbs"))
29	g_strEnvFile = g_strPath & "\env.bat"
30	g_strCfgFile = g_strPath & "\AutoConfig.kmk"
31	g_strLogFile = g_strPath & "\configure.log"
32	'g_strTmpFile = g_strPath & "\configure.tmp"
33
34	dim g_objShell, g_objFileSys
35	Set g_objShell = WScript.CreateObject("WScript.Shell")
36	Set g_objFileSys = WScript.CreateObject("Scripting.FileSystemObject")
37
38	dim g_strPathkBuild, g_strPathkBuildBin, g_strPathDev, g_strPathVCC, g_strPathPSDK, g_strPathDDK, g_strSubOutput
39	g_strPathkBuild = ""
40	g_strPathDev = ""
41	g_strPathVCC = ""
42	g_strPathPSDK = ""
43	g_strPathDDK = ""
44
45	dim g_blnDisableCOM, g_strDisableCOM
46	g_blnDisableCOM = False
47	g_strDisableCOM = ""
48
49	' The internal mode is primarily for skipping the xerces and xalan monsters.
50	dim g_blnInternalMode
51	g_blnInternalMode = False
52
53
54
55	''
56	' Converts to unix slashes
57	function UnixSlashes(str)
58	UnixSlashes = replace(str, "\", "/")
59	end function
60
61
62	''
63	' Converts to dos slashes
64	function DosSlashes(str)
65	DosSlashes = replace(str, "/", "\")
66	end function
67
68
69	''
70	' Read a file (typically the tmp file) into a string.
71	function FileToString(strFilename)
72	const ForReading = 1, TristateFalse = 0
73	dim objLogFile, str
74
75	set objFile = g_objFileSys.OpenTextFile(DosSlashes(strFilename), ForReading, False, TristateFalse)
76	str = objFile.ReadAll()
77	objFile.Close()
78
79	FileToString = str
80	end function
81
82
83	''
84	' Deletes a file
85	sub FileDelete(strFilename)
86	if g_objFileSys.FileExists(DosSlashes(strFilename)) then
87	g_objFileSys.DeleteFile(DosSlashes(strFilename))
88	end if
89	end sub
90
91
92	''
93	' Appends a line to an ascii file.
94	sub FileAppendLine(strFilename, str)
95	const ForAppending = 8, TristateFalse = 0
96	dim objFile
97
98	set objFile = g_objFileSys.OpenTextFile(DosSlashes(strFilename), ForAppending, True, TristateFalse)
99	objFile.WriteLine(str)
100	objFile.Close()
101	end sub
102
103
104	''
105	' Checks if the file exists.
106	function FileExists(strFilename)
107	FileExists = g_objFileSys.FileExists(DosSlashes(strFilename))
108	end function
109
110
111	''
112	' Checks if the directory exists.
113	function DirExists(strDirectory)
114	DirExists = g_objFileSys.FolderExists(DosSlashes(strDirectory))
115	end function
116
117	''
118	' Gets a value from the registry. Returns "" if string wasn't found / valid.
119	function RegGetString(strName)
120	RegGetString = ""
121	On Error Resume Next
122	RegGetString = g_objShell.RegRead(strName)
123	end function
124
125	''
126	' Returns an array of subkey strings.
127	function RegEnumSubKeys(strRoot, strKeyPath)
128	const HKEY_LOCAL_MACHINE = &H80000002
129	const HKEY_CURRENT_USER = &H80000001
130	dim objReg, iRoot
131	set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
132
133	select case strRoot
134	case "HKLM"
135	iRoot = HKEY_LOCAL_MACHINE
136	case "HKCU"
137	iRoot = HKEY_CURRENT_USER
138	case else
139	MsgFatal "RegEnumSubKeys: Unknown root: " & strRoot
140	end select
141
142	On Error Resume Next
143	rc = objReg.EnumKey(iRoot, strKeyPath, arrSubKeys)
144	if rc = 0 then
145	RegEnumSubKeys = arrSubKeys
146	else
147	RegEnumSubKeys = Array()
148	end if
149	end function
150
151
152	''
153	' Gets the commandline used to invoke the script.
154	function GetCommandline()
155	dim str, i
156
157	'' @todo find an api for querying it instead of reconstructing it like this...
158	GetCommandline = "cscript configure.vbs"
159	for i = 1 to WScript.Arguments.Count
160	str = WScript.Arguments.Item(i - 1)
161	if str = "" then
162	str = """"""
163	elseif (InStr(1, str, " ")) then
164	str = """" & str & """"
165	end if
166	GetCommandline = GetCommandline & " " & str
167	next
168	end function
169
170
171	''
172	' Gets an environment variable.
173	function EnvGet(strName)
174	EnvGet = g_objShell.Environment("PROCESS")(strName)
175	end function
176
177
178	''
179	' Sets an environment variable.
180	sub EnvSet(strName, strValue)
181	g_objShell.Environment("PROCESS")(strName) = strValue
182	LogPrint "EnvSet: " & strName & "=" & strValue
183	end sub
184
185
186	''
187	' Appends a string to an environment variable
188	sub EnvAppend(strName, strValue)
189	dim str
190	str = g_objShell.Environment("PROCESS")(strName)
191	g_objShell.Environment("PROCESS")(strName) = str & strValue
192	LogPrint "EnvAppend: " & strName & "=" & str & strValue
193	end sub
194
195
196	''
197	' Prepends a string to an environment variable
198	sub EnvPrepend(strName, strValue)
199	dim str
200	str = g_objShell.Environment("PROCESS")(strName)
201	g_objShell.Environment("PROCESS")(strName) = strValue & str
202	LogPrint "EnvPrepend: " & strName & "=" & strValue & str
203	end sub
204
205
206	''
207	' Get the path of the parent directory. Returns root if root was specified.
208	' Expects abs path.
209	function PathParent(str)
210	PathParent = g_objFileSys.GetParentFolderName(DosSlashes(str))
211	end function
212
213
214	''
215	' Strips the filename from at path.
216	function PathStripFilename(str)
217	PathStripFilename = g_objFileSys.GetParentFolderName(DosSlashes(str))
218	end function
219
220
221	''
222	' Get the abs path, use the short version if necessary.
223	function PathAbs(str)
224	PathAbs = g_objFileSys.GetAbsolutePathName(DosSlashes(str))
225	if (InStr(1, PathAbs, " ") > 0) _
226	Or (InStr(1, PathAbs, "&") > 0) _
227	Or (InStr(1, PathAbs, "$") > 0) _
228	then
229	if FileExists(PathAbs) then
230	dim objFile
231	set objFile = g_objFileSys.GetFile(PathAbs)
232	PathAbs = objFile.ShortPath
233	elseif DirExists(PathAbs) then
234	dim objFolder
235	set objFolder = g_objFileSys.GetFolder(PathAbs)
236	PathAbs = objFolder.ShortPath
237	else
238	' ignore non-existing paths.
239	end if
240	end if
241
242
243	if (FileExists(PathAbs) Or DirExists(PathAbs)) _
244	And ( (InStr(1, PathAbs, " ") > 0) _
245	Or (InStr(1, PathAbs, "&") > 0) _
246	Or (InStr(1, PathAbs, "$") > 0)) _
247	then
248	MsgFatal "PathAbs(" & str & ") attempted to return filename with problematic " _
249	& "characters in it (" & PathAbs & "). The tool/sdk referenced will probably " _
250	& "need to be copied or reinstalled to a location without 'spaces', '$', ';' " _
251	& "or '&' in the path name. (Unless it's a problem with this script of course...)"
252	end if
253	end function
254
255
256	''
257	' Executes a command in the shell catching output in g_strShellOutput
258	function Shell(strCommand, blnBoth)
259	dim strShell, strCmdline, objExec, str
260
261	strShell = g_objShell.ExpandEnvironmentStrings("%ComSpec%")
262	if blnBoth = true then
263	strCmdline = strShell & " /c " & strCommand & " 2>&1"
264	else
265	strCmdline = strShell & " /c " & strCommand & " 2>nul"
266	end if
267
268	LogPrint "# Shell: " & strCmdline
269	Set objExec = g_objShell.Exec(strCmdLine)
270	g_strShellOutput = objExec.StdOut.ReadAll()
271	objExec.StdErr.ReadAll()
272	do while objExec.Status = 0
273	Wscript.Sleep 20
274	g_strShellOutput = g_strShellOutput & objExec.StdOut.ReadAll()
275	objExec.StdErr.ReadAll()
276	loop
277
278	LogPrint "# Status: " & objExec.ExitCode
279	LogPrint "# Start of Output"
280	LogPrint g_strShellOutput
281	LogPrint "# End of Output"
282
283	Shell = objExec.ExitCode
284	end function
285
286
287	''
288	' Try find the specified file in the path.
289	function Which(strFile)
290	dim strPath, iStart, iEnd, str
291
292	' the path
293	strPath = EnvGet("Path")
294	iStart = 1
295	do while iStart <= Len(strPath)
296	iEnd = InStr(iStart, strPath, ";")
297	if iEnd <= 0 then iEnd = Len(strPath) + 1
298	if iEnd > iStart then
299	str = Mid(strPath, iStart, iEnd - iStart) & "/" & strFile
300	if FileExists(str) then
301	Which = str
302	exit function
303	end if
304	end if
305	iStart = iEnd + 1
306	loop
307
308	' registry or somewhere?
309
310	Which = ""
311	end function
312
313
314	''
315	' Append text to the log file and echo it to stdout
316	sub Print(str)
317	LogPrint str
318	Wscript.Echo str
319	end sub
320
321
322	''
323	' Prints a test header
324	sub PrintHdr(strTest)
325	LogPrint "*** Checking for " & strTest & " ***"
326	Wscript.Echo "Checking for " & StrTest & "..."
327	end sub
328
329
330	''
331	' Prints a success message
332	sub PrintResult(strTest, strResult)
333	LogPrint "** " & strTest & ": " & strResult
334	Wscript.Echo " Found "& strTest & ": " & strResult
335	end sub
336
337
338	''
339	' Warning message.
340	sub MsgWarning(strMsg)
341	Print "warning: " & strMsg
342	end sub
343
344
345	''
346	' Fatal error.
347	sub MsgFatal(strMsg)
348	Print "fatal error: " & strMsg
349	Wscript.Quit
350	end sub
351
352
353	''
354	' Error message, fatal unless flag to ignore errors is given.
355	sub MsgError(strMsg)
356	Print "error: " & strMsg
357	if g_blnInternalMode = False then
358	Wscript.Quit
359	end if
360	end sub
361
362
363	''
364	' Write a log header with some basic info.
365	sub LogInit
366	FileDelete g_strLogFile
367	LogPrint "# Log file generated by " & Wscript.ScriptFullName
368	for i = 1 to WScript.Arguments.Count
369	LogPrint "# Arg #" & i & ": " & WScript.Arguments.Item(i - 1)
370	next
371	if Wscript.Arguments.Count = 0 then
372	LogPrint "# No arguments given"
373	end if
374	LogPrint "# Reconstructed command line: " & GetCommandline()
375
376	' some Wscript stuff
377	LogPrint "# Wscript properties:"
378	LogPrint "# ScriptName: " & Wscript.ScriptName
379	LogPrint "# Version: " & Wscript.Version
380	LogPrint "# Build: " & Wscript.BuildVersion
381	LogPrint "# Name: " & Wscript.Name
382	LogPrint "# Full Name: " & Wscript.FullName
383	LogPrint "# Path: " & Wscript.Path
384	LogPrint "#"
385
386
387	' the environment
388	LogPrint "# Environment:"
389	dim objEnv
390	for each strVar in g_objShell.Environment("PROCESS")
391	LogPrint "# " & strVar
392	next
393	LogPrint "#"
394	end sub
395
396
397	''
398	' Append text to the log file.
399	sub LogPrint(str)
400	FileAppendLine g_strLogFile, str
401	'Wscript.Echo "dbg: " & str
402	end sub
403
404
405	''
406	' Checks if the file exists and logs failures.
407	function LogFileExists(strPath, strFilename)
408	LogFileExists = FileExists(strPath & "/" & strFilename)
409	if LogFileExists = False then
410	LogPrint "Testing '" & strPath & "': " & strFilename & " not found"
411	end if
412
413	end function
414
415
416	''
417	' Finds the first file matching the pattern.
418	' If no file is found, log the failure.
419	function LogFindFile(strPath, strPattern)
420	dim str
421
422	'
423	' Yes, there are some facy database kinda interface to the filesystem
424	' however, breaking down the path and constructing a usable query is
425	' too much hassle. So, we'll do it the unix way...
426	'
427	if Shell("dir /B """ & DosSlashes(strPath) & "\" & DosSlashes(strPattern) & """", True) = 0 _
428	And InStr(1, g_strShellOutput, Chr(13)) > 1 _
429	then
430	' return the first word.
431	LogFindFile = Left(g_strShellOutput, InStr(1, g_strShellOutput, Chr(13)) - 1)
432	else
433	LogPrint "Testing '" & strPath & "': " & strPattern & " not found"
434	LogFindFile = ""
435	end if
436	end function
437
438
439	''
440	' Initializes the config file.
441	sub CfgInit
442	FileDelete g_strCfgFile
443	CfgPrint "# -- Makefile --"
444	CfgPrint "#"
445	CfgPrint "# Build configuration generated by " & GetCommandline()
446	CfgPrint "#"
447	if g_blnInternalMode = False then
448	CfgPrint "VBOX_OSE := 1"
449	end if
450	end sub
451
452
453	''
454	' Prints a string to the config file.
455	sub CfgPrint(str)
456	FileAppendLine g_strCfgFile, str
457	end sub
458
459
460	''
461	' Initializes the environment batch script.
462	sub EnvInit
463	FileDelete g_strEnvFile
464	EnvPrint "@echo off"
465	EnvPrint "rem"
466	EnvPrint "rem Environment setup script generated by " & GetCommandline()
467	EnvPrint "rem"
468	end sub
469
470
471	''
472	' Prints a string to the environment batch script.
473	sub EnvPrint(str)
474	FileAppendLine g_strEnvFile, str
475	end sub
476
477
478	''
479	' No COM
480	sub DisableCOM(strReason)
481	if g_blnDisableCOM = False then
482	LogPrint "Disabled COM components: " & strReason
483	g_blnDisableCOM = True
484	g_strDisableCOM = strReason
485	CfgPrint "VBOX_WITH_MAIN="
486	CfgPrint "VBOX_WITH_QTGUI="
487	CfgPrint "VBOX_WITH_VBOXSDL="
488	CfgPrint "VBOX_WITH_DEBUGGER_GUI="
489	CfgPrint "VBOX_WITHOUT_COM=1"
490	end if
491	end sub
492
493
494	''
495	' Checks the the path doesn't contain characters the tools cannot deal with.
496	sub CheckSourcePath
497	dim sPwd
498
499	sPwd = PathAbs(g_strPath)
500	if InStr(1, sPwd, " ") > 0 then
501	MsgError "Source path contains spaces! Please move it. (" & sPwd & ")"
502	end if
503	if InStr(1, sPwd, "$") > 0 then
504	MsgError "Source path contains the '$' char! Please move it. (" & sPwd & ")"
505	end if
506	if InStr(1, sPwd, "%") > 0 then
507	MsgError "Source path contains the '%' char! Please move it. (" & sPwd & ")"
508	end if
509	if InStr(1, sPwd, Chr(10)) > 0 _
510	Or InStr(1, sPwd, Chr(13)) > 0 _
511	Or InStr(1, sPwd, Chr(9)) > 0 _
512	then
513	MsgError "Source path contains control characters! Please move it. (" & sPwd & ")"
514	end if
515	Print "Source path: OK"
516	end sub
517
518
519	''
520	' Checks for kBuild - very simple :)
521	sub CheckForkBuild(strOptkBuild)
522	PrintHdr "kBuild"
523
524	'
525	' Check if there is a 'kmk' in the path somewhere without
526	' any PATH_KBUILD* stuff around.
527	'
528	blnNeedEnvVars = True
529	g_strPathkBuild = strOptkBuild
530	g_strPathkBuildBin = ""
531	if (g_strPathkBuild = "") _
532	And (EnvGet("PATH_KBUILD") = "") _
533	And (EnvGet("PATH_KBUILD_BIN") = "") _
534	And (Shell("kmk.exe --version", True) = 0) _
535	And (InStr(1,g_strShellOutput, "kBuild Make 0.1") > 0) _
536	And (InStr(1,g_strShellOutput, "PATH_KBUILD") > 0) _
537	And (InStr(1,g_strShellOutput, "PATH_KBUILD_BIN") > 0) then
538	'' @todo Need to parse out the PATH_KBUILD and PATH_KBUILD_BIN values to complete the other tests.
539	'blnNeedEnvVars = False
540	MsgWarning "You've installed kBuild it seems. configure.vbs hasn't been updated to " _
541	& "deal with that yet and will use the one it ships with. Sorry."
542	end if
543
544	'
545	' Check for the PATH_KBUILD env.var. and fall back on root/kBuild otherwise.
546	'
547	if g_strPathkBuild = "" then
548	g_strPathkBuild = EnvGet("PATH_KBUILD")
549	if (g_strPathkBuild <> "") and (FileExists(g_strPathkBuild & "/footer.kmk") = False) then
550	MsgWarning "Ignoring incorrect kBuild path (PATH_KBUILD=" & g_strPathkBuild & ")"
551	g_strPathkBuild = ""
552	end if
553
554	if g_strPathkBuild = "" then
555	g_strPathkBuild = g_strPath & "/kBuild"
556	end if
557	end if
558
559	g_strPathkBuild = UnixSlashes(PathAbs(g_strPathkBuild))
560
561	'
562	' Determin the location of the kBuild binaries.
563	'
564	if g_strPathkBuildBin = "" then
565	dim str2
566	if EnvGet("PROCESSOR_ARCHITECTURE") = "x86" then
567	g_strPathkBuildBin = g_strPathkBuild & "/bin/win.x86"
568	else ' boldly assumes there is only x86 and amd64.
569	g_strPathkBuildBin = g_strPathkBuild & "/bin/win.amd64"
570	if FileExists(g_strPathkBuild & "/kmk.exe") = False then
571	g_strPathkBuildBin = g_strPathkBuild & "/bin/win.x86"
572	end if
573	end if
574	if FileExists(g_strPathkBuild & "/kmk.exe") = False then
575	g_strPathkBuildBin = g_strPathkBuild & "/bin/win.x86"
576	end if
577	end if
578
579	'
580	' Perform basic validations of the kBuild installation.
581	'
582	if (FileExists(g_strPathkBuild & "/footer.kmk") = False) _
583	Or (FileExists(g_strPathkBuild & "/header.kmk") = False) _
584	Or (FileExists(g_strPathkBuild & "/rules.kmk") = False) then
585	MsgFatal "Can't find valid kBuild at '" & g_strPathkBuild & "'. Either there is an " _
586	& "incorrect PATH_KBUILD in the environment or the checkout didn't succeed."
587	exit sub
588	end if
589	if (FileExists(g_strPathkBuildBin & "/kmk.exe") = False) _
590	Or (FileExists(g_strPathkBuildBin & "/kmk_ash.exe") = False) then
591	MsgFatal "Can't find valid kBuild binaries at '" & g_strPathkBuildBin & "'. Either there is an " _
592	& "incorrect PATH_KBUILD in the environment or the checkout didn't succeed."
593	exit sub
594	end if
595
596	if (Shell(DosSlashes(g_strPathkBuildBin & "/kmk.exe") & " --version", True) <> 0) Then
597	MsgFatal "Can't execute '" & g_strPathkBuildBin & "/kmk.exe --version'. check configure.log for the out."
598	exit sub
599	end if
600
601	'
602	' Check for env.vars that kBuild uses.
603	'
604	str = EnvGet("BUILD_TYPE")
605	if (str <> "") _
606	And (InStr(1, "\|release\|debug\|profile\|kprofile", str) <= 0) then
607	EnvPrint "set BUILD_TYPE=release"
608	EnvSet "BUILD_TYPE", "release"
609	MsgWarning "Found unknown BUILD_TYPE value '" & str &"' in your environment. Setting it to 'release'."
610	end if
611
612	str = EnvGet("BUILD_TARGET")
613	if (str <> "") _
614	And (InStr(1, "win\|win32\|win64", str) <= 0) then '' @todo later only 'win' will be valid. remember to fix this check!
615	EnvPrint "set BUILD_TARGET=win"
616	EnvSet "BUILD_TARGET", "win"
617	MsgWarning "Found unknown BUILD_TARGET value '" & str &"' in your environment. Setting it to 'win32'."
618	end if
619
620	str = EnvGet("BUILD_TARGET_ARCH")
621	if (str <> "") _
622	And (InStr(1, "x86\|amd64", str) <= 0) then
623	EnvPrint "set BUILD_TARGET_ARCH=x86"
624	EnvSet "BUILD_TARGET_ARCH", "x86"
625	MsgWarning "Found unknown BUILD_TARGET_ARCH value '" & str &"' in your environment. Setting it to 'x86'."
626	end if
627
628	str = EnvGet("BUILD_TARGET_CPU")
629	' perhaps a bit pedantic this since this isn't clearly define nor used much...
630	if (str <> "") _
631	And (InStr(1, "i386\|i486\|i686\|i786\|i868\|k5\|k6\|k7\|k8", str) <= 0) then
632	EnvPrint "set BUILD_TARGET_CPU=i386"
633	EnvSet "BUILD_TARGET_CPU", "i386"
634	MsgWarning "Found unknown BUILD_TARGET_CPU value '" & str &"' in your environment. Setting it to 'i386'."
635	end if
636
637	str = EnvGet("BUILD_PLATFORM")
638	if (str <> "") _
639	And (InStr(1, "win\|win32\|win64", str) <= 0) then '' @todo later only 'win' will be valid. remember to fix this check!
640	EnvPrint "set BUILD_PLATFORM=win"
641	EnvSet "BUILD_PLATFORM", "win"
642	MsgWarning "Found unknown BUILD_PLATFORM value '" & str &"' in your environment. Setting it to 'win32'."
643	end if
644
645	str = EnvGet("BUILD_PLATFORM_ARCH")
646	if (str <> "") _
647	And (InStr(1, "x86\|amd64", str) <= 0) then
648	EnvPrint "set BUILD_PLATFORM_ARCH=x86"
649	EnvSet "BUILD_PLATFORM_ARCH", "x86"
650	MsgWarning "Found unknown BUILD_PLATFORM_ARCH value '" & str &"' in your environment. Setting it to 'x86'."
651	end if
652
653	str = EnvGet("BUILD_PLATFORM_CPU")
654	' perhaps a bit pedantic this since this isn't clearly define nor used much...
655	if (str <> "") _
656	And (InStr(1, "i386\|i486\|i686\|i786\|i868\|k5\|k6\|k7\|k8", str) <= 0) then
657	EnvPrint "set BUILD_PLATFORM_CPU=i386"
658	EnvSet "BUILD_PLATFORM_CPU", "i386"
659	MsgWarning "Found unknown BUILD_PLATFORM_CPU value '" & str &"' in your environment. Setting it to 'i386'."
660	end if
661
662	'
663	' If PATH_DEV is set, check that it's pointing to something useful.
664	'
665	str = EnvGet("PATH_DEV")
666	g_strPathDev = str
667	if (str <> "") _
668	And False then '' @todo add some proper tests here.
669	strNew = UnixSlashes(g_strPath & "/tools")
670	EnvPrint "set PATH_DEV=" & strNew
671	EnvSet "PATH_DEV", strNew
672	MsgWarning "Found PATH_DEV='" & str &"' in your environment. Setting it to '" & strNew & "'."
673	g_strPathDev = strNew
674	end if
675	if g_strPathDev = "" then g_strPathDev = UnixSlashes(g_strPath & "/tools")
676
677	'
678	' Write PATH_KBUILD to the environment script if necessary.
679	'
680	if blnNeedEnvVars = True then
681	EnvPrint "set PATH_KBUILD=" & g_strPathkBuild
682	EnvSet "PATH_KBUILD", g_strPathkBuild
683	EnvPrint "set PATH=" & g_strPathkBuildBin & ";%PATH%"
684	EnvPrepend "PATH", g_strPathkBuildBin & ";"
685	end if
686
687	PrintResult "kBuild", g_strPathkBuild
688	PrintResult "kBuild binaries", g_strPathkBuildBin
689	end sub
690
691
692	''
693	' Checks for Visual C++ version 7 or 8.
694	sub CheckForVisualCPP(strOptVC, strOptVCCommon, blnOptVCExpressEdition)
695	dim strPathVC, strPathVCCommon, str, str2, blnNeedMsPDB
696	PrintHdr "Visual C++"
697
698	'
699	' Try find it...
700	'
701	strPathVC = ""
702	strPathVCCommon = ""
703	if (strPathVC = "") And (strOptVC <> "") then
704	if CheckForVisualCPPSub(strOptVC, strOptVCCommon, blnOptVCExpressEdition) then
705	strPathVC = strOptVC
706	strPathVCCommon = strOptVCCommon
707	end if
708	end if
709
710	if strPathVC = "" Then
711	strPathVC = g_strPathDev & "/win.x86/vcc/v8"
712	if CheckForVisualCPPSub(strPathVC, "", blnOptVCExpressEdition) = False then
713	strPathVC = g_strPathDev & "/win.x86/vcc/v7"
714	if CheckForVisualCPPSub(strPathVC, "", blnOptVCExpressEdition) = False then
715	strPathVC = ""
716	end if
717	end if
718	end if
719
720	if (strPathVC = "") _
721	And (Shell("cl.exe", True) = 0) then
722	str = Which("cl.exe")
723	if FileExists(PathStripFilename(strClExe) & "/build.exe") then
724	' don't know how to deal with this cl.
725	Warning "Ignoring DDK cl.exe (" & str & ")."
726	else
727	strPathVC = PathParent(PathStripFilename(str))
728	strPathVCCommon = PathParent(strPathVC) & "/Common7"
729	end if
730	end if
731
732	if strPathVC = "" then
733	str = RegGetString("HKLM\SOFTWARE\Microsoft\VisualStudio\8.0\Setup\VS\ProductDir")
734	str2 = RegGetString("HKLM\SOFTWARE\Microsoft\VisualStudio\8.0\Setup\VS\EnvironmentDirectory")
735	if str <> "" And str2 <> "" Then
736	str = str & "VC"
737	str2 = PathParent(str2)
738	if CheckForVisualCPPSub(str, str2, blnOptVCExpressEdition) then
739	strPathVC = str
740	strPathVCCommon = str2
741	end if
742	end if
743	end if
744
745	if strPathVC = "" then
746	'' @todo check what this really looks like on 7.1
747	str = RegGetString("HKLM\SOFTWARE\Microsoft\VisualStudio\7.1\Setup\VS\ProductDir")
748	str2 = RegGetString("HKLM\SOFTWARE\Microsoft\VisualStudio\7.1\Setup\VS\EnvironmentDirectory")
749	if str <> "" And str2 <> "" Then
750	str = str & "VC7"
751	str2 = PathParent(str2)
752	if CheckForVisualCPPSub(str, str2, blnOptVCExpressEdition) then
753	strPathVC = str
754	strPathVCCommon = str2
755	end if
756	end if
757	end if
758
759	if strPathVC = "" then
760	str = RegGetString("HKLM\SOFTWARE\Microsoft\VisualStudio\7.0\Setup\VS\ProductDir")
761	str2 = RegGetString("HKLM\SOFTWARE\Microsoft\VisualStudio\7.0\Setup\VS\EnvironmentDirectory")
762	if str <> "" And str2 <> "" Then
763	str = str & "VC7"
764	str2 = PathParent(str2)
765	if CheckForVisualCPPSub(str, str2, blnOptVCExpressEdition) then
766	strPathVC = str
767	strPathVCCommon = str2
768	end if
769	end if
770	end if
771
772	if strPathVC = "" then
773	str = RegGetString("HKLM\SOFTWARE\Microsoft\VisualStudio\SxS\VC7\8.0")
774	if str <> "" then
775	str2 = PathParent(str) & "/Common7"
776	if CheckForVisualCPPSub(str, str2, blnOptVCExpressEdition) then
777	strPathVC = str
778	strPathVCCommon = str2
779	end if
780	end if
781	end if
782
783	' finally check for the express edition.
784	if strPathVC = "" then
785	str = RegGetString("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft Visual C++ 2005 Express Edition - ENU\InstallLocation")
786	if str <> "" then
787	str2 = str & "Common7"
788	str = str & "VC/"
789	if CheckForVisualCPPSub(str, str2, blnOptVCExpressEdition) then
790	strPathVC = str
791	strPathVCCommon = str2
792	end if
793	end if
794	end if
795
796	if strPathVC = "" then
797	MsgError "Cannot find cl.exe (Visual C++) anywhere on your system. Check the build requirements."
798	exit sub
799	end if
800
801	'
802	' Clean up the path and determin the VC directory.
803	'
804	strPathVC = UnixSlashes(PathAbs(strPathVC))
805	g_strPathVCC = strPathVC
806
807	'
808	' Check the version.
809	' We'll have to make sure mspdbXX.dll is somewhere in the PATH.
810	'
811	if (strPathVCCommon <> "") Then
812	EnvAppend "PATH", ";" & strPathVCCommon & "/IDE"
813	end if
814	if Shell(DosSlashes(strPathVC & "/bin/cl.exe"), True) <> 0 then
815	MsgError "Executing '" & strClExe & "' (which we believe to be the Visual C++ compiler driver) failed."
816	exit sub
817	end if
818
819	if (InStr(1, g_strShellOutput, "Version 13.10") <= 0) _
820	And (InStr(1, g_strShellOutput, "Version 14.") <= 0) then
821	MsgError "The Visual C++ compiler we found ('" & strPathVC & "') isn't 7.1 or 8.0. Check the build requirements."
822	exit sub
823	end if
824
825	'
826	' Ok, emit build config variables.
827	'
828	if InStr(1, g_strShellOutput, "Version 14.") > 0 then
829	CfgPrint "VBOX_USE_VCC80 := 1"
830	CfgPrint "PATH_TOOL_VCC80 := " & g_strPathVCC
831	CfgPrint "PATH_TOOL_VCC80X86 = $(PATH_TOOL_VCC80)"
832	CfgPrint "PATH_TOOL_VCC80AMD64 = $(PATH_TOOL_VCC80)"
833	if blnOptVCExpressEdition _
834	And LogFileExists(strPathVC, "atlmfc/include/atlbase.h") = False _
835	then
836	CfgPrint "TOOL_VCC80X86_MT = $(PATH_SDK_WINPSDK)/Bin/mt.exe"
837	CfgPrint "TOOL_VCC80AMD64_MT = $(TOOL_VCC80X86_MT)"
838	CfgPrint "VBOX_WITHOUT_COMPILER_REDIST=1"
839	DisableCOM "No ATL"
840	PrintResult "Visual C++ v8 (or later) without ATL", g_strPathVCC
841	else
842	PrintResult "Visual C++ v8 (or later)", g_strPathVCC
843	end if
844	else
845	CfgPrint "PATH_TOOL_VCC70 := " & g_strPathVCC
846	if blnOptVCExpressEdition _
847	And LogFileExists(strPathVC, "atlmfc/include/atlbase.h") = False _
848	then
849	CfgPrint "VBOX_WITHOUT_COMPILER_REDIST=1"
850	DisableCOM "No ATL"
851	PrintResult "Visual C++ v7.1 without ATL", g_strPathVCC
852	else
853	PrintResult "Visual C++ v7.1", g_strPathVCC
854	end if
855	end if
856
857	' and the env.bat path fix.
858	if strPathVCCommon <> "" then
859	EnvPrint "set PATH=%PATH%;" & strPathVCCommon & "/IDE;"
860	end if
861	end sub
862
863	''
864	' Checks if the specified path points to a usable PSDK.
865	function CheckForVisualCPPSub(strPathVC, strPathVCCommon, blnOptVCExpressEdition)
866	strPathVC = UnixSlashes(PathAbs(strPathVC))
867	CheckForVisualCPPSub = False
868	LogPrint "trying: strPathVC=" & strPathVC & " strPathVCCommon=" & strPathVCCommon & " blnOptVCExpressEdition=" & blnOptVCExpressEdition
869	if LogFileExists(strPathVC, "bin/cl.exe") _
870	And LogFileExists(strPathVC, "bin/link.exe") _
871	And LogFileExists(strPathVC, "include/string.h") _
872	And LogFileExists(strPathVC, "lib/libcmt.lib") _
873	And LogFileExists(strPathVC, "lib/msvcrt.lib") _
874	then
875	if blnOptVCExpressEdition _
876	Or ( LogFileExists(strPathVC, "atlmfc/include/atlbase.h") _
877	And LogFileExists(strPathVC, "atlmfc/lib/atls.lib")) _
878	Then
879	'' @todo figure out a way we can verify the version/build!
880	CheckForVisualCPPSub = True
881	end if
882	end if
883	end function
884
885
886	''
887	' Checks for a platform SDK that works with the compiler
888	sub CheckForPlatformSDK(strOptSDK)
889	dim strPathPSDK, str
890	PrintHdr "Windows Platform SDK (recent)"
891
892	strPathPSDK = ""
893
894	' Check the supplied argument first.
895	str = strOptSDK
896	if str <> "" then
897	if CheckForPlatformSDKSub(str) then strPathPSDK = str
898	end if
899
900	' The tools location.
901	if strPathPSDK = "" then
902	str = g_strPathDev & "/win.x86/sdk/200604"
903	if CheckForPlatformSDKSub(str) then strPathPSDK = str
904	end if
905
906	if strPathPSDK = "" then
907	str = g_strPathDev & "/win.x86/sdk/200504"
908	if CheckForPlatformSDKSub(str) then strPathPSDK = str
909	end if
910
911	if strPathPSDK = "" then
912	str = g_strPathDev & "/win.x86/sdk/200209"
913	if CheckForPlatformSDKSub(str) then strPathPSDK = str
914	end if
915
916	' Look for it in the environment
917	str = EnvGet("MSSdk")
918	if (strPathPSDK = "") And (str <> "") then
919	if CheckForPlatformSDKSub(str) then strPathPSDK = str
920	end if
921
922	str = EnvGet("Mstools")
923	if (strPathPSDK = "") And (str <> "") then
924	if CheckForPlatformSDKSub(str) then strPathPSDK = str
925	end if
926
927	' Check if there is one installed with the compiler.
928	if (strPathPSDK = "") And (str <> "") then
929	str = g_strPathVCC & "/PlatformSDK"
930	if CheckForPlatformSDKSub(str) then strPathPSDK = str
931	end if
932
933	' Check the registry next.
934	arrSubKeys = RegEnumSubKeys("HKLM", "SOFTWARE\Microsoft\MicrosoftSDK\InstalledSDKs")
935	for Each strSubKey In arrSubKeys
936	str = RegGetString("HKLM\SOFTWARE\Microsoft\MicrosoftSDK\InstalledSDKs\" & strSubKey & "\Install Dir")
937	if (strPathPSDK = "") And (str <> "") then
938	if CheckForPlatformSDKSub(str) then strPathPSDK = str
939	end if
940	Next
941	arrSubKeys = RegEnumSubKeys("HKCU", "SOFTWARE\Microsoft\MicrosoftSDK\InstalledSDKs")
942	for Each strSubKey In arrSubKeys
943	str = RegGetString("HKCU\SOFTWARE\Microsoft\MicrosoftSDK\InstalledSDKs\" & strSubKey & "\Install Dir")
944	if (strPathPSDK = "") And (str <> "") then
945	if CheckForPlatformSDKSub(str) then strPathPSDK = str
946	end if
947	Next
948
949	' Give up.
950	if strPathPSDK = "" then
951	MsgError "Cannot find a suitable Platform SDK. Check configure.log and the build requirements."
952	exit sub
953	end if
954
955	'
956	' Emit the config.
957	'
958	strPathPSDK = UnixSlashes(PathAbs(strPathPSDK))
959	CfgPrint "PATH_SDK_WINPSDK := " & strPathPSDK
960	CfgPrint "PATH_SDK_WINPSDKINCS = $(PATH_SDK_WINPSDK)"
961	CfgPrint "PATH_SDK_WIN32SDK = $(PATH_SDK_WINPSDK)"
962	CfgPrint "PATH_SDK_WIN64SDK = $(PATH_SDK_WINPSDK)"
963
964	PrintResult "Windows Platform SDK", strPathPSDK
965	g_strPathPSDK = strPathPSDK
966	end sub
967
968	''
969	' Checks if the specified path points to a usable PSDK.
970	function CheckForPlatformSDKSub(strPathPSDK)
971	CheckForPlatformSDKSub = False
972	LogPrint "trying: strPathPSDK=" & strPathPSDK
973	if LogFileExists(strPathPSDK, "include/Windows.h") _
974	And LogFileExists(strPathPSDK, "lib/Kernel32.Lib") _
975	And LogFileExists(strPathPSDK, "lib/User32.Lib") _
976	then
977	CheckForPlatformSDKSub = True
978	end if
979	end function
980
981
982	''
983	' Checks for a Windows 2003 DDK that works with the compiler intrinsics.
984	sub CheckForWin2k3DDK(strOptDDK)
985	dim strPathDDK, str, strSubKeys
986	PrintHdr "Windows 2003 DDK, build 3790 or later"
987
988	'
989	' Find the DDK.
990	'
991	strPathDDK = ""
992	' The specified path.
993	if (strPathDDK = "") And (strOptDDK <> "") then
994	if CheckForWin2k3DDKSub(strOptDDK, True) then strPathDDK = strOptDDK
995	end if
996
997	' The tools location.
998	if strPathDDK = "" then
999	str = g_strPathDev & "/win.x86/ddkwin2k3/200503"
1000	if CheckForWin2k3DDKSub(str, False) then strPathDDK = str
1001	end if
1002
1003	if strPathDDK = "" then
1004	str = g_strPathDev & "/win.x86/ddkwin2k3/2004"
1005	if CheckForWin2k3DDKSub(str, False) then strPathDDK = str
1006	end if
1007
1008	if strPathDDK = "" then
1009	MsgError "Cannot find a suitable Windows 2003 DDK. Check configure.log and the build requirements."
1010	exit sub
1011	end if
1012
1013	' Check the environment
1014	str = EnvGet("DDK_INC_PATH")
1015	if (strPathDDK = "") And (str <> "") then
1016	str = PathParent(PathParent(str))
1017	if CheckForWin2k3DDKSub(str, True) then strPathDDK = str
1018	end if
1019
1020	str = EnvGet("BASEDIR")
1021	if (strPathDDK = "") And (str <> "") then
1022	if CheckForWin2k3DDKSub(str, True) then strPathDDK = str
1023	end if
1024
1025	' Check the registry next.
1026	arrSubKeys = RegEnumSubKeys("HKLM", "SOFTWARE\Microsoft\WINDDK") '' @todo Need some sorting stuff here.
1027	for Each strSubKey In arrSubKeys
1028	str = RegGetString("HKLM\SOFTWARE\Microsoft\WINDDK\" & strSubKey & "\SFNDirectory")
1029	if (strPathDDK = "") And (str <> "") then
1030	if CheckForWin2k3DDKSub(str, False) then strPathDDK = str
1031	end if
1032	Next
1033	arrSubKeys = RegEnumSubKeys("HKCU", "SOFTWARE\Microsoft\WINDDK") '' @todo Need some sorting stuff here.
1034	for Each strSubKey In arrSubKeys
1035	str = RegGetString("HKCU\SOFTWARE\Microsoft\WINDDK\" & strSubKey & "\SFNDirectory")
1036	if (strPathDDK = "") And (str <> "") then
1037	if CheckForWin2k3DDKSub(str, False) then strPathDDK = str
1038	end if
1039	Next
1040
1041	'
1042	' Emit the config.
1043	'
1044	strPathDDK = UnixSlashes(PathAbs(strPathDDK))
1045	CfgPrint "PATH_SDK_W2K3DDK := " & strPathDDK
1046	CfgPrint "PATH_SDK_W2K3DDKX86 = $(PATH_SDK_W2K3DDK)"
1047	CfgPrint "PATH_SDK_W2K3DDKAMD64 = $(PATH_SDK_W2K3DDK)"
1048
1049	PrintResult "Windows 2003 DDK", strPathDDK
1050	g_strPathDDK = strPathDDK
1051	end sub
1052
1053	'' Quick check if the DDK is in the specified directory or not.
1054	function CheckForWin2k3DDKSub(strPathDDK, blnCheckBuild)
1055	CheckForWin2k3DDKSub = False
1056	LogPrint "trying: strPathDDK=" & strPathDDK & " blnCheckBuild=" & blnCheckBuild
1057	if LogFileExists(strPathDDK, "inc/ddk/wnet/ntdef.h") _
1058	And LogFileExists(strPathDDK, "lib/wnet/i386/int64.lib") _
1059	then
1060	'' @todo figure out a way we can verify the version/build!
1061	CheckForWin2k3DDKSub = True
1062	end if
1063	end function
1064
1065
1066	''
1067	' Finds midl.exe
1068	sub CheckForMidl()
1069	dim strMidl
1070	PrintHdr "Midl.exe"
1071
1072	' Skip if no COM/ATL.
1073	if g_blnDisableCOM then
1074	PrintResult "Xerces", "Skipped (" & g_strDisableCOM & ")"
1075	exit sub
1076	end if
1077
1078	if LogFileExists(g_strPathPSDK, "bin/Midl.exe") then
1079	strMidl = g_strPathPSDK & "/bin/Midl.exe"
1080	elseif LogFileExists(g_strPathVCC, "Common7/Tools/Bin/Midl.exe") then
1081	strMidl = g_strPathVCC & "/Common7/Tools/Bin/Midl.exe"
1082	elseif LogFileExists(g_strPathDDK, "bin/x86/Midl.exe") then
1083	strMidl = g_strPathDDK & "/bin/x86/Midl.exe"
1084	elseif LogFileExists(g_strPathDDK, "bin/Midl.exe") then
1085	strMidl = g_strPathDDK & "/bin/Midl.exe"
1086	elseif LogFileExists(g_strPathDev, "win.x86/bin/Midl.exe") then
1087	strMidl = g_strPathDev & "/win.x86/bin/Midl.exe"
1088	else
1089	MsgWarning "Midl.exe not found!"
1090	exit sub
1091	end if
1092
1093	CfgPrint "MAIN_IDL = " & strMidl
1094	PrintResult "Midl.exe", strMidl
1095	end sub
1096
1097
1098	''
1099	' Checks for a recent DirectX SDK.
1100	sub CheckForDirectXSDK(strOptDXSDK)
1101	dim strPathDXSDK, str, arrSubKeys, arrSubKeys2, strKey, strKey2
1102	PrintHdr "Direct X SDK"
1103
1104	'
1105	' Find the DX SDK.
1106	'
1107	strPathDXSDK = ""
1108	' The specified path.
1109	if (strPathDXSDK = "") And (strOptDXSDK <> "") then
1110	if CheckForDirectXSDKSub(strOptDXSDK) then strPathDXSDK = strOptDXSDK
1111	end if
1112
1113	' The tools location.
1114	if strPathDXSDK = "" then
1115	str = g_strPathDev & "/win.x86/dxsdk/200610"
1116	if CheckForDirectXSDKSub(str) then strPathDXSDK = str
1117	end if
1118
1119	' Check the installer registry (sucks a bit).
1120	arrSubKeys = RegEnumSubKeys("HKLM", "SOFTWARE\Microsoft\Windows\CurrentVersion\Installer\UserData")
1121	for Each strSubKey In arrSubKeys
1122	strKey = "SOFTWARE\Microsoft\Windows\CurrentVersion\Installer\UserData\" & strSubKey & "\Products"
1123	arrSubKeys2 = RegEnumSubKeys("HKLM", strKey)
1124	for Each strSubKey2 In arrSubKeys2
1125	strKey2 = "HKLM\" & strKey & "\" & strSubKey2 & "\InstallProperties"
1126	str = RegGetString(strKey2 & "\DisplayName")
1127	if InStr(1, str, "Microsoft DirectX SDK") > 0 then
1128	str = RegGetString(strKey2 & "\InstallLocation")
1129	if (str <> "") And (strPathDXSDK = "") then
1130	if CheckForDirectXSDKSub(str) then
1131	strPathDXSDK = str
1132	Exit For
1133	end if
1134	end if
1135	end if
1136	Next
1137	Next
1138
1139	if strPathDXSDK = "" then
1140	MsgError "Cannot find a suitable Direct X SDK. Check configure.log and the build requirements."
1141	exit sub
1142	end if
1143
1144	'
1145	' Emit the config.
1146	'
1147	strPathDXSDK = UnixSlashes(PathAbs(strPathDXSDK))
1148	CfgPrint "PATH_SDK_DXSDK := " & strPathDXSDK
1149	CfgPrint "PATH_SDK_DXSDKX86 = $(PATH_SDK_DXSDK)"
1150	CfgPrint "PATH_SDK_DXSDKAMD64 = $(PATH_SDK_DXSDK)"
1151
1152	PrintResult "Direct X SDK", strPathDXSDK
1153	end sub
1154
1155	'' Quick check if the DXSDK is in the specified directory or not.
1156	function CheckForDirectXSDKSub(strPathDXSDK)
1157	CheckForDirectXSDKSub = False
1158	LogPrint "trying: strPathDXSDK=" & strPathDXSDK
1159	if LogFileExists(strPathDXSDK, "Lib/x86/dxguid.lib") _
1160	then
1161	'' @todo figure out a way we can verify the version/build!
1162	CheckForDirectXSDKSub = True
1163	end if
1164	end function
1165
1166
1167	''
1168	' Checks for a MingW32 suitable for building the recompiler.
1169	'
1170	' strOptW32API is currently ignored.
1171	'
1172	sub CheckForMingW(strOptMingw, strOptW32API)
1173	dim strPathMingW, strPathW32API, str
1174	PrintHdr "MinGW GCC v3.3.x + Binutils + Runtime + W32API"
1175
1176	'
1177	' Find the MinGW and W32API tools.
1178	'
1179	strPathMingW = ""
1180	strPathW32API = ""
1181
1182	' The specified path.
1183	if (strPathMingW = "") And (strOptMingW <> "") then
1184	if CheckForMingWSub(strOptMingW, strOptW32API) then
1185	strPathMingW = strOptMingW
1186	strPathW32API = strOptW32API
1187	end if
1188	end if
1189
1190	' The tools location.
1191	if strPathMingW = "" then
1192	str = g_strPathDev & "/win.x86/mingw32/v3.3.3"
1193	str2 = g_strPathDev & "/win.x86/w32api/v2.5"
1194	if CheckForMingWSub(str, str2) then
1195	strPathMingW = str
1196	strPathW32API = str2
1197	end if
1198	end if
1199
1200	' See if there is any gcc around.
1201	if strPathMingW = "" then
1202	str = Which("mingw32-gcc.exe")
1203	if (str <> "") then
1204	str = PathParent(PathStripFilename(str))
1205	if CheckForMingWSub(str, str) then strPathMingW = str
1206	end if
1207	end if
1208
1209	if strPathMingW = "" then
1210	str = Which("gcc.exe")
1211	if (str <> "") then
1212	str = PathParent(PathStripFilename(str))
1213	if CheckForMingWSub(str, str) then strPathMingW = str
1214	end if
1215	end if
1216
1217	' Success?
1218	if strPathMingW = "" then
1219	if strOptMingw = "" then
1220	MsgError "Can't locate a suitable MinGW installation. Try specify the path with " _
1221	& "the --with-MinGW=<path> argument. If still no luck, consult the configure.log and the build requirements."
1222	else
1223	MsgError "Can't locate a suitable MinGW installation. Please consult the configure.log and the build requirements."
1224	end if
1225	exit sub
1226	end if
1227
1228	'
1229	' Emit the config.
1230	'
1231	strPathMingW = UnixSlashes(PathAbs(strPathMingW))
1232	CfgPrint "PATH_TOOL_MINGW32 := " & strPathMingW
1233	PrintResult "MinGW (GCC v" & g_strSubOutput & ")", strPathMingW
1234	if (strPathMingW = strPathW32API) Or strPathW32API = "" then
1235	CfgPrint "PATH_SDK_W32API = $(PATH_TOOL_MINGW32)"
1236	else
1237	CfgPrint "PATH_SDK_W32API = " & strPathW32API
1238	PrintResult "W32API", strPathW32API
1239	end if
1240	end sub
1241
1242	''
1243	' Checks if the specified path points to an usable MinGW or not.
1244	function CheckForMingWSub(strPathMingW, strPathW32API)
1245	g_strSubOutput = ""
1246	if strPathW32API = "" then strPathW32API = strPathMingW
1247	LogPrint "trying: strPathMingW=" &strPathMingW & " strPathW32API=" & strPathW32API
1248
1249	if LogFileExists(strPathMingW, "bin/mingw32-gcc.exe") _
1250	And LogFileExists(strPathMingW, "bin/ld.exe") _
1251	And LogFileExists(strPathMingW, "bin/objdump.exe") _
1252	And LogFileExists(strPathMingW, "bin/dllwrap.exe") _
1253	And LogFileExists(strPathMingW, "bin/as.exe") _
1254	And LogFileExists(strPathMingW, "include/string.h") _
1255	And LogFileExists(strPathMingW, "include/_mingw.h") _
1256	And LogFileExists(strPathMingW, "lib/dllcrt1.o") _
1257	And LogFileExists(strPathMingW, "lib/dllcrt2.o") _
1258	And LogFileExists(strPathMingW, "lib/libmsvcrt.a") _
1259	_
1260	And LogFileExists(strPathW32API, "lib/libkernel32.a") _
1261	And LogFileExists(strPathW32API, "include/windows.h") _
1262	then
1263	if Shell(DosSlashes(strPathMingW & "/bin/gcc.exe") & " --version", True) = 0 then
1264	dim offVer, iMajor, iMinor, iPatch, strVer
1265
1266	' extract the version.
1267	strVer = ""
1268	offVer = InStr(1, g_strShellOutput, "(GCC) ")
1269	if offVer > 0 then
1270	strVer = LTrim(Mid(g_strShellOutput, offVer + Len("(GCC) ")))
1271	strVer = RTrim(Left(strVer, InStr(1, strVer, " ")))
1272	if (Mid(strVer, 2, 1) = ".") _
1273	And (Mid(strVer, 4, 1) = ".") then
1274	iMajor = Int(Left(strVer, 1)) ' Is Int() the right thing here? I want atoi()!!!
1275	iMinor = Int(Mid(strVer, 3, 1))
1276	iPatch = Int(Mid(strVer, 5))
1277	else
1278	LogPrint "Malformed version: '" & strVer & "'"
1279	strVer = ""
1280	end if
1281	end if
1282	if strVer <> "" then
1283	if (iMajor = 3) And (iMinor = 3) then
1284	CheckForMingWSub = True
1285	g_strSubOutput = strVer
1286	else
1287	LogPrint "MinGW version '" & iMajor & "." & iMinor & "." & iPatch & "' is not supported (or configure.vbs failed to parse it correctly)."
1288	end if
1289	else
1290	LogPrint "Couldn't locate the GCC version in the output!"
1291	end if
1292
1293	else
1294	LogPrint "Failed to run gcc.exe!"
1295	end if
1296	end if
1297	end function
1298
1299
1300	''
1301	' Checks for any libSDL binaries.
1302	sub CheckForlibSDL(strOptlibSDL)
1303	dim strPathlibSDL, str
1304	PrintHdr "libSDL"
1305
1306	'
1307	' Try find some SDL library.
1308	'
1309
1310	' First, the specific location.
1311	strPathlibSDL = ""
1312	if (strPathlibSDL = "") And (strOptlibSDL <> "") then
1313	if CheckForlibSDLSub(strOptlibSDL) then strPathlibSDL = strOptlibSDL
1314	end if
1315
1316	' The tools location.
1317	if strPathlibSDL = "" Then
1318	str = g_strPathDev & "/win.x86/libsdl/v1.2.11"
1319	if CheckForlibSDLSub(str) then strPathlibSDL = str
1320	end if
1321
1322	if strPathlibSDL = "" Then
1323	str = g_strPathDev & "/win.x86/libsdl/v1.2.7-InnoTek"
1324	if CheckForlibSDLSub(str) then strPathlibSDL = str
1325	end if
1326
1327	' Poke about in the path.
1328	str = Which("SDLmain.lib")
1329	if (strPathlibSDL = "") And (str <> "") Then
1330	str = PathParent(PathStripFilename(str))
1331	if CheckForlibSDLSub(str) then strPathlibSDL = str
1332	end if
1333
1334	str = Which("SDL.dll")
1335	if (strPathlibSDL = "") And (str <> "") Then
1336	str = PathParent(PathStripFilename(str))
1337	if CheckForlibSDLSub(str) then strPathlibSDL = str
1338	end if
1339
1340	' Success?
1341	if strPathlibSDL = "" then
1342	if strOptlibSDL = "" then
1343	MsgError "Can't locate libSDL. Try specify the path with the --with-libSDL=<path> argument. " _
1344	& "If still no luck, consult the configure.log and the build requirements."
1345	else
1346	MsgError "Can't locate libSDL. Please consult the configure.log and the build requirements."
1347	end if
1348	exit sub
1349	end if
1350
1351	strPathLibSDL = UnixSlashes(PathAbs(strPathLibSDL))
1352	CfgPrint "PATH_SDK_LIBSDL := " & strPathlibSDL
1353
1354	PrintResult "libSDL", strPathlibSDL
1355	end sub
1356
1357	''
1358	' Checks if the specified path points to an usable libSDL or not.
1359	function CheckForlibSDLSub(strPathlibSDL)
1360	CheckForlibSDLSub = False
1361	LogPrint "trying: strPathlibSDL=" & strPathlibSDL
1362	if LogFileExists(strPathlibSDL, "lib/SDL.lib") _
1363	And LogFileExists(strPathlibSDL, "lib/SDLmain.lib") _
1364	And LogFileExists(strPathlibSDL, "lib/SDL.dll") _
1365	And LogFileExists(strPathlibSDL, "include/SDL.h") _
1366	And LogFileExists(strPathlibSDL, "include/SDL_syswm.h") _
1367	And LogFileExists(strPathlibSDL, "include/SDL_version.h") _
1368	then
1369	CheckForlibSDLSub = True
1370	end if
1371	end function
1372
1373
1374	dim g_strXercesVer
1375	g_strXercesVer = ""
1376
1377	''
1378	' Checks for xerces.
1379	sub CheckForXerces(strOptXerces)
1380	dim strPathXerces, str
1381	PrintHdr "Xerces"
1382
1383	' Skip if no COM/ATL.
1384	if g_blnDisableCOM then
1385	PrintResult "Xerces", "Skipped (" & g_strDisableCOM & ")"
1386	exit sub
1387	end if
1388
1389	'
1390	' Try find some xerces dll/lib.
1391	'
1392	strPathXerces = ""
1393	if (strPathXerces = "") And (strOptXerces <> "") then
1394	if CheckForXercesSub(strOptXerces) then strPathXerces = strOptXerces
1395	end if
1396
1397	if strPathXerces = "" Then
1398	str = Which("xerces-c_2_9.lib")
1399	if str = "" then str = Which("xerces-c_2_8.lib")
1400	if str = "" then str = Which("xerces-c_2_7.lib")
1401	if str = "" then str = Which("xerces-c_2_6.lib")
1402	if str <> "" Then
1403	str = PathParent(PathStripFilename(str))
1404	if CheckForXercesSub(str) then strPathXerces = str
1405	end if
1406	end if
1407
1408	if strPathXerces = "" Then
1409	str = Which("xerces-c_2_9.dll")
1410	if str = "" then str = Which("xerces-c_2_8.dll")
1411	if str = "" then str = Which("xerces-c_2_7.dll")
1412	if str = "" then str = Which("xerces-c_2_6.dll")
1413	if str <> "" Then
1414	str = PathParent(PathStripFilename(str))
1415	if CheckForXercesSub(str) then strPathXerces = str
1416	end if
1417	end if
1418
1419	' Ignore failure if we're in 'internal' mode.
1420	if (strPathXerces = "") and g_blnInternalMode then
1421	PrintResult "Xerces", "ignored (internal mode)"
1422	exit sub
1423	end if
1424
1425	' Success?
1426	if strPathXerces = "" then
1427	if strOptXerces = "" then
1428	MsgError "Can't locate Xerces. Try specify the path with the --with-xerces=<path> argument. " _
1429	& "If still no luck, consult the configure.log and the build requirements."
1430	else
1431	MsgError "Can't locate Xerces. Please consult the configure.log and the build requirements."
1432	end if
1433	exit sub
1434	end if
1435
1436	strPathXerces = UnixSlashes(PathAbs(strPathXerces))
1437	CfgPrint "SDK_VBOX_XERCES_INCS := " & strPathXerces & "/include"
1438	CfgPrint "SDK_VBOX_XERCES_LIBS := " & strPathXerces & "/lib/xerces-c_" & Left(g_strXercesVer, 1) & ".lib"
1439	CfgPrint "DLL_SDK_VBOX_XERCES_XERCES := " & strPathXerces & "/bin/xerces-c_" & g_strXercesVer & ".dll"
1440
1441	PrintResult "Xerces", strPathXerces
1442	end sub
1443
1444	''
1445	' Checks if the specified path points to an usable libSDL or not.
1446	function CheckForXercesSub(strPathXerces)
1447	dim str
1448
1449	CheckForXercersSub = False
1450	LogPrint "trying: strPathXerces=" & strPathXerces
1451	if LogFileExists(strPathXerces, "include/xercesc/dom/DOM.hpp") _
1452	And LogFileExists(strPathXerces, "include/xercesc/validators/datatype/DatatypeValidator.hpp") _
1453	then
1454	' The version is encoded in the dll/lib name, so try first
1455	' to find the dll and then a matching lib.
1456	str = LogFindFile(strPathXerces, "bin/xerces-c_*.dll")
1457	if str <> "" then
1458	g_strXercesVer = Mid(str, Len("xerces-c_") + 1, Len(str) - Len("xerces-c_.dll"))
1459	' the library omits the minor version (in the current distro).
1460	if LogFileExists(strPathXerces, "lib/xerces-c_" & Left(g_strXercesVer, 1) & ".lib") then
1461	CheckForXercesSub = True
1462	end if
1463	end if
1464	end if
1465	end function
1466
1467
1468	dim g_strXalanVer
1469	g_strXalanVer = ""
1470
1471	''
1472	' Checks for Xalan.
1473	sub CheckForXalan(strOptXalan)
1474	dim strPathXalan, str
1475	PrintHdr "Xalan"
1476
1477	' Skip if no COM/ATL.
1478	if g_blnDisableCOM then
1479	PrintResult "Xalan", "Skipped (" & g_strDisableCOM & ")"
1480	exit sub
1481	end if
1482
1483	'
1484	' Try find some Xalan dll/lib.
1485	'
1486	strPathXalan = ""
1487	if (strPathXalan = "") And (strOptXalan <> "") then
1488	if CheckForXalanSub(strOptXalan) then strPathXalan = strOptXalan
1489	end if
1490
1491	if strPathXalan = "" Then
1492	str = Which("Xalan-c_1_12.lib")
1493	if str = "" then str = Which("Xalan-c_1_11.lib")
1494	if str = "" then str = Which("Xalan-c_1_10.lib")
1495	if str = "" then str = Which("Xalan-c_1_9.lib")
1496	if str <> "" Then
1497	str = PathParent(PathStripFilename(str))
1498	if CheckForXalanSub(str) then strPathXalan = str
1499	end if
1500	end if
1501
1502	if strPathXalan = "" Then
1503	str = Which("Xalan-c_1_12.dll")
1504	if str = "" then str = Which("Xalan-c_1_11.dll")
1505	if str = "" then str = Which("Xalan-c_1_10.dll")
1506	if str = "" then str = Which("Xalan-c_1_9.dll")
1507	if str <> "" Then
1508	str = PathParent(PathStripFilename(str))
1509	if CheckForXalanSub(str) then strPathXalan = str
1510	end if
1511	end if
1512
1513	' Ignore failure if we're in 'internal' mode.
1514	if (strPathXalan = "") and g_blnInternalMode then
1515	PrintResult "Xalan", "ignored (internal mode)"
1516	exit sub
1517	end if
1518
1519	' Success?
1520	if strPathXalan = "" then
1521	if strOptXalan = "" then
1522	MsgError "Can't locate Xalan. Try specify the path with the --with-Xalan=<path> argument. " _
1523	& "If still no luck, consult the configure.log and the build requirements."
1524	else
1525	MsgError "Can't locate Xalan. Please consult the configure.log and the build requirements."
1526	end if
1527	exit sub
1528	end if
1529
1530	strPathXalan = UnixSlashes(PathAbs(strPathXalan))
1531	CfgPrint "SDK_VBOX_XALAN_INCS := " & strPathXalan & "/include"
1532	CfgPrint "SDK_VBOX_XALAN_LIBS := " & strPathXalan & "/lib/Xalan-C_" & Left(g_strXalanVer, 1) & ".lib"
1533	CfgPrint "DLL_SDK_VBOX_XALAN_XALAN := " & strPathXalan & "/bin/Xalan-C_" & g_strXalanVer & ".dll"
1534	CfgPrint "DLL_SDK_VBOX_XALAN_XALAN-MESSAGES := " & strPathXalan & "/bin/XalanMessages_" & g_strXalanVer & ".dll"
1535
1536	PrintResult "Xalan", strPathXalan
1537	end sub
1538
1539	''
1540	' Checks if the specified path points to an usable Xalan or not.
1541	function CheckForXalanSub(strPathXalan)
1542	dim str
1543
1544	CheckForXercersSub = False
1545	LogPrint "trying: strPathXalan=" & strPathXalan
1546
1547	if LogFileExists(strPathXalan, "include/xalanc/DOMSupport/DOMSupport.hpp") _
1548	And LogFileExists(strPathXalan, "include/xalanc/XalanDOM/XalanText.hpp") _
1549	then
1550	' The version is encoded in the dll/lib name, so try first
1551	' to find the dll and then a matching lib.
1552	str = LogFindFile(strPathXalan, "bin/Xalan-C_*.dll")
1553	if str <> "" then
1554	g_strXalanVer = Mid(str, Len("Xalan-C_") + 1, Len(str) - Len("Xalan-C_.dll"))
1555	' the library omits the minor version (in the current distro).
1556	if LogFileExists(strPathXalan, "bin/XalanMessages_" & g_strXalanVer & ".dll") _
1557	And LogFileExists(strPathXalan, "lib/Xalan-C_" & Left(g_strXalanVer, 1) & ".lib") _
1558	then
1559	CheckForXalanSub = True
1560	end if
1561	end if
1562	end if
1563	end function
1564
1565
1566	dim g_strQtVer
1567	g_strQtVer = ""
1568
1569	''
1570	' Checks for any Qt binaries. Failure here isn't fatal.
1571	sub CheckForQt(strOptQt)
1572	dim strPathQt, str
1573
1574	PrintHdr "Qt"
1575
1576	'
1577	' Try find the Qt installation.
1578	'
1579	strPathQt = ""
1580
1581	if (strPathQt = "") And (strOptQt <> "") then
1582	if CheckForQtSub(strOptQt) then strPathQt = strOptQt
1583	end if
1584
1585	if strPathQt = "" then
1586	str = g_strPathDev & "/win.x86/qt/v3.3.3"
1587	if CheckForQtSub(str) then strPathQt = str
1588	end if
1589
1590	'' @todo check for Qt installations and stuff later.
1591
1592	' Found anything?
1593	if strPathQt = "" then
1594	CfgPrint "VBOX_WITH_QTGUI="
1595	PrintResult "Qt", "not found"
1596	else
1597	CfgPrint "VBOX_PATH_QT := " & strPathQt
1598	CfgPrint "QTDIR = $(VBOX_PATH_QT)"
1599	CfgPrint "LIB_QT = $(VBOX_PATH_QT)/lib/dynamic/qt-mt" & g_strQtVer & ".lib"
1600	CfgPrint "VBOX_DLL_QT = $(VBOX_PATH_QT)/bin/qt-mt" & g_strQtVer & ".dll"
1601	PrintResult "Qt (" & g_strQtVer & ")", strPathQt
1602	end if
1603	end sub
1604
1605	''
1606	' Checks if the specified path points to an usable Qt install or not.
1607	function CheckForQtSub(strPathQt)
1608
1609	CheckForQtSub = False
1610	LogPrint "trying: strPathQt=" & strPathQt
1611	if LogFileExists(strPathQt, "bin/moc.exe") _
1612	And LogFileExists(strPathQt, "bin/uic.exe") _
1613	And LogFileExists(strPathQt, "include/qvbox.h") _
1614	And LogFileExists(strPathQt, "include/qt_windows.h") _
1615	And LogFileExists(strPathQt, "include/qapplication.h") _
1616	And LogFileExists(strPathQt, "include/qtextedit.h") _
1617	And LogFileExists(strPathQt, "lib/dynamic/qtmain.lib") _
1618	then
1619	dim str
1620
1621	' This check might need improving.
1622	str = LogFindFile(strPathQt, "lib/dynamic/qt-mt33*.lib")
1623	if str <> "" then
1624	g_strQtVer = Mid(str, Len("qt-mt") + 1, Len(str) - Len("qt-mt.lib"))
1625	if LogFileExists(strPathQt, "bin/qt-mt" & g_strQtVer & ".dll") then
1626	CheckForQtSub = True
1627	end if
1628	end if
1629	end if
1630	end function
1631
1632
1633	''
1634	' Show usage.
1635	sub usage
1636	Print "Usage: cscript configure.vbs [options]"
1637	Print ""
1638	Print "Configuration:"
1639	Print " -h, --help"
1640	Print " --internal"
1641	Print ""
1642	Print "Components:"
1643	Print " --disable-COM"
1644	Print ""
1645	Print "Locations:"
1646	Print " --with-DDK=PATH "
1647	Print " --with-DXSDK=PATH "
1648	Print " --with-kBuild=PATH "
1649	Print " --with-libSDL=PATH "
1650	Print " --with-MinGW=PATH "
1651	Print " --with-Qt3=PATH "
1652	Print " --with-SDK=PATH "
1653	Print " --with-VC=PATH "
1654	Print " --with-VC-Common=PATH "
1655	Print " --with-VC-Express-Edition"
1656	Print " --with-W32API=PATH "
1657	Print " --with-Xalan=PATH "
1658	Print " --with-Xerces=PATH "
1659	end sub
1660
1661	''
1662	' The main() like function.
1663	'
1664	Sub Main
1665	'
1666	' Write the log header and check that we're not using wscript.
1667	'
1668	LogInit
1669	If UCase(Right(Wscript.FullName, 11)) = "WSCRIPT.EXE" Then
1670	Wscript.Echo "This script must be run under CScript."
1671	Wscript.Quit(1)
1672	End If
1673
1674	'
1675	' Parse arguments.
1676	'
1677	strOptDDK = ""
1678	strOptDXDDK = ""
1679	strOptkBuild = ""
1680	strOptlibSDL = ""
1681	strOptMingW = ""
1682	strOptQt = ""
1683	strOptSDK = ""
1684	strOptVC = ""
1685	strOptVCCommon = ""
1686	blnOptVCExpressEdition = False
1687	strOptW32API = ""
1688	blnOptXalan = ""
1689	blnOptXerces = ""
1690	blnOptDisableCOM = False
1691	for i = 1 to Wscript.Arguments.Count
1692	dim str, strArg, strPath
1693
1694	' Separate argument and path value
1695	str = Wscript.Arguments.item(i - 1)
1696	if InStr(1, str, "=") > 0 then
1697	strArg = Mid(str, 1, InStr(1, str, "=") - 1)
1698	strPath = Mid(str, InStr(1, str, "=") + 1)
1699	if strPath = "" then MsgFatal "Syntax error! Argument #" & i & " is missing the path."
1700	else
1701	strArg = str
1702	strPath = ""
1703	end if
1704
1705	' Process the argument
1706	select case LCase(strArg)
1707	case "--with-ddk"
1708	strOptDDK = strPath
1709	case "--with-dxsdk"
1710	strOptDXSDK = strPath
1711	case "--with-kbuild"
1712	strOptkBuild = strPath
1713	case "--with-libsdl"
1714	strOptlibSDL = strPath
1715	case "--with-mingw"
1716	strOptMingW = strPath
1717	case "--with-qt"
1718	strOptQt = strPath
1719	case "--with-sdk"
1720	strOptSDK = strPath
1721	case "--with-vc"
1722	strOptVC = strPath
1723	case "--with-vc-common"
1724	strOptVCCommon = strPath
1725	case "--with-vc-express-edition"
1726	blnOptVCExpressEdition = True
1727	case "--with-w32api"
1728	strOptW32API = strPath
1729	case "--with-xalan"
1730	strOptXalan = strPath
1731	case "--with-xerces"
1732	strOptXerces = strPath
1733	case "--disable-com"
1734	blnOptDisableCOM = True
1735	case "--enable-com"
1736	blnOptDisableCOM = False
1737	case "--internal"
1738	g_blnInternalMode = True
1739	case "-h", "--help", "-?"
1740	usage
1741	Wscript.Quit(0)
1742	case else
1743	Wscript.echo "syntax error: Unknown option '" & str &"'."
1744	usage
1745	Wscript.Quit(1)
1746	end select
1747	next
1748
1749	'
1750	' Initialize output files.
1751	'
1752	CfgInit
1753	EnvInit
1754
1755	'
1756	' Check that the Shell function is sane.
1757	'
1758	g_objShell.Environment("PROCESS")("TESTING_ENVIRONMENT_INHERITANCE") = "This works"
1759	if Shell("set TESTING_ENVIRONMENT_INHERITANC", False) <> 0 then ' The 'E' is missing on purpose (4nt).
1760	MsgFatal "shell execution test failed!"
1761	end if
1762	if g_strShellOutput <> "TESTING_ENVIRONMENT_INHERITANCE=This works" & CHR(13) & CHR(10) then
1763	MsgFatal "shell inheritance or shell execution isn't working right."
1764	end if
1765	g_objShell.Environment("PROCESS")("TESTING_ENVIRONMENT_INHERITANCE") = ""
1766	Print "Shell inheritance test: OK"
1767
1768	'
1769	' Do the checks.
1770	'
1771	if blnOptDisableCOM = True then
1772	DisableCOM "--disable-com"
1773	end if
1774	CheckSourcePath
1775	CheckForkBuild strOptkBuild
1776	CheckForVisualCPP strOptVC, strOptVCCommon, blnOptVCExpressEdition
1777	CheckForPlatformSDK strOptSDK
1778	CheckForWin2k3DDK strOptDDK
1779	CheckForMidl
1780	CheckForDirectXSDK strOptDXSDK
1781	CheckForMingW strOptMingw, strOptW32API
1782	CheckForlibSDL strOptlibSDL
1783	CheckForXerces strOptXerces
1784	CheckForXalan strOptXalan
1785	CheckForQt strOptQt
1786	if g_blnInternalMode then
1787	EnvPrint "call " & g_strPathDev & "/env.cmd %1 %2 %3 %4 %5 %6 %7 %8 %9"
1788	end if
1789
1790	End Sub
1791
1792
1793	Main
1794

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format