VirtualBox

source: kBuild/vendor/grep/2.12/m4/gnulib-common.m4@ 3627

Last change on this file since 3627 was 2595, checked in by bird, 13 years ago

gnu grep version 2.12 (grep-2.12.tar.xz, md5sum=8d2f0346d08b13c18afb81f0e8aa1e2f)
File size: 13.5 KB
Line 
1# gnulib-common.m4 serial 32
2dnl Copyright (C) 2007-2012 Free Software Foundation, Inc.
3dnl This file is free software; the Free Software Foundation
4dnl gives unlimited permission to copy and/or distribute it,
5dnl with or without modifications, as long as this notice is preserved.
6
7# gl_COMMON
8# is expanded unconditionally through gnulib-tool magic.
9AC_DEFUN([gl_COMMON], [
10 dnl Use AC_REQUIRE here, so that the code is expanded once only.
11 AC_REQUIRE([gl_00GNULIB])
12 AC_REQUIRE([gl_COMMON_BODY])
13])
14AC_DEFUN([gl_COMMON_BODY], [
15 AH_VERBATIM([_Noreturn],
16[/* The _Noreturn keyword of C11. */
17#ifndef _Noreturn
18# if (3 <= __GNUC__ || (__GNUC__ == 2 && 8 <= __GNUC_MINOR__) \
19 || 0x5110 <= __SUNPRO_C)
20# define _Noreturn __attribute__ ((__noreturn__))
21# elif defined _MSC_VER && 1200 <= _MSC_VER
22# define _Noreturn __declspec (noreturn)
23# else
24# define _Noreturn
25# endif
26#endif
27])
28 AH_VERBATIM([isoc99_inline],
29[/* Work around a bug in Apple GCC 4.0.1 build 5465: In C99 mode, it supports
30 the ISO C 99 semantics of 'extern inline' (unlike the GNU C semantics of
31 earlier versions), but does not display it by setting __GNUC_STDC_INLINE__.
32 __APPLE__ && __MACH__ test for MacOS X.
33 __APPLE_CC__ tests for the Apple compiler and its version.
34 __STDC_VERSION__ tests for the C99 mode. */
35#if defined __APPLE__ && defined __MACH__ && __APPLE_CC__ >= 5465 && !defined __cplusplus && __STDC_VERSION__ >= 199901L && !defined __GNUC_STDC_INLINE__
36# define __GNUC_STDC_INLINE__ 1
37#endif])
38 AH_VERBATIM([unused_parameter],
39[/* Define as a marker that can be attached to declarations that might not
40 be used. This helps to reduce warnings, such as from
41 GCC -Wunused-parameter. */
42#if __GNUC__ >= 3 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
43# define _GL_UNUSED __attribute__ ((__unused__))
44#else
45# define _GL_UNUSED
46#endif
47/* The name _UNUSED_PARAMETER_ is an earlier spelling, although the name
48 is a misnomer outside of parameter lists. */
49#define _UNUSED_PARAMETER_ _GL_UNUSED
50
51/* The __pure__ attribute was added in gcc 2.96. */
52#if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 96)
53# define _GL_ATTRIBUTE_PURE __attribute__ ((__pure__))
54#else
55# define _GL_ATTRIBUTE_PURE /* empty */
56#endif
57
58/* The __const__ attribute was added in gcc 2.95. */
59#if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 95)
60# define _GL_ATTRIBUTE_CONST __attribute__ ((__const__))
61#else
62# define _GL_ATTRIBUTE_CONST /* empty */
63#endif
64])
65 dnl Preparation for running test programs:
66 dnl Tell glibc to write diagnostics from -D_FORTIFY_SOURCE=2 to stderr, not
67 dnl to /dev/tty, so they can be redirected to log files. Such diagnostics
68 dnl arise e.g., in the macros gl_PRINTF_DIRECTIVE_N, gl_SNPRINTF_DIRECTIVE_N.
69 LIBC_FATAL_STDERR_=1
70 export LIBC_FATAL_STDERR_
71])
72
73# gl_MODULE_INDICATOR_CONDITION
74# expands to a C preprocessor expression that evaluates to 1 or 0, depending
75# whether a gnulib module that has been requested shall be considered present
76# or not.
77m4_define([gl_MODULE_INDICATOR_CONDITION], [1])
78
79# gl_MODULE_INDICATOR_SET_VARIABLE([modulename])
80# sets the shell variable that indicates the presence of the given module to
81# a C preprocessor expression that will evaluate to 1.
82AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE],
83[
84 gl_MODULE_INDICATOR_SET_VARIABLE_AUX(
85 [GNULIB_[]m4_translit([[$1]],
86 [abcdefghijklmnopqrstuvwxyz./-],
87 [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])],
88 [gl_MODULE_INDICATOR_CONDITION])
89])
90
91# gl_MODULE_INDICATOR_SET_VARIABLE_AUX([variable])
92# modifies the shell variable to include the gl_MODULE_INDICATOR_CONDITION.
93# The shell variable's value is a C preprocessor expression that evaluates
94# to 0 or 1.
95AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE_AUX],
96[
97 m4_if(m4_defn([gl_MODULE_INDICATOR_CONDITION]), [1],
98 [
99 dnl Simplify the expression VALUE || 1 to 1.
100 $1=1
101 ],
102 [gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR([$1],
103 [gl_MODULE_INDICATOR_CONDITION])])
104])
105
106# gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR([variable], [condition])
107# modifies the shell variable to include the given condition. The shell
108# variable's value is a C preprocessor expression that evaluates to 0 or 1.
109AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR],
110[
111 dnl Simplify the expression 1 || CONDITION to 1.
112 if test "$[]$1" != 1; then
113 dnl Simplify the expression 0 || CONDITION to CONDITION.
114 if test "$[]$1" = 0; then
115 $1=$2
116 else
117 $1="($[]$1 || $2)"
118 fi
119 fi
120])
121
122# gl_MODULE_INDICATOR([modulename])
123# defines a C macro indicating the presence of the given module
124# in a location where it can be used.
125# | Value | Value |
126# | in lib/ | in tests/ |
127# --------------------------------------------+---------+-----------+
128# Module present among main modules: | 1 | 1 |
129# --------------------------------------------+---------+-----------+
130# Module present among tests-related modules: | 0 | 1 |
131# --------------------------------------------+---------+-----------+
132# Module not present at all: | 0 | 0 |
133# --------------------------------------------+---------+-----------+
134AC_DEFUN([gl_MODULE_INDICATOR],
135[
136 AC_DEFINE_UNQUOTED([GNULIB_]m4_translit([[$1]],
137 [abcdefghijklmnopqrstuvwxyz./-],
138 [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]),
139 [gl_MODULE_INDICATOR_CONDITION],
140 [Define to a C preprocessor expression that evaluates to 1 or 0,
141 depending whether the gnulib module $1 shall be considered present.])
142])
143
144# gl_MODULE_INDICATOR_FOR_TESTS([modulename])
145# defines a C macro indicating the presence of the given module
146# in lib or tests. This is useful to determine whether the module
147# should be tested.
148# | Value | Value |
149# | in lib/ | in tests/ |
150# --------------------------------------------+---------+-----------+
151# Module present among main modules: | 1 | 1 |
152# --------------------------------------------+---------+-----------+
153# Module present among tests-related modules: | 1 | 1 |
154# --------------------------------------------+---------+-----------+
155# Module not present at all: | 0 | 0 |
156# --------------------------------------------+---------+-----------+
157AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS],
158[
159 AC_DEFINE([GNULIB_TEST_]m4_translit([[$1]],
160 [abcdefghijklmnopqrstuvwxyz./-],
161 [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]), [1],
162 [Define to 1 when the gnulib module $1 should be tested.])
163])
164
165# gl_ASSERT_NO_GNULIB_POSIXCHECK
166# asserts that there will never be a need to #define GNULIB_POSIXCHECK.
167# and thereby enables an optimization of configure and config.h.
168# Used by Emacs.
169AC_DEFUN([gl_ASSERT_NO_GNULIB_POSIXCHECK],
170[
171 dnl Override gl_WARN_ON_USE_PREPARE.
172 dnl But hide this definition from 'aclocal'.
173 AC_DEFUN([gl_W][ARN_ON_USE_PREPARE], [])
174])
175
176# gl_ASSERT_NO_GNULIB_TESTS
177# asserts that there will be no gnulib tests in the scope of the configure.ac
178# and thereby enables an optimization of config.h.
179# Used by Emacs.
180AC_DEFUN([gl_ASSERT_NO_GNULIB_TESTS],
181[
182 dnl Override gl_MODULE_INDICATOR_FOR_TESTS.
183 AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS], [])
184])
185
186# Test whether <features.h> exists.
187# Set HAVE_FEATURES_H.
188AC_DEFUN([gl_FEATURES_H],
189[
190 AC_CHECK_HEADERS_ONCE([features.h])
191 if test $ac_cv_header_features_h = yes; then
192 HAVE_FEATURES_H=1
193 else
194 HAVE_FEATURES_H=0
195 fi
196 AC_SUBST([HAVE_FEATURES_H])
197])
198
199# m4_foreach_w
200# is a backport of autoconf-2.59c's m4_foreach_w.
201# Remove this macro when we can assume autoconf >= 2.60.
202m4_ifndef([m4_foreach_w],
203 [m4_define([m4_foreach_w],
204 [m4_foreach([$1], m4_split(m4_normalize([$2]), [ ]), [$3])])])
205
206# AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
207# ----------------------------------------------------
208# Backport of autoconf-2.63b's macro.
209# Remove this macro when we can assume autoconf >= 2.64.
210m4_ifndef([AS_VAR_IF],
211[m4_define([AS_VAR_IF],
212[AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
213
214# gl_PROG_CC_C99
215# Modifies the value of the shell variable CC in an attempt to make $CC
216# understand ISO C99 source code.
217# This is like AC_PROG_CC_C99, except that
218# - AC_PROG_CC_C99 did not exist in Autoconf versions < 2.60,
219# - AC_PROG_CC_C99 does not mix well with AC_PROG_CC_STDC
220# <http://lists.gnu.org/archive/html/bug-gnulib/2011-09/msg00367.html>,
221# but many more packages use AC_PROG_CC_STDC than AC_PROG_CC_C99
222# <http://lists.gnu.org/archive/html/bug-gnulib/2011-09/msg00441.html>.
223# Remaining problems:
224# - When AC_PROG_CC_STDC is invoked twice, it adds the C99 enabling options
225# to CC twice
226# <http://lists.gnu.org/archive/html/bug-gnulib/2011-09/msg00431.html>.
227# - AC_PROG_CC_STDC is likely to change now that C11 is an ISO standard.
228AC_DEFUN([gl_PROG_CC_C99],
229[
230 dnl Change that version number to the minimum Autoconf version that supports
231 dnl mixing AC_PROG_CC_C99 calls with AC_PROG_CC_STDC calls.
232 m4_version_prereq([9.0],
233 [AC_REQUIRE([AC_PROG_CC_C99])],
234 [AC_REQUIRE([AC_PROG_CC_STDC])])
235])
236
237# gl_PROG_AR_RANLIB
238# Determines the values for AR, ARFLAGS, RANLIB that fit with the compiler.
239# The user can set the variables AR, ARFLAGS, RANLIB if he wants to override
240# the values.
241AC_DEFUN([gl_PROG_AR_RANLIB],
242[
243 dnl Minix 3 comes with two toolchains: The Amsterdam Compiler Kit compiler
244 dnl as "cc", and GCC as "gcc". They have different object file formats and
245 dnl library formats. In particular, the GNU binutils programs ar, ranlib
246 dnl produce libraries that work only with gcc, not with cc.
247 AC_REQUIRE([AC_PROG_CC])
248 AC_CACHE_CHECK([for Minix Amsterdam compiler], [gl_cv_c_amsterdam_compiler],
249 [
250 AC_EGREP_CPP([Amsterdam],
251 [
252#ifdef __ACK__
253Amsterdam
254#endif
255 ],
256 [gl_cv_c_amsterdam_compiler=yes],
257 [gl_cv_c_amsterdam_compiler=no])
258 ])
259 if test -z "$AR"; then
260 if test $gl_cv_c_amsterdam_compiler = yes; then
261 AR='cc -c.a'
262 if test -z "$ARFLAGS"; then
263 ARFLAGS='-o'
264 fi
265 else
266 dnl Use the Automake-documented default values for AR and ARFLAGS,
267 dnl but prefer ${host}-ar over ar (useful for cross-compiling).
268 AC_CHECK_TOOL([AR], [ar], [ar])
269 if test -z "$ARFLAGS"; then
270 ARFLAGS='cru'
271 fi
272 fi
273 else
274 if test -z "$ARFLAGS"; then
275 ARFLAGS='cru'
276 fi
277 fi
278 AC_SUBST([AR])
279 AC_SUBST([ARFLAGS])
280 if test -z "$RANLIB"; then
281 if test $gl_cv_c_amsterdam_compiler = yes; then
282 RANLIB=':'
283 else
284 dnl Use the ranlib program if it is available.
285 AC_PROG_RANLIB
286 fi
287 fi
288 AC_SUBST([RANLIB])
289])
290
291# AC_PROG_MKDIR_P
292# is a backport of autoconf-2.60's AC_PROG_MKDIR_P, with a fix
293# for interoperability with automake-1.9.6 from autoconf-2.62.
294# Remove this macro when we can assume autoconf >= 2.62 or
295# autoconf >= 2.60 && automake >= 1.10.
296m4_ifdef([AC_PROG_MKDIR_P], [
297 dnl For automake-1.9.6 && autoconf < 2.62: Ensure MKDIR_P is AC_SUBSTed.
298 m4_define([AC_PROG_MKDIR_P],
299 m4_defn([AC_PROG_MKDIR_P])[
300 AC_SUBST([MKDIR_P])])], [
301 dnl For autoconf < 2.60: Backport of AC_PROG_MKDIR_P.
302 AC_DEFUN_ONCE([AC_PROG_MKDIR_P],
303 [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
304 MKDIR_P='$(mkdir_p)'
305 AC_SUBST([MKDIR_P])])])
306
307# AC_C_RESTRICT
308# This definition overrides the AC_C_RESTRICT macro from autoconf 2.60..2.61,
309# so that mixed use of GNU C and GNU C++ and mixed use of Sun C and Sun C++
310# works.
311# This definition can be removed once autoconf >= 2.62 can be assumed.
312m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]),[2.62]),[-1],[
313AC_DEFUN([AC_C_RESTRICT],
314[AC_CACHE_CHECK([for C/C++ restrict keyword], [ac_cv_c_restrict],
315 [ac_cv_c_restrict=no
316 # The order here caters to the fact that C++ does not require restrict.
317 for ac_kw in __restrict __restrict__ _Restrict restrict; do
318 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
319 [[typedef int * int_ptr;
320 int foo (int_ptr $ac_kw ip) {
321 return ip[0];
322 }]],
323 [[int s[1];
324 int * $ac_kw t = s;
325 t[0] = 0;
326 return foo(t)]])],
327 [ac_cv_c_restrict=$ac_kw])
328 test "$ac_cv_c_restrict" != no && break
329 done
330 ])
331 AH_VERBATIM([restrict],
332[/* Define to the equivalent of the C99 'restrict' keyword, or to
333 nothing if this is not supported. Do not define if restrict is
334 supported directly. */
335#undef restrict
336/* Work around a bug in Sun C++: it does not support _Restrict, even
337 though the corresponding Sun C compiler does, which causes
338 "#define restrict _Restrict" in the previous line. Perhaps some future
339 version of Sun C++ will work with _Restrict; if so, it'll probably
340 define __RESTRICT, just as Sun C does. */
341#if defined __SUNPRO_CC && !defined __RESTRICT
342# define _Restrict
343#endif])
344 case $ac_cv_c_restrict in
345 restrict) ;;
346 no) AC_DEFINE([restrict], []) ;;
347 *) AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
348 esac
349])
350])
351
352# gl_BIGENDIAN
353# is like AC_C_BIGENDIAN, except that it can be AC_REQUIREd.
354# Note that AC_REQUIRE([AC_C_BIGENDIAN]) does not work reliably because some
355# macros invoke AC_C_BIGENDIAN with arguments.
356AC_DEFUN([gl_BIGENDIAN],
357[
358 AC_C_BIGENDIAN
359])
360
361# gl_CACHE_VAL_SILENT(cache-id, command-to-set-it)
362# is like AC_CACHE_VAL(cache-id, command-to-set-it), except that it does not
363# output a spurious "(cached)" mark in the midst of other configure output.
364# This macro should be used instead of AC_CACHE_VAL when it is not surrounded
365# by an AC_MSG_CHECKING/AC_MSG_RESULT pair.
366AC_DEFUN([gl_CACHE_VAL_SILENT],
367[
368 saved_as_echo_n="$as_echo_n"
369 as_echo_n=':'
370 AC_CACHE_VAL([$1], [$2])
371 as_echo_n="$saved_as_echo_n"
372])
Note: See TracBrowser for help on using the repository browser.

© 2025 Oracle Support Privacy / Do Not Sell My Info Terms of Use Trademark Policy Automated Access Etiquette