| 1 | # intmax_t.m4 serial 8
|
|---|
| 2 | dnl Copyright (C) 1997-2004, 2006-2007, 2009-2012 Free Software Foundation,
|
|---|
| 3 | dnl Inc.
|
|---|
| 4 | dnl This file is free software; the Free Software Foundation
|
|---|
| 5 | dnl gives unlimited permission to copy and/or distribute it,
|
|---|
| 6 | dnl with or without modifications, as long as this notice is preserved.
|
|---|
| 7 |
|
|---|
| 8 | dnl From Paul Eggert.
|
|---|
| 9 |
|
|---|
| 10 | AC_PREREQ([2.53])
|
|---|
| 11 |
|
|---|
| 12 | # Define intmax_t to 'long' or 'long long'
|
|---|
| 13 | # if it is not already defined in <stdint.h> or <inttypes.h>.
|
|---|
| 14 |
|
|---|
| 15 | AC_DEFUN([gl_AC_TYPE_INTMAX_T],
|
|---|
| 16 | [
|
|---|
| 17 | dnl For simplicity, we assume that a header file defines 'intmax_t' if and
|
|---|
| 18 | dnl only if it defines 'uintmax_t'.
|
|---|
| 19 | AC_REQUIRE([gl_AC_HEADER_INTTYPES_H])
|
|---|
| 20 | AC_REQUIRE([gl_AC_HEADER_STDINT_H])
|
|---|
| 21 | if test $gl_cv_header_inttypes_h = no && test $gl_cv_header_stdint_h = no; then
|
|---|
| 22 | AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
|
|---|
| 23 | test $ac_cv_type_long_long_int = yes \
|
|---|
| 24 | && ac_type='long long' \
|
|---|
| 25 | || ac_type='long'
|
|---|
| 26 | AC_DEFINE_UNQUOTED([intmax_t], [$ac_type],
|
|---|
| 27 | [Define to long or long long if <inttypes.h> and <stdint.h> don't define.])
|
|---|
| 28 | else
|
|---|
| 29 | AC_DEFINE([HAVE_INTMAX_T], [1],
|
|---|
| 30 | [Define if you have the 'intmax_t' type in <stdint.h> or <inttypes.h>.])
|
|---|
| 31 | fi
|
|---|
| 32 | ])
|
|---|
| 33 |
|
|---|
| 34 | dnl An alternative would be to explicitly test for 'intmax_t'.
|
|---|
| 35 |
|
|---|
| 36 | AC_DEFUN([gt_AC_TYPE_INTMAX_T],
|
|---|
| 37 | [
|
|---|
| 38 | AC_REQUIRE([gl_AC_HEADER_INTTYPES_H])
|
|---|
| 39 | AC_REQUIRE([gl_AC_HEADER_STDINT_H])
|
|---|
| 40 | AC_CACHE_CHECK([for intmax_t], [gt_cv_c_intmax_t],
|
|---|
| 41 | [AC_COMPILE_IFELSE(
|
|---|
| 42 | [AC_LANG_PROGRAM(
|
|---|
| 43 | [[
|
|---|
| 44 | #include <stddef.h>
|
|---|
| 45 | #include <stdlib.h>
|
|---|
| 46 | #if HAVE_STDINT_H_WITH_UINTMAX
|
|---|
| 47 | #include <stdint.h>
|
|---|
| 48 | #endif
|
|---|
| 49 | #if HAVE_INTTYPES_H_WITH_UINTMAX
|
|---|
| 50 | #include <inttypes.h>
|
|---|
| 51 | #endif
|
|---|
| 52 | ]],
|
|---|
| 53 | [[intmax_t x = -1; return !x;]])],
|
|---|
| 54 | [gt_cv_c_intmax_t=yes],
|
|---|
| 55 | [gt_cv_c_intmax_t=no])])
|
|---|
| 56 | if test $gt_cv_c_intmax_t = yes; then
|
|---|
| 57 | AC_DEFINE([HAVE_INTMAX_T], [1],
|
|---|
| 58 | [Define if you have the 'intmax_t' type in <stdint.h> or <inttypes.h>.])
|
|---|
| 59 | else
|
|---|
| 60 | AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
|
|---|
| 61 | test $ac_cv_type_long_long_int = yes \
|
|---|
| 62 | && ac_type='long long' \
|
|---|
| 63 | || ac_type='long'
|
|---|
| 64 | AC_DEFINE_UNQUOTED([intmax_t], [$ac_type],
|
|---|
| 65 | [Define to long or long long if <stdint.h> and <inttypes.h> don't define.])
|
|---|
| 66 | fi
|
|---|
| 67 | ])
|
|---|
